configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT()
   4 AC_CONFIG_SRCDIR([byteorder.h])
   5 AC_CONFIG_HEADER(config.h)
   6 AC_PREREQ(2.59)
   7
   8 RSYNC_VERSION=3.0.5pre1
   9 AC_SUBST(RSYNC_VERSION)
  10 AC_MSG_NOTICE([Configuring rsync $RSYNC_VERSION])
  11
  12 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$RSYNC_VERSION"], [rsync release version])
  13
  14 LDFLAGS=${LDFLAGS-""}
  15
  16 AC_CANONICAL_TARGET([])
  17
  18 dnl Checks for programs.
  19 AC_PROG_CC
  20 AC_PROG_CPP
  21 AC_PROG_EGREP
  22 AC_PROG_INSTALL
  23 AC_PROG_CC_STDC
  24 AC_SUBST(SHELL)
  25
  26 AC_DEFINE([_GNU_SOURCE], 1,
  27           [Define _GNU_SOURCE so that we get all necessary prototypes])
  28
  29 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  30         AC_MSG_WARN([rsync requires an ANSI C compiler and you don't seem to have one])
  31 fi
  32
  33 # We must decide this before testing the compiler.
  34
  35 # Please allow this to default to yes, so that your users have more
  36 # chance of getting a useful stack trace if problems occur.
  37
  38 AC_MSG_CHECKING([whether to include debugging symbols])
  39 AC_ARG_ENABLE(debug,
  40         AC_HELP_STRING([--disable-debug],
  41                 [disable debugging symbols and features]))
  42
  43 if test x"$enable_debug" = x"no"; then
  44     AC_MSG_RESULT(no)
  45     CFLAGS=${CFLAGS-"-O"}
  46 else
  47     AC_MSG_RESULT([yes])
  48     # leave CFLAGS alone; AC_PROG_CC will try to include -g if it can
  49     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  50     dnl CFLAGS=${CFLAGS-"-g"}
  51 fi
  52
  53
  54 AC_ARG_ENABLE(profile,
  55         AC_HELP_STRING([--enable-profile],
  56                 [turn on CPU profiling]))
  57 if test x"$enable_profile" = x"yes"; then
  58         CFLAGS="$CFLAGS -pg"
  59 fi
  60
  61
  62 # Specifically, this turns on panic_action handling.
  63 AC_ARG_ENABLE(maintainer-mode,
  64         AC_HELP_STRING([--enable-maintainer-mode],
  65                 [turn on extra debug features]))
  66 if test x"$enable_maintainer_mode" = x"yes"; then
  67         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
  68 fi
  69
  70
  71 # This is needed for our included version of popt.  Kind of silly, but
  72 # I don't want our version too far out of sync.
  73 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  74
  75 # If GCC, turn on warnings.
  76 if test x"$GCC" = x"yes"; then
  77         CFLAGS="$CFLAGS -Wall -W"
  78 fi
  79
  80 AC_ARG_WITH(included-popt,
  81         AC_HELP_STRING([--with-included-popt], [use bundled popt library, not from system]))
  82
  83 AC_ARG_WITH(rsync-path,
  84         AC_HELP_STRING([--with-rsync-path=PATH], [set default --rsync-path to PATH (default: rsync)]),
  85         [ RSYNC_PATH="$with_rsync_path" ],
  86         [ RSYNC_PATH="rsync" ])
  87
  88 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
  89
  90 AC_ARG_WITH(rsyncd-conf,
  91         AC_HELP_STRING([--with-rsyncd-conf=PATH], [set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
  92         [ if test ! -z "$with_rsyncd_conf" ; then
  93                 case $with_rsyncd_conf in
  94                         yes|no)
  95                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
  96                                 ;;
  97                         /*)
  98                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
  99                                 ;;
 100                         *)
 101                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 102                                 ;;
 103                 esac
 104         else
 105                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 106         fi ],
 107         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 108
 109 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 110
 111 AC_ARG_WITH(rsh,
 112         AC_HELP_STRING([--with-rsh=CMD], [set remote shell command to CMD (default: ssh)]))
 113
 114 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 115 if test x$HAVE_REMSH = x1; then
 116         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 117 fi
 118
 119 if test x"$with_rsh" != x; then
 120         RSYNC_RSH="$with_rsh"
 121 else
 122         RSYNC_RSH="ssh"
 123 fi
 124 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 125
 126 AC_CHECK_PROG(HAVE_YODL2MAN, yodl2man, 1, 0)
 127 if test x$HAVE_YODL2MAN = x1; then
 128     MAKE_MAN=man
 129 fi
 130
 131 AC_ARG_WITH(nobody-group,
 132     AC_HELP_STRING([--with-nobody-group=GROUP],
 133                    [set the default unprivileged group (default nobody or nogroup)]),
 134     [ NOBODY_GROUP="$with_nobody_group" ])
 135
 136 if test x"$with_nobody_group" = x; then
 137     AC_MSG_CHECKING([the group for user "nobody"])
 138     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 139         NOBODY_GROUP=nobody
 140     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 141         NOBODY_GROUP=nogroup
 142     else
 143         NOBODY_GROUP=nobody # test for others?
 144     fi
 145     AC_MSG_RESULT($NOBODY_GROUP)
 146 fi
 147
 148 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 149 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 150
 151 # arrgh. libc in some old debian version screwed up the largefile
 152 # stuff, getting byte range locking wrong
 153 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 154 AC_TRY_RUN([
 155 #define _FILE_OFFSET_BITS 64
 156 #include <stdio.h>
 157 #include <fcntl.h>
 158 #include <sys/types.h>
 159 #include <sys/wait.h>
 160
 161 int main(void)
 162 {
 163         struct flock lock;
 164         int status;
 165         char tpl[32] = "/tmp/locktest.XXXXXX";
 166         int fd = mkstemp(tpl);
 167         if (fd < 0) {
 168                 strcpy(tpl, "conftest.dat");
 169                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 170         }
 171
 172         lock.l_type = F_WRLCK;
 173         lock.l_whence = SEEK_SET;
 174         lock.l_start = 0;
 175         lock.l_len = 1;
 176         lock.l_pid = 0;
 177         fcntl(fd,F_SETLK,&lock);
 178         if (fork() == 0) {
 179                 lock.l_start = 1;
 180                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 181         }
 182         wait(&status);
 183         unlink(tpl);
 184         exit(WEXITSTATUS(status));
 185 }
 186 ],
 187 rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)])
 188 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 189    AC_SYS_LARGEFILE
 190 fi
 191
 192 ipv6type=unknown
 193 ipv6lib=none
 194 ipv6trylibc=yes
 195
 196 AC_ARG_ENABLE(ipv6,
 197         AC_HELP_STRING([--disable-ipv6],
 198                 [don't even try to use IPv6]))
 199 if test x"$enable_ipv6" != x"no"; then
 200         AC_MSG_CHECKING([ipv6 stack type])
 201         for i in inria kame linux-glibc linux-inet6 toshiba v6d zeta; do
 202                 case $i in
 203                 inria)
 204                         # http://www.kame.net/
 205                         AC_EGREP_CPP(yes, [
 206 #include <netinet/in.h>
 207 #ifdef IPV6_INRIA_VERSION
 208 yes
 209 #endif],
 210                                 [ipv6type=$i;
 211                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 212                                 ])
 213                         ;;
 214                 kame)
 215                         # http://www.kame.net/
 216                         AC_EGREP_CPP(yes, [
 217 #include <netinet/in.h>
 218 #ifdef __KAME__
 219 yes
 220 #endif],
 221                                 [ipv6type=$i;
 222                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 223                         ;;
 224                 linux-glibc)
 225                         # http://www.v6.linux.or.jp/
 226                         AC_EGREP_CPP(yes, [
 227 #include <features.h>
 228 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 229 yes
 230 #endif],
 231                                 [ipv6type=$i;
 232 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 233                         ;;
 234                 linux-inet6)
 235                         # http://www.v6.linux.or.jp/
 236                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 237                                 ipv6type=$i
 238                                 ipv6lib=inet6
 239                                 ipv6libdir=/usr/inet6/lib
 240                                 ipv6trylibc=yes;
 241                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 242                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 243                         fi
 244                         ;;
 245                 toshiba)
 246                         AC_EGREP_CPP(yes, [
 247 #include <sys/param.h>
 248 #ifdef _TOSHIBA_INET6
 249 yes
 250 #endif],
 251                                 [ipv6type=$i;
 252                                 ipv6lib=inet6;
 253                                 ipv6libdir=/usr/local/v6/lib;
 254                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 255                         ;;
 256                 v6d)
 257                         AC_EGREP_CPP(yes, [
 258 #include </usr/local/v6/include/sys/v6config.h>
 259 #ifdef __V6D__
 260 yes
 261 #endif],
 262                                 [ipv6type=$i;
 263                                 ipv6lib=v6;
 264                                 ipv6libdir=/usr/local/v6/lib;
 265                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 266                         ;;
 267                 zeta)
 268                         AC_EGREP_CPP(yes, [
 269 #include <sys/param.h>
 270 #ifdef _ZETA_MINAMI_INET6
 271 yes
 272 #endif],
 273                                 [ipv6type=$i;
 274                                 ipv6lib=inet6;
 275                                 ipv6libdir=/usr/local/v6/lib;
 276                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 277                         ;;
 278                 esac
 279                 if test "$ipv6type" != "unknown"; then
 280                         break
 281                 fi
 282         done
 283         AC_MSG_RESULT($ipv6type)
 284
 285         AC_SEARCH_LIBS(getaddrinfo, inet6)
 286 fi
 287
 288 dnl Do you want to disable use of locale functions
 289 AC_ARG_ENABLE([locale],
 290         AC_HELP_STRING([--disable-locale],
 291                 [disable locale features]))
 292 AH_TEMPLATE([CONFIG_LOCALE],
 293 [Undefine if you don't want locale features.  By default this is defined.])
 294 if test x"$enable_locale" != x"no"; then
 295         AC_DEFINE(CONFIG_LOCALE)
 296 fi
 297
 298 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 299 case $host_os in
 300         *cygwin* ) AC_MSG_RESULT(yes)
 301                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 302                             [Define to 1 if sockets need to be shutdown])
 303                    ;;
 304                * ) AC_MSG_RESULT(no);;
 305 esac
 306
 307 AC_C_BIGENDIAN
 308 AC_HEADER_DIRENT
 309 AC_HEADER_TIME
 310 AC_HEADER_SYS_WAIT
 311 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 312     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 313     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 314     sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 315     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
 316     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h \
 317     popt.h popt/popt.h)
 318 AC_HEADER_MAJOR
 319
 320 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 321 AC_TRY_RUN([
 322 #include <sys/types.h>
 323 #ifdef MAJOR_IN_MKDEV
 324 #include <sys/mkdev.h>
 325 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 326 #  define makedev mkdev
 327 # endif
 328 #elif defined MAJOR_IN_SYSMACROS
 329 #include <sys/sysmacros.h>
 330 #endif
 331
 332 int main(void)
 333 {
 334         dev_t dev = makedev(0, 5, 7);
 335         if (major(dev) != 5 || minor(dev) != 7)
 336                 exit(1);
 337         return 0;
 338 }
 339 ],
 340 rsync_cv_MAKEDEV_TAKES_3_ARGS=yes,rsync_cv_MAKEDEV_TAKES_3_ARGS=no,rsync_cv_MAKEDEV_TAKES_3_ARGS=no)])
 341 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 342    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 343 fi
 344
 345 AC_CHECK_SIZEOF(int)
 346 AC_CHECK_SIZEOF(long)
 347 AC_CHECK_SIZEOF(long long)
 348 AC_CHECK_SIZEOF(short)
 349 AC_CHECK_SIZEOF(int16_t)
 350 AC_CHECK_SIZEOF(uint16_t)
 351 AC_CHECK_SIZEOF(int32_t)
 352 AC_CHECK_SIZEOF(uint32_t)
 353 AC_CHECK_SIZEOF(int64_t)
 354 AC_CHECK_SIZEOF(off_t)
 355 AC_CHECK_SIZEOF(off64_t)
 356 AC_CHECK_SIZEOF(time_t)
 357
 358 AC_C_INLINE
 359 AC_C_LONG_DOUBLE
 360
 361 AC_TYPE_SIGNAL
 362 AC_TYPE_UID_T
 363 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 364 AC_TYPE_GETGROUPS
 365 AC_CHECK_MEMBERS([struct stat.st_rdev])
 366
 367 TYPE_SOCKLEN_T
 368
 369 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 370     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
 371         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
 372 if test x"$rsync_cv_errno" = x"yes"; then
 373    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 374 fi
 375
 376 # The following test taken from the cvs sources
 377 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 378 # These need checks to be before checks for any other functions that
 379 #    might be in the same libraries.
 380 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 381 # libsocket.so which has a bad implementation of gethostbyname (it
 382 # only looks in /etc/hosts), so we only look for -lsocket if we need
 383 # it.
 384 AC_CHECK_FUNCS(connect)
 385 if test x"$ac_cv_func_connect" = x"no"; then
 386     case "$LIBS" in
 387     *-lnsl*) ;;
 388     *) AC_CHECK_LIB(nsl_s, printf) ;;
 389     esac
 390     case "$LIBS" in
 391     *-lnsl*) ;;
 392     *) AC_CHECK_LIB(nsl, printf) ;;
 393     esac
 394     case "$LIBS" in
 395     *-lsocket*) ;;
 396     *) AC_CHECK_LIB(socket, connect) ;;
 397     esac
 398     case "$LIBS" in
 399     *-linet*) ;;
 400     *) AC_CHECK_LIB(inet, connect) ;;
 401     esac
 402     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 403     dnl has been cached.
 404     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 405        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 406         # ac_cv_func_connect=yes
 407         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 408         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 409     fi
 410 fi
 411
 412 AC_SEARCH_LIBS(inet_ntop, resolv)
 413
 414 # Solaris and HP-UX weirdness:
 415 # Search for libiconv_open (not iconv_open) to discover if -liconv is needed!
 416 AC_SEARCH_LIBS(libiconv_open, iconv)
 417
 418 AC_MSG_CHECKING([for iconv declaration])
 419 AC_CACHE_VAL(am_cv_proto_iconv, [
 420     AC_TRY_COMPILE([
 421 #include <stdlib.h>
 422 #include <iconv.h>
 423 extern
 424 #ifdef __cplusplus
 425 "C"
 426 #endif
 427 #if defined(__STDC__) || defined(__cplusplus)
 428 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 429 #else
 430 size_t iconv();
 431 #endif
 432 ], [], am_cv_proto_iconv_arg1="", am_cv_proto_iconv_arg1="const")
 433       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 434     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
 435 AC_MSG_RESULT([$]{ac_t:-
 436          }[$]am_cv_proto_iconv)
 437 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 438                    [Define as const if the declaration of iconv() needs const.])
 439
 440 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 441
 442 AC_CHECK_FUNCS(inet_ntop, , [AC_LIBOBJ(lib/inet_ntop)])
 443 AC_CHECK_FUNCS(inet_pton, , [AC_LIBOBJ(lib/inet_pton)])
 444
 445 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 446 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
 447 #include <sys/socket.h>])
 448
 449 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 450 #   builtin getaddrinfo if one of the defines don't exist
 451 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 452                rsync_cv_HAVE_GETADDR_DEFINES,[
 453                         AC_EGREP_CPP(yes, [
 454                         #include <sys/types.h>
 455                         #include <sys/socket.h>
 456                         #include <netdb.h>
 457                         #ifdef AI_PASSIVE
 458                         yes
 459                         #endif],
 460                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 461                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 462 if test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"; then
 463         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 464         # something else so we must include <netdb.h> to get the
 465         # redefinition.
 466         AC_CHECK_FUNCS(getaddrinfo, ,
 467                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 468                 AC_TRY_LINK([#include <sys/types.h>
 469                 #include <sys/socket.h>
 470                 #include <netdb.h>],[getaddrinfo(NULL, NULL, NULL, NULL);],
 471                         [AC_MSG_RESULT([yes])
 472                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 473                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],
 474                         [AC_MSG_RESULT([no])
 475                         AC_LIBOBJ(lib/getaddrinfo)])])
 476 else
 477         AC_LIBOBJ(lib/getaddrinfo)
 478 fi
 479
 480 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 481                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 482                 [],
 483                 [
 484 #include <sys/types.h>
 485 #include <sys/socket.h>
 486 ])
 487
 488 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 489                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 490                 [],
 491                 [
 492 #include <sys/types.h>
 493 #include <sys/socket.h>
 494 #include <netinet/in.h>
 495 ])
 496
 497 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 498                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 499                 [],
 500                 [
 501 #include <sys/types.h>
 502 #include <sys/socket.h>
 503 #include <netinet/in.h>
 504 ])
 505
 506 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 507                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 508                 [],
 509                 [
 510 #include <sys/types.h>
 511 #include <sys/socket.h>
 512 #include <netinet/in.h>
 513 ])
 514
 515 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 516 #if HAVE_SYS_TYPES_H
 517 # include <sys/types.h>
 518 #endif
 519 #if HAVE_SYS_STAT_H
 520 # include <sys/stat.h>
 521 #endif
 522 #if STDC_HEADERS
 523 # include <stdlib.h>
 524 # include <stddef.h>
 525 #else
 526 # if HAVE_STDLIB_H
 527 #  include <stdlib.h>
 528 # endif
 529 #endif
 530 ])
 531
 532 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 533 #
 534 AC_CHECK_FUNCS(strcasecmp)
 535 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 536     AC_CHECK_LIB(resolv, strcasecmp)
 537 fi
 538
 539 AC_CHECK_FUNCS(aclsort)
 540 if test x"$ac_cv_func_aclsort" = x"no"; then
 541     AC_CHECK_LIB(sec, aclsort)
 542 fi
 543
 544 dnl At the moment we don't test for a broken memcmp(), because all we
 545 dnl need to do is test for equality, not comparison, and it seems that
 546 dnl every platform has a memcmp that can do at least that.
 547 dnl AC_FUNC_MEMCMP
 548
 549 AC_FUNC_UTIME_NULL
 550 AC_FUNC_ALLOCA
 551 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 552     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 553     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 554     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 555     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 556     strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 557     extattr_get_link sigaction sigprocmask setattrlist)
 558
 559 dnl cygwin iconv.h defines iconv_open as libiconv_open
 560 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 561     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 562 fi
 563
 564 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 565 if test $ac_cv_func_getpgrp = yes; then
 566     AC_FUNC_GETPGRP
 567 fi
 568
 569 AC_ARG_ENABLE(iconv,
 570     AC_HELP_STRING([--disable-iconv],
 571             [disable rsync's --iconv option]),
 572     [], [enable_iconv=$ac_cv_func_iconv_open])
 573 AH_TEMPLATE([ICONV_OPTION],
 574 [Define if you want the --iconv option.  Specifing a value will set the
 575 default iconv setting (a NULL means no --iconv processing by default).])
 576 if test x"$enable_iconv" != x"no"; then
 577         if test x"$enable_iconv" = x"yes"; then
 578                 AC_DEFINE(ICONV_OPTION, NULL)
 579         else
 580                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 581         fi
 582         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 583 fi
 584
 585 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 586   AC_TRY_RUN([
 587 #if HAVE_UNISTD_H
 588 # include <unistd.h>
 589 #endif
 590 #include <stdlib.h>
 591 #include <errno.h>
 592     main() {
 593         char const *dangling_symlink = "conftest.dangle";
 594         unlink(dangling_symlink);
 595         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 596         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) exit(1);
 597         exit(0);
 598     }],
 599   rsync_cv_chown_modifies_symlink=yes,rsync_cv_chown_modifies_symlink=no,rsync_cv_chown_modifies_symlink=no)])
 600 if test $rsync_cv_chown_modifies_symlink = yes; then
 601   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 602 fi
 603
 604 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 605   AC_TRY_RUN([
 606 #if HAVE_UNISTD_H
 607 # include <unistd.h>
 608 #endif
 609 #include <stdlib.h>
 610 #include <errno.h>
 611 #define FILENAME "conftest.dangle"
 612     main() {
 613         unlink(FILENAME);
 614         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 615         if (link(FILENAME, FILENAME "2") < 0) exit(1);
 616         exit(0);
 617     }],
 618   rsync_cv_can_hardlink_symlink=yes,rsync_cv_can_hardlink_symlink=no,rsync_cv_can_hardlink_symlink=no)])
 619 if test $rsync_cv_can_hardlink_symlink = yes; then
 620   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 621 fi
 622
 623 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 624   AC_TRY_RUN([
 625 #if HAVE_UNISTD_H
 626 # include <unistd.h>
 627 #endif
 628 #include <stdlib.h>
 629 #include <errno.h>
 630 #define FILENAME "conftest.fifi"
 631     main() {
 632         unlink(FILENAME);
 633         if (mkfifo(FILENAME, 0777) < 0) abort();
 634         if (link(FILENAME, FILENAME "2") < 0) exit(1);
 635         exit(0);
 636     }],
 637   rsync_cv_can_hardlink_special=yes,rsync_cv_can_hardlink_special=no,rsync_cv_can_hardlink_special=no)])
 638 if test $rsync_cv_can_hardlink_special = yes; then
 639     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 640 fi
 641
 642 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 643 AC_TRY_RUN([
 644 #include <sys/types.h>
 645 #include <sys/socket.h>
 646
 647 main() {
 648        int fd[2];
 649        exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
 650 }],
 651 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
 652 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 653     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 654 fi
 655
 656 if test x"$with_included_popt" != x"yes"; then
 657     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 658 fi
 659 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
 660     # If the system has /usr/include/popt/popt.h, we enable the
 661     # included popt because an attempt to "#include <popt/popt.h>"
 662     # would use our included header file anyway (due to -I.), and
 663     # might conflict with the system popt.
 664     with_included_popt=yes
 665 elif test x"$ac_cv_header_popt_h" != x"yes"; then
 666     with_included_popt=yes
 667 fi
 668
 669 AC_MSG_CHECKING([whether to use included libpopt])
 670 if test x"$with_included_popt" = x"yes"; then
 671     AC_MSG_RESULT($srcdir/popt)
 672     BUILD_POPT='$(popt_OBJS)'
 673     CFLAGS="$CFLAGS -I$srcdir/popt"
 674     if test x"$ALLOCA" != x
 675     then
 676         # this can be removed when/if we add an included alloca.c;
 677         #  see autoconf documentation on AC_FUNC_ALLOCA
 678         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 679     fi
 680 else
 681     AC_MSG_RESULT(no)
 682 fi
 683
 684 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
 685 AC_TRY_COMPILE([],[signed char *s = ""],
 686 rsync_cv_SIGNED_CHAR_OK=yes,rsync_cv_SIGNED_CHAR_OK=no)])
 687 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
 688     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
 689 fi
 690
 691 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 692 AC_TRY_RUN([#include <sys/types.h>
 693 #include <dirent.h>
 694 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 695 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 696 di->d_name[0] == 0) exit(0); exit(1);} ],
 697 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
 698 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 699     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
 700 fi
 701
 702 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
 703 AC_TRY_COMPILE([#include <sys/types.h>
 704 #include <utime.h>],
 705 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 706 rsync_cv_HAVE_STRUCT_UTIMBUF=yes,rsync_cv_HAVE_STRUCT_UTIMBUF=no)])
 707 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
 708     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
 709 fi
 710
 711 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 712 AC_TRY_COMPILE([#include <sys/time.h>
 713 #include <unistd.h>],
 714 [struct timeval tv; exit(gettimeofday(&tv, NULL));],
 715 rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no)])
 716 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
 717     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
 718 fi
 719
 720 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 721 AC_TRY_RUN([
 722 #include <sys/types.h>
 723 #include <stdarg.h>
 724 void foo(const char *format, ...) {
 725        va_list ap;
 726        int len;
 727        char buf[5];
 728
 729        va_start(ap, format);
 730        len = vsnprintf(0, 0, format, ap);
 731        va_end(ap);
 732        if (len != 5) exit(1);
 733
 734        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 735
 736        exit(0);
 737 }
 738 main() { foo("hello"); }
 739 ],
 740 rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)])
 741 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 742     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
 743 fi
 744
 745
 746 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 747 AC_TRY_RUN([#include <stdlib.h>
 748 #include <sys/types.h>
 749 #include <sys/stat.h>
 750 #include <unistd.h>
 751 main() {
 752   struct stat st;
 753   char tpl[20]="/tmp/test.XXXXXX";
 754   int fd = mkstemp(tpl);
 755   if (fd == -1) exit(1);
 756   unlink(tpl);
 757   if (fstat(fd, &st) != 0) exit(1);
 758   if ((st.st_mode & 0777) != 0600) exit(1);
 759   exit(0);
 760 }],
 761 rsync_cv_HAVE_SECURE_MKSTEMP=yes,
 762 rsync_cv_HAVE_SECURE_MKSTEMP=no,
 763 rsync_cv_HAVE_SECURE_MKSTEMP=cross)])
 764 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 765     case $target_os in
 766     hpux*)
 767         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
 768         dnl so we noisily skip using it.  See HP change request JAGaf34426
 769         dnl for details. (sbonds)
 770         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
 771         ;;
 772     *)
 773         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
 774         ;;
 775     esac
 776 fi
 777
 778
 779 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
 780 AC_TRY_RUN([
 781 #include <stdio.h>
 782 #include <sys/stat.h>
 783 #include <errno.h>
 784 main() { int rc, ec; char *fn = "fifo-test";
 785 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
 786 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 787 return 0;}],
 788            rsync_cv_MKNOD_CREATES_FIFOS=yes,rsync_cv_MKNOD_CREATES_FIFOS=no,rsync_cv_MKNOD_CREATES_FIFOS=cross)])
 789 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
 790     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
 791 fi
 792
 793 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
 794 AC_TRY_RUN([
 795 #include <stdio.h>
 796 #include <sys/stat.h>
 797 #include <errno.h>
 798 main() { int rc, ec; char *fn = "sock-test";
 799 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
 800 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 801 return 0;}],
 802            rsync_cv_MKNOD_CREATES_SOCKETS=yes,rsync_cv_MKNOD_CREATES_SOCKETS=no,rsync_cv_MKNOD_CREATES_SOCKETS=cross)])
 803 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
 804     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
 805 fi
 806
 807 #
 808 # The following test was mostly taken from the tcl/tk plus patches
 809 #
 810 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 811 rm -rf conftest*
 812 cat > conftest.$ac_ext <<EOF
 813 int main() { return 0; }
 814 EOF
 815 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 816 if test -f conftest..o; then
 817     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 818 else
 819     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 820 fi
 821 rm -rf conftest*
 822 ])
 823 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 824     OBJ_SAVE="#"
 825     OBJ_RESTORE="#"
 826     CC_SHOBJ_FLAG='-o $@'
 827 else
 828     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 829     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 830     CC_SHOBJ_FLAG=""
 831 fi
 832
 833 AC_SUBST(OBJ_SAVE)
 834 AC_SUBST(OBJ_RESTORE)
 835 AC_SUBST(CC_SHOBJ_FLAG)
 836 AC_SUBST(BUILD_POPT)
 837 AC_SUBST(MAKE_MAN)
 838
 839 AC_CHECK_FUNCS(_acl __acl _facl __facl)
 840 #################################################
 841 # check for ACL support
 842
 843 AC_MSG_CHECKING([whether to support ACLs])
 844 AC_ARG_ENABLE(acl-support,
 845         AC_HELP_STRING([--disable-acl-support],
 846                        [disable ACL support]))
 847
 848 if test x"$enable_acl_support" = x"no"; then
 849     AC_MSG_RESULT(no)
 850 else
 851     case "$host_os" in
 852     *sysv5*)
 853         AC_MSG_RESULT(Using UnixWare ACLs)
 854         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
 855         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
 856         ;;
 857     *solaris*|*cygwin*)
 858         AC_MSG_RESULT(Using solaris ACLs)
 859         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
 860         AC_DEFINE(SUPPORT_ACLS, 1)
 861         ;;
 862     *hpux*)
 863         AC_MSG_RESULT(Using HPUX ACLs)
 864         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
 865         AC_DEFINE(SUPPORT_ACLS, 1)
 866         ;;
 867     *irix*)
 868         AC_MSG_RESULT(Using IRIX ACLs)
 869         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
 870         AC_DEFINE(SUPPORT_ACLS, 1)
 871         ;;
 872     *aix*)
 873         AC_MSG_RESULT(Using AIX ACLs)
 874         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
 875         AC_DEFINE(SUPPORT_ACLS, 1)
 876         ;;
 877     *osf*)
 878         AC_MSG_RESULT(Using Tru64 ACLs)
 879         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
 880         AC_DEFINE(SUPPORT_ACLS, 1)
 881         LIBS="$LIBS -lpacl"
 882         ;;
 883     darwin*)
 884         AC_MSG_RESULT(Using OS X ACLs)
 885         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
 886         AC_DEFINE(SUPPORT_ACLS, 1)
 887         ;;
 888     *)
 889         AC_MSG_RESULT(running tests:)
 890         AC_CHECK_LIB(acl,acl_get_file)
 891             AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
 892             AC_TRY_LINK([#include <sys/types.h>
 893 #include <sys/acl.h>],
 894 [ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);],
 895 samba_cv_HAVE_POSIX_ACLS=yes,samba_cv_HAVE_POSIX_ACLS=no)])
 896         AC_MSG_CHECKING(ACL test results)
 897         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
 898             AC_MSG_RESULT(Using posix ACLs)
 899             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
 900             AC_DEFINE(SUPPORT_ACLS, 1)
 901             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
 902                 AC_TRY_LINK([#include <sys/types.h>
 903 #include <sys/acl.h>],
 904 [ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);],
 905 samba_cv_HAVE_ACL_GET_PERM_NP=yes,samba_cv_HAVE_ACL_GET_PERM_NP=no)])
 906             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
 907                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
 908             fi
 909         else
 910             if test x"$enable_acl_support" = x"yes"; then
 911                 AC_MSG_ERROR(Failed to find ACL support)
 912             else
 913                 AC_MSG_RESULT(No ACL support found)
 914             fi
 915         fi
 916         ;;
 917     esac
 918 fi
 919
 920 #################################################
 921 # check for extended attribute support
 922 AC_MSG_CHECKING(whether to support extended attributes)
 923 AC_ARG_ENABLE(xattr-support,
 924     AC_HELP_STRING([--disable-xattr-support],
 925             [disable extended attributes]),
 926     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link" in
 927         *yes*) enable_xattr_support=maybe ;;
 928         *) enable_xattr_support=no ;;
 929         esac])
 930 AH_TEMPLATE([SUPPORT_XATTRS],
 931 [Define to 1 to add support for extended attributes])
 932 if test x"$enable_xattr_support" = x"no"; then
 933     AC_MSG_RESULT(no)
 934 else
 935     case "$host_os" in
 936     *linux*)
 937         AC_MSG_RESULT(Using Linux xattrs)
 938         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs])
 939         AC_DEFINE(SUPPORT_XATTRS, 1)
 940         ;;
 941     darwin*)
 942         AC_MSG_RESULT(Using OS X xattrs)
 943         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
 944         AC_DEFINE(SUPPORT_XATTRS, 1)
 945         ;;
 946     freebsd*)
 947         AC_MSG_RESULT(Using FreeBSD extattrs)
 948         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
 949         AC_DEFINE(SUPPORT_XATTRS, 1)
 950         ;;
 951     *)
 952         if test x"$enable_xattr_support" = x"yes"; then
 953             AC_MSG_ERROR(Failed to find extended attribute support)
 954         else
 955             AC_MSG_RESULT(No extended attribute support found)
 956         fi
 957         ;;
 958     esac
 959 fi
 960
 961 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
 962     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
 963     OLD_CFLAGS="$CFLAGS"
 964     CFLAGS="$CFLAGS -Wno-unused-parameter"
 965     AC_COMPILE_IFELSE([ ], [rsync_warn_flag=yes], [rsync_warn_flag=no])
 966     AC_MSG_RESULT([$rsync_warn_flag])
 967     if test x"$rsync_warn_flag" = x"no"; then
 968         CFLAGS="$OLD_CFLAGS"
 969     fi
 970 fi
 971
 972 case "$CC" in
 973 ' checker'*|checker*)
 974     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
 975     ;;
 976 esac
 977
 978 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
 979 AC_OUTPUT
 980
 981 AC_MSG_RESULT()
 982 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
 983 AC_MSG_RESULT()