configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([rsync],[3.2.1pre1],[https://rsync.samba.org/bugtracking.html])
   4
   5 AC_CONFIG_MACRO_DIR([m4])
   6 AC_CONFIG_SRCDIR([byteorder.h])
   7 AC_CONFIG_HEADER(config.h)
   8 AC_PREREQ([2.69])
   9
  10 AC_SUBST(RSYNC_VERSION, $PACKAGE_VERSION)
  11 AC_MSG_NOTICE([Configuring rsync $PACKAGE_VERSION])
  12
  13 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$PACKAGE_VERSION"], [rsync release version])
  14
  15 LDFLAGS=${LDFLAGS-""}
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl define the directory for replacement function since AC_LIBOBJ does not
  20 dnl officially support subdirs and fails with automake
  21 AC_CONFIG_LIBOBJ_DIR([lib])
  22
  23 # We must decide this before testing the compiler.
  24
  25 # Please allow this to default to yes, so that your users have more
  26 # chance of getting a useful stack trace if problems occur.
  27
  28 AC_MSG_CHECKING([whether to include debugging symbols])
  29 AC_ARG_ENABLE(debug,
  30         AS_HELP_STRING([--disable-debug],[disable debugging symbols and features]))
  31
  32 if test x"$enable_debug" = x"no"; then
  33     AC_MSG_RESULT(no)
  34     ac_cv_prog_cc_g=no
  35 else
  36     AC_MSG_RESULT([yes])
  37     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  38     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  39 fi
  40
  41 dnl Checks for programs.
  42 AC_PROG_CC
  43 AC_PROG_CPP
  44 AC_PROG_CXX
  45 AC_PROG_AWK
  46 AC_PROG_EGREP
  47 AC_PROG_INSTALL
  48 AC_PROG_MKDIR_P
  49 AC_PROG_CC_STDC
  50 AC_SUBST(SHELL)
  51 AC_PATH_PROG([PERL], [perl])
  52 AC_PATH_PROG([PYTHON3], [python3])
  53
  54 AC_DEFINE([_GNU_SOURCE], 1,
  55           [Define _GNU_SOURCE so that we get all necessary prototypes])
  56
  57 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  58         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  59 fi
  60
  61 AC_ARG_ENABLE(profile,
  62         AS_HELP_STRING([--enable-profile],[turn on CPU profiling]))
  63 if test x"$enable_profile" = x"yes"; then
  64         CFLAGS="$CFLAGS -pg"
  65 fi
  66
  67 AC_MSG_CHECKING([if md2man can create man pages])
  68 if test x"$ac_cv_path_PYTHON3" = x; then
  69     AC_MSG_RESULT(no - python3 not found)
  70     md2man_works=no
  71 else
  72     md2man_out=`"$srcdir/md2man" --test "$srcdir/rsync-ssl.1.md" 2>&1`
  73     if test $? = 0; then
  74         AC_MSG_RESULT(yes)
  75         md2man_works=yes
  76     else
  77         AC_MSG_RESULT(no)
  78         md2man_works=no
  79         echo "$md2man_out"
  80     fi
  81 fi
  82
  83 AC_MSG_CHECKING([if we require man-page building])
  84 AC_ARG_ENABLE([md2man],
  85         AS_HELP_STRING([--disable-md2man],[disable md2man for man page creation]))
  86 if test x"$enable_md2man" != x"no"; then
  87     if test -f "$srcdir/rsync.1"; then
  88         AC_MSG_RESULT(optional)
  89     else
  90         AC_MSG_RESULT(required)
  91         if test x"$md2man_works" = x"no"; then
  92             AC_MSG_ERROR(You need python3 and the cmarkgfm OR commonmark python3 lib in order to build man pages.
  93 You can specify --disable-md2man if you want to skip building them.)
  94         fi
  95     fi
  96     MAKE_MAN=man
  97 else
  98     AC_MSG_RESULT(no)
  99     MAKE_MAN=''
 100 fi
 101
 102 # Specifically, this turns on panic_action handling.
 103 AC_ARG_ENABLE(maintainer-mode,
 104         AS_HELP_STRING([--enable-maintainer-mode],[turn on extra debug features]))
 105 if test x"$enable_maintainer_mode" = x"yes"; then
 106         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
 107 fi
 108
 109 # This is needed for our included version of popt.  Kind of silly, but
 110 # I don't want our version too far out of sync.
 111 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
 112
 113 # If GCC, turn on warnings.
 114 if test x"$GCC" = x"yes"; then
 115         CFLAGS="$CFLAGS -Wall -W"
 116 fi
 117
 118 AC_ARG_WITH(included-popt,
 119         AS_HELP_STRING([--with-included-popt],[use bundled popt library, not from system]))
 120
 121 AC_ARG_WITH(included-zlib,
 122         AS_HELP_STRING([--with-included-zlib],[use bundled zlib library, not from system]))
 123
 124 AC_ARG_WITH(protected-args,
 125         AS_HELP_STRING([--with-protected-args],[make --protected-args option the default]))
 126 if test x"$with_protected_args" = x"yes"; then
 127         AC_DEFINE_UNQUOTED(RSYNC_USE_PROTECTED_ARGS, 1, [Define to 1 if --protected-args should be the default])
 128 fi
 129
 130 AC_ARG_WITH(rsync-path,
 131         AS_HELP_STRING([--with-rsync-path=PATH],[set default --rsync-path to PATH (default: rsync)]),
 132         [ RSYNC_PATH="$with_rsync_path" ],
 133         [ RSYNC_PATH="rsync" ])
 134
 135 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
 136
 137 AC_ARG_WITH(rsyncd-conf,
 138         AS_HELP_STRING([--with-rsyncd-conf=PATH],[set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 139         [ if test ! -z "$with_rsyncd_conf" ; then
 140                 case $with_rsyncd_conf in
 141                         yes|no)
 142                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 143                                 ;;
 144                         /*)
 145                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 146                                 ;;
 147                         *)
 148                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 149                                 ;;
 150                 esac
 151         else
 152                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 153         fi ],
 154         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 155
 156 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 157
 158 AC_ARG_WITH(rsh,
 159         AS_HELP_STRING([--with-rsh=CMD],[set remote shell command to CMD (default: ssh)]))
 160
 161 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 162 if test x$HAVE_REMSH = x1; then
 163         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 164 fi
 165
 166 if test x"$with_rsh" != x; then
 167         RSYNC_RSH="$with_rsh"
 168 else
 169         RSYNC_RSH="ssh"
 170 fi
 171 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 172
 173 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 174 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 175 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 176
 177 AC_ARG_WITH(nobody-group,
 178     AS_HELP_STRING([--with-nobody-group=GROUP],[set the default unprivileged group (default nobody or nogroup)]),
 179     [ NOBODY_GROUP="$with_nobody_group" ])
 180
 181 if test x"$with_nobody_group" = x; then
 182     AC_MSG_CHECKING([the group for user "nobody"])
 183     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 184         NOBODY_GROUP=nobody
 185     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 186         NOBODY_GROUP=nogroup
 187     else
 188         NOBODY_GROUP=nobody # test for others?
 189     fi
 190     AC_MSG_RESULT($NOBODY_GROUP)
 191 fi
 192
 193 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 194 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 195
 196 # SIMD optimizations
 197 SIMD=
 198
 199 AC_MSG_CHECKING([whether to enable SIMD optimizations])
 200 AC_ARG_ENABLE(simd,
 201     AS_HELP_STRING([--disable-simd],[disable SIMD optimizations (requires c++)]))
 202
 203 # Clag is crashing with -g -O2, so we'll get rid of -g for now.
 204 CXXFLAGS=`echo "$CXXFLAGS" | sed 's/-g //'`
 205
 206 if test x"$enable_simd" != x"no"; then
 207     # For x86-64 SIMD, g++ >=5 or clang++ >=7 is required
 208     if test x"$build_cpu" = x"x86_64"; then
 209         AC_LANG(C++)
 210         AC_RUN_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 211 #include <immintrin.h>
 212 __attribute__ ((target("default"))) int test_ssse3(int x) { return x; }
 213 __attribute__ ((target("default"))) int test_sse2(int x) { return x; }
 214 __attribute__ ((target("default"))) int test_avx2(int x) { return x; }
 215 __attribute__ ((target("ssse3"))) int test_ssse3(int x) { return x; }
 216 __attribute__ ((target("sse2"))) int test_sse2(int x) { return x; }
 217 __attribute__ ((target("avx2"))) int test_avx2(int x) { return x; }
 218 typedef long long __m128i_u __attribute__((__vector_size__(16), __may_alias__, __aligned__(1)));
 219 typedef long long __m256i_u __attribute__((__vector_size__(32), __may_alias__, __aligned__(1)));
 220 __attribute__ ((target("default"))) void more_testing(char* buf, int len) { }
 221 __attribute__ ((target("ssse3"))) void more_testing(char* buf, int len)
 222 {
 223     int i;
 224     for (i = 0; i < (len-32); i+=32) {
 225         __m128i in8_1, in8_2;
 226         in8_1 = _mm_lddqu_si128((__m128i_u*)&buf[i]);
 227         in8_2 = _mm_lddqu_si128((__m128i_u*)&buf[i + 16]);
 228     }
 229 }
 230 ]], [[if (test_ssse3(42) != 42 || test_sse2(42) != 42 || test_avx2(42) != 42) exit(1);]])],[CXX_OK=yes],[CXX_OK=no])
 231         AC_LANG(C)
 232         if test x"$CXX_OK" = x"yes"; then
 233             # AC_MSG_RESULT() is called below.
 234             SIMD="x86_64"
 235         elif test x"$enable_simd" = x"yes"; then
 236             AC_MSG_RESULT(error)
 237             AC_MSG_ERROR(The SIMD compilation test failed.
 238 Omit --enable-simd to continue without it.)
 239         fi
 240     elif test x"$enable_simd" = x"yes"; then
 241         AC_MSG_RESULT(unavailable)
 242         AC_MSG_ERROR(The SIMD optimizations are currently x86_64 only.
 243 Omit --enable-simd to continue without it.)
 244     fi
 245 fi
 246
 247 if test x"$SIMD" != x""; then
 248     AC_MSG_RESULT([yes ($SIMD)])
 249     AC_DEFINE(HAVE_SIMD, 1, [Define to 1 to enable SIMD optimizations])
 250     SIMD='$(SIMD_'"$SIMD)"
 251     # We only use c++ for its target attribute dispatching, disable unneeded bulky features
 252     CXXFLAGS="$CXXFLAGS -fno-exceptions -fno-rtti"
 253     # Apple often has "g++" as a symlink for clang. Try to find out the truth.
 254     CXX_VERSION=`$CXX --version 2>/dev/null | head -n 2`
 255     case "$CXX_VERSION" in
 256     *clang*) CXXFLAGS="$CXXFLAGS -fno-slp-vectorize" ;; # avoid a performance hit
 257     esac
 258 else
 259     AC_MSG_RESULT(no)
 260 fi
 261
 262 AC_SUBST(SIMD)
 263
 264 AC_MSG_CHECKING([if assembler accepts noexecstack])
 265 OLD_CFLAGS="$CFLAGS"
 266 CFLAGS="$CFLAGS -Wa,--noexecstack"
 267 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ ]], [[return 0;]])],
 268 [ NOEXECSTACK='-Wa,--noexecstack' ; AC_MSG_RESULT(yes) ],
 269 [ NOEXECSTACK='' ; AC_MSG_RESULT(no) ])
 270 CFLAGS="$OLD_CFLAGS"
 271 AC_SUBST(NOEXECSTACK)
 272
 273 ASM=
 274
 275 AC_MSG_CHECKING([whether to enable ASM optimizations])
 276 AC_ARG_ENABLE(asm,
 277     AS_HELP_STRING([--disable-asm],[disable ASM optimizations]))
 278
 279 if test x"$enable_asm" != x"no"; then
 280     if test x"$build_cpu" = x"x86_64"; then
 281         ASM="$build_cpu"
 282     elif test x"$enable_asm" = x"yes"; then
 283         AC_MSG_RESULT(unavailable)
 284         AC_MSG_ERROR(The ASM optimizations are currently x86_64 only.
 285 Omit --enable-asm to continue without it.)
 286     fi
 287 fi
 288
 289 if test x"$ASM" != x""; then
 290     AC_MSG_RESULT([yes ($ASM)])
 291     AC_DEFINE(HAVE_ASM, 1, [Define to 1 to enable ASM optimizations])
 292     ASM='$(ASM_'"$ASM)"
 293 else
 294     AC_MSG_RESULT(no)
 295 fi
 296
 297 AC_SUBST(ASM)
 298
 299 # arrgh. libc in some old debian version screwed up the largefile
 300 # stuff, getting byte range locking wrong
 301 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 302 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 303 #define _FILE_OFFSET_BITS 64
 304 #include <stdio.h>
 305 #include <fcntl.h>
 306 #include <sys/types.h>
 307 #include <sys/wait.h>
 308 #if HAVE_UNISTD_H
 309 #include <unistd.h>
 310 #endif
 311
 312 int main(void)
 313 {
 314         struct flock lock;
 315         int status;
 316         char tpl[32] = "/tmp/locktest.XXXXXX";
 317         int fd = mkstemp(tpl);
 318         if (fd < 0) {
 319                 strcpy(tpl, "conftest.dat");
 320                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 321         }
 322
 323         lock.l_type = F_WRLCK;
 324         lock.l_whence = SEEK_SET;
 325         lock.l_start = 0;
 326         lock.l_len = 1;
 327         lock.l_pid = 0;
 328         fcntl(fd,F_SETLK,&lock);
 329         if (fork() == 0) {
 330                 lock.l_start = 1;
 331                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 332         }
 333         wait(&status);
 334         unlink(tpl);
 335         return WEXITSTATUS(status);
 336 }
 337 ]])],[rsync_cv_HAVE_BROKEN_LARGEFILE=yes],[rsync_cv_HAVE_BROKEN_LARGEFILE=no],[rsync_cv_HAVE_BROKEN_LARGEFILE=cross])])
 338 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 339    AC_SYS_LARGEFILE
 340 fi
 341
 342 ipv6type=unknown
 343 ipv6lib=none
 344 ipv6trylibc=yes
 345
 346 AC_ARG_ENABLE(ipv6,
 347         AS_HELP_STRING([--disable-ipv6],[turn off IPv6 support]))
 348 if test x"$enable_ipv6" != x"no"; then
 349         AC_MSG_CHECKING([ipv6 stack type])
 350         for i in inria kame linux-glibc linux-inet6 solaris toshiba v6d zeta cygwin; do
 351                 case $i in
 352                 inria)
 353                         # http://www.kame.net/
 354                         AC_EGREP_CPP(yes, [
 355 #include <netinet/in.h>
 356 #ifdef IPV6_INRIA_VERSION
 357 yes
 358 #endif],
 359                                 [ipv6type=$i;
 360                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 361                                 ])
 362                         ;;
 363                 kame)
 364                         # http://www.kame.net/
 365                         AC_EGREP_CPP(yes, [
 366 #include <netinet/in.h>
 367 #ifdef __KAME__
 368 yes
 369 #endif],
 370                                 [ipv6type=$i;
 371                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 372                         ;;
 373                 linux-glibc)
 374                         # http://www.v6.linux.or.jp/
 375                         AC_EGREP_CPP(yes, [
 376 #include <features.h>
 377 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 378 yes
 379 #endif],
 380                                 [ipv6type=$i;
 381 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 382                         ;;
 383                 linux-inet6)
 384                         # http://www.v6.linux.or.jp/
 385                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 386                                 ipv6type=$i
 387                                 ipv6lib=inet6
 388                                 ipv6libdir=/usr/inet6/lib
 389                                 ipv6trylibc=yes;
 390                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 391                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 392                         fi
 393                         ;;
 394                 solaris)
 395                         # http://www.sun.com
 396                         AC_EGREP_CPP(yes, [
 397 #include <netinet/ip6.h>
 398 #ifdef __sun
 399 yes
 400 #endif],
 401                                 [ipv6type=$i;
 402                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 403                         ;;
 404                 toshiba)
 405                         AC_EGREP_CPP(yes, [
 406 #include <sys/param.h>
 407 #ifdef _TOSHIBA_INET6
 408 yes
 409 #endif],
 410                                 [ipv6type=$i;
 411                                 ipv6lib=inet6;
 412                                 ipv6libdir=/usr/local/v6/lib;
 413                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 414                         ;;
 415                 v6d)
 416                         AC_EGREP_CPP(yes, [
 417 #include </usr/local/v6/include/sys/v6config.h>
 418 #ifdef __V6D__
 419 yes
 420 #endif],
 421                                 [ipv6type=$i;
 422                                 ipv6lib=v6;
 423                                 ipv6libdir=/usr/local/v6/lib;
 424                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 425                         ;;
 426                 zeta)
 427                         AC_EGREP_CPP(yes, [
 428 #include <sys/param.h>
 429 #ifdef _ZETA_MINAMI_INET6
 430 yes
 431 #endif],
 432                                 [ipv6type=$i;
 433                                 ipv6lib=inet6;
 434                                 ipv6libdir=/usr/local/v6/lib;
 435                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 436                         ;;
 437                 cygwin)
 438                         AC_EGREP_CPP(yes, [
 439 #include <netinet/in.h>
 440 #ifdef _CYGWIN_IN6_H
 441 yes
 442 #endif],
 443                                 [ipv6type=$i;
 444                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 445                         ;;
 446                 esac
 447                 if test "$ipv6type" != "unknown"; then
 448                         break
 449                 fi
 450         done
 451         AC_MSG_RESULT($ipv6type)
 452
 453         AC_SEARCH_LIBS(getaddrinfo, inet6)
 454 fi
 455
 456 dnl Do you want to disable use of locale functions
 457 AC_ARG_ENABLE([locale],
 458         AS_HELP_STRING([--disable-locale],[disable locale features]))
 459 AH_TEMPLATE([CONFIG_LOCALE],
 460 [Undefine if you do not want locale features.  By default this is defined.])
 461 if test x"$enable_locale" != x"no"; then
 462         AC_DEFINE(CONFIG_LOCALE)
 463 fi
 464
 465 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 466 case $host_os in
 467         *cygwin* ) AC_MSG_RESULT(yes)
 468                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 469                             [Define to 1 if sockets need to be shutdown])
 470                    ;;
 471                * ) AC_MSG_RESULT(no);;
 472 esac
 473
 474 AC_C_BIGENDIAN
 475 AC_HEADER_DIRENT
 476 AC_HEADER_TIME
 477 AC_HEADER_SYS_WAIT
 478 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 479     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 480     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 481     sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 482     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
 483     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h \
 484     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netinet/ip.h \
 485     zlib.h xxhash.h openssl/md4.h openssl/md5.h zstd.h lz4.h)
 486 AC_HEADER_MAJOR_FIXED
 487
 488 AC_MSG_CHECKING([whether to enable use of openssl crypto library])
 489 AC_ARG_ENABLE([openssl],
 490         AS_HELP_STRING([--disable-openssl],[disable openssl crypto library]))
 491 AH_TEMPLATE([USE_OPENSSL],
 492 [Undefine if you do not want to use openssl crypto library.  By default this is defined.])
 493 if test x"$enable_openssl" != x"no"; then
 494     if test x"$ac_cv_header_openssl_md4_h" = x"yes" && test x"$ac_cv_header_openssl_md5_h" = x"yes"; then
 495       AC_MSG_RESULT(yes)
 496       AC_SEARCH_LIBS(MD5_Init, crypto,
 497           [AC_DEFINE(USE_OPENSSL)],
 498           [AC_MSG_ERROR(Failed to find MD5_Init function in openssl crypto lib.
 499 Use --disable-openssl to continue without openssl crypto lib support.)])
 500     else
 501         AC_MSG_RESULT(no)
 502         AC_MSG_ERROR(Failed to find openssl/md4.h and openssl/md5.h for openssl crypto lib support.
 503 Use --disable-openssl to continue without it.)
 504     fi
 505 else
 506     AC_MSG_RESULT(no)
 507 fi
 508
 509 AC_MSG_CHECKING([whether to enable xxhash checksum support])
 510 AC_ARG_ENABLE([xxhash],
 511         AS_HELP_STRING([--disable-xxhash],[disable xxhash checksums]))
 512 AH_TEMPLATE([SUPPORT_XXHASH],
 513 [Undefine if you do not want xxhash checksums.  By default this is defined.])
 514 if test x"$enable_xxhash" != x"no"; then
 515     if test x"$ac_cv_header_xxhash_h" = x"yes"; then
 516         AC_MSG_RESULT(yes)
 517         AC_SEARCH_LIBS(XXH64_createState, xxhash,
 518             [AC_DEFINE(SUPPORT_XXHASH)],
 519             [AC_MSG_ERROR(Failed to find XXH64_createState function in xxhash lib.
 520 Use --disable-xxhash to continue without xxhash checksums.)])
 521     else
 522         AC_MSG_RESULT(no)
 523         AC_MSG_ERROR(Failed to find xxhash.h for xxhash checksum support.
 524 Use --disable-xxhash to continue without it.)
 525     fi
 526 else
 527     AC_MSG_RESULT(no)
 528 fi
 529
 530 AC_MSG_CHECKING([whether to enable zstd compression])
 531 AC_ARG_ENABLE([zstd],
 532         AC_HELP_STRING([--disable-zstd], [disable zstd compression]))
 533 AH_TEMPLATE([SUPPORT_ZSTD],
 534 [Undefine if you do not want zstd compression.  By default this is defined.])
 535 if test x"$enable_zstd" != x"no"; then
 536     if test x"$ac_cv_header_zstd_h" = x"yes"; then
 537         AC_MSG_RESULT(yes)
 538         AC_SEARCH_LIBS(ZSTD_minCLevel, zstd,
 539             [AC_DEFINE(SUPPORT_ZSTD)],
 540             [AC_MSG_ERROR(Failed to find ZSTD_minCLevel function in zstd lib.
 541 Use --disable-zstd to continue without zstd compression.)])
 542     else
 543         AC_MSG_RESULT(no)
 544         AC_MSG_ERROR(Failed to find zstd.h for zstd compression support.
 545 Use --disable-zstd to continue without it.)
 546     fi
 547 else
 548     AC_MSG_RESULT(no)
 549 fi
 550
 551 AC_MSG_CHECKING([whether to enable LZ4 compression])
 552 AC_ARG_ENABLE([lz4],
 553         AC_HELP_STRING([--disable-lz4], [disable LZ4 compression]))
 554 AH_TEMPLATE([SUPPORT_LZ4],
 555 [Undefine if you do not want LZ4 compression.  By default this is defined.])
 556 if test x"$enable_lz4" != x"no"; then
 557     if test x"$ac_cv_header_lz4_h" = x"yes"; then
 558         AC_MSG_RESULT(yes)
 559         AC_SEARCH_LIBS(LZ4_compress_default, lz4,
 560             [AC_DEFINE(SUPPORT_LZ4)],
 561             [AC_MSG_ERROR(Failed to find LZ4_compress_default function in lz4 lib.
 562 Use --disable-lz4 to continue without lz4 compression.)])
 563     else
 564         AC_MSG_RESULT(no)
 565         AC_MSG_ERROR(Failed to find lz4.h for lz4 compression support.
 566 Use --disable-lz4 to continue without it.)
 567     fi
 568 else
 569     AC_MSG_RESULT(no)
 570 fi
 571
 572 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 573 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 574 #include <sys/types.h>
 575 #ifdef MAJOR_IN_MKDEV
 576 #include <sys/mkdev.h>
 577 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 578 #  define makedev mkdev
 579 # endif
 580 #elif defined MAJOR_IN_SYSMACROS
 581 #include <sys/sysmacros.h>
 582 #endif
 583
 584 int main(void)
 585 {
 586         dev_t dev = makedev(0, 5, 7);
 587         if (major(dev) != 5 || minor(dev) != 7)
 588                 return 1;
 589         return 0;
 590 }
 591 ]])],[rsync_cv_MAKEDEV_TAKES_3_ARGS=yes],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no])])
 592 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 593    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 594 fi
 595
 596 AC_CHECK_SIZEOF(int)
 597 AC_CHECK_SIZEOF(long)
 598 AC_CHECK_SIZEOF(long long)
 599 AC_CHECK_SIZEOF(short)
 600 AC_CHECK_SIZEOF(int16_t)
 601 AC_CHECK_SIZEOF(uint16_t)
 602 AC_CHECK_SIZEOF(int32_t)
 603 AC_CHECK_SIZEOF(uint32_t)
 604 AC_CHECK_SIZEOF(int64_t)
 605 AC_CHECK_SIZEOF(off_t)
 606 AC_CHECK_SIZEOF(off64_t)
 607 AC_CHECK_SIZEOF(time_t)
 608 AC_CHECK_SIZEOF(char*)
 609
 610 AC_C_INLINE
 611
 612 AC_TYPE_LONG_DOUBLE_WIDER
 613 ac_cv_c_long_double=$ac_cv_type_long_double_wider
 614 if test $ac_cv_c_long_double = yes; then
 615   AC_DEFINE([HAVE_LONG_DOUBLE],[1],[Define to 1 if the type `long double' works and has more range or precision than `double'.])
 616 fi
 617
 618 AC_TYPE_UID_T
 619 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 620 AC_TYPE_GETGROUPS
 621 AC_CHECK_MEMBERS([struct stat.st_rdev,
 622                   struct stat.st_mtimensec,
 623                   struct stat.st_mtimespec.tv_nsec,
 624                   struct stat.st_mtim.tv_nsec],,,[
 625 #ifdef HAVE_SYS_TYPES_H
 626 #include <sys/types.h>
 627 #endif
 628 #ifdef HAVE_SYS_STAT_H
 629 #include <sys/stat.h>
 630 #endif
 631 #ifdef HAVE_UNISTD_H
 632 #include <unistd.h>
 633 #endif])
 634
 635 TYPE_SOCKLEN_T
 636
 637 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 638     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[int i = errno]])],[rsync_cv_errno=yes],[rsync_cv_have_errno_decl=no])])
 639 if test x"$rsync_cv_errno" = x"yes"; then
 640    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 641 fi
 642
 643 # The following test taken from the cvs sources
 644 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 645 # These need checks to be before checks for any other functions that
 646 #    might be in the same libraries.
 647 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 648 # libsocket.so which has a bad implementation of gethostbyname (it
 649 # only looks in /etc/hosts), so we only look for -lsocket if we need
 650 # it.
 651 AC_CHECK_FUNCS(connect)
 652 if test x"$ac_cv_func_connect" = x"no"; then
 653     case "$LIBS" in
 654     *-lnsl*) ;;
 655     *) AC_CHECK_LIB(nsl_s, printf) ;;
 656     esac
 657     case "$LIBS" in
 658     *-lnsl*) ;;
 659     *) AC_CHECK_LIB(nsl, printf) ;;
 660     esac
 661     case "$LIBS" in
 662     *-lsocket*) ;;
 663     *) AC_CHECK_LIB(socket, connect) ;;
 664     esac
 665     case "$LIBS" in
 666     *-linet*) ;;
 667     *) AC_CHECK_LIB(inet, connect) ;;
 668     esac
 669     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 670     dnl has been cached.
 671     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 672        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 673         # ac_cv_func_connect=yes
 674         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 675         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 676     fi
 677 fi
 678
 679 AC_SEARCH_LIBS(inet_ntop, resolv)
 680
 681 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 682 # accept either iconv_open or libiconv_open, since some include files map
 683 # the former to the latter.
 684 AC_SEARCH_LIBS(iconv_open, iconv)
 685 AC_SEARCH_LIBS(libiconv_open, iconv)
 686
 687 AC_MSG_CHECKING([for iconv declaration])
 688 AC_CACHE_VAL(am_cv_proto_iconv, [
 689     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 690 #include <stdlib.h>
 691 #include <iconv.h>
 692 extern
 693 #ifdef __cplusplus
 694 "C"
 695 #endif
 696 #if defined(__STDC__) || defined(__cplusplus)
 697 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 698 #else
 699 size_t iconv();
 700 #endif
 701 ]], [[]])],[am_cv_proto_iconv_arg1=""],[am_cv_proto_iconv_arg1="const"])
 702       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 703     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed 's/( /(/'`
 704 AC_MSG_RESULT([$]{ac_t:-
 705          }[$]am_cv_proto_iconv)
 706 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 707                    [Define as const if the declaration of iconv() needs const.])
 708
 709 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 710
 711 AC_REPLACE_FUNCS([inet_ntop inet_pton])
 712
 713 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 714 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
 715 #include <sys/socket.h>])
 716
 717 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 718 #   builtin getaddrinfo if one of the defines don't exist
 719 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 720                rsync_cv_HAVE_GETADDR_DEFINES,[
 721                         AC_EGREP_CPP(yes, [
 722                         #include <sys/types.h>
 723                         #include <sys/socket.h>
 724                         #include <netdb.h>
 725                         #ifdef AI_PASSIVE
 726                         yes
 727                         #endif],
 728                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 729                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 730 AS_IF([test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"],[
 731         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 732         # something else so we must include <netdb.h> to get the
 733         # redefinition.
 734         AC_CHECK_FUNCS(getaddrinfo, ,
 735                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 736                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 737                 #include <sys/socket.h>
 738                 #include <netdb.h>]], [[getaddrinfo(NULL, NULL, NULL, NULL);]])],[AC_MSG_RESULT([yes])
 739                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 740                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],[AC_MSG_RESULT([no])
 741                         AC_LIBOBJ([getaddrinfo])])])
 742     ],[AC_LIBOBJ([getaddrinfo])])
 743
 744 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 745                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 746                 [],
 747                 [
 748 #include <sys/types.h>
 749 #include <sys/socket.h>
 750 ])
 751
 752 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 753                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 754                 [],
 755                 [
 756 #include <sys/types.h>
 757 #include <sys/socket.h>
 758 #include <netinet/in.h>
 759 ])
 760
 761 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 762                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 763                 [],
 764                 [
 765 #include <sys/types.h>
 766 #include <sys/socket.h>
 767 #include <netinet/in.h>
 768 ])
 769
 770 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 771                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 772                 [],
 773                 [
 774 #include <sys/types.h>
 775 #include <sys/socket.h>
 776 #include <netinet/in.h>
 777 ])
 778
 779 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 780 #if HAVE_SYS_TYPES_H
 781 # include <sys/types.h>
 782 #endif
 783 #if HAVE_SYS_STAT_H
 784 # include <sys/stat.h>
 785 #endif
 786 #if STDC_HEADERS
 787 # include <stdlib.h>
 788 # include <stddef.h>
 789 #else
 790 # if HAVE_STDLIB_H
 791 #  include <stdlib.h>
 792 # endif
 793 #endif
 794 ])
 795
 796 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 797 #
 798 AC_CHECK_FUNCS(strcasecmp)
 799 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 800     AC_CHECK_LIB(resolv, strcasecmp)
 801 fi
 802
 803 AC_CHECK_FUNCS(aclsort)
 804 if test x"$ac_cv_func_aclsort" = x"no"; then
 805     AC_CHECK_LIB(sec, aclsort)
 806 fi
 807
 808 dnl At the moment we don't test for a broken memcmp(), because all we
 809 dnl need to do is test for equality, not comparison, and it seems that
 810 dnl every platform has a memcmp that can do at least that.
 811 dnl AC_FUNC_MEMCMP
 812
 813 AC_FUNC_UTIME_NULL
 814 AC_FUNC_ALLOCA
 815 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 816     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 817     chflags getattrlist \
 818     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 819     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 820     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 821     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 822     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 823     initgroups utimensat posix_fallocate attropen setvbuf nanosleep usleep)
 824
 825 dnl cygwin iconv.h defines iconv_open as libiconv_open
 826 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 827     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 828 fi
 829
 830 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 831
 832 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 833 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
 834 #include <sys/types.h>]], [[fallocate(0, 0, 0, 0);]])],[rsync_cv_have_fallocate=yes],[rsync_cv_have_fallocate=no])])
 835 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 836     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 837 fi
 838
 839 AC_MSG_CHECKING([for FALLOC_FL_PUNCH_HOLE])
 840 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 841         #define _GNU_SOURCE 1
 842         #include <linux/falloc.h>
 843         #ifndef FALLOC_FL_PUNCH_HOLE
 844         #error FALLOC_FL_PUNCH_HOLE is missing
 845         #endif
 846     ]])], [
 847         AC_MSG_RESULT([yes])
 848         AC_DEFINE([HAVE_FALLOC_FL_PUNCH_HOLE], [1], [Define if FALLOC_FL_PUNCH_HOLE is available.])
 849     ], [
 850         AC_MSG_RESULT([no])
 851     ]
 852 )
 853
 854 AC_MSG_CHECKING([for FALLOC_FL_ZERO_RANGE])
 855 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 856         #define _GNU_SOURCE 1
 857         #include <linux/falloc.h>
 858         #ifndef FALLOC_FL_ZERO_RANGE
 859         #error FALLOC_FL_ZERO_RANGE is missing
 860         #endif
 861     ]])], [
 862         AC_MSG_RESULT([yes])
 863         AC_DEFINE([HAVE_FALLOC_FL_ZERO_RANGE], [1], [Define if FALLOC_FL_ZERO_RANGE is available.])
 864     ], [
 865         AC_MSG_RESULT([no])
 866     ]
 867 )
 868
 869 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 870 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/syscall.h>
 871 #include <unistd.h>
 872 #include <sys/types.h>]], [[syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);]])],[rsync_cv_have_sys_fallocate=yes],[rsync_cv_have_sys_fallocate=no])])
 873 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 874     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 875 fi
 876
 877 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 878     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 879     case $host_os in
 880     *cygwin*)
 881         AC_MSG_RESULT(yes)
 882         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 883                   [Define if posix_fallocate is efficient (Cygwin)])
 884         ;;
 885     *)
 886         AC_MSG_RESULT(no)
 887         ;;
 888     esac
 889 fi
 890
 891 dnl End of preallocation stuff
 892
 893 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 894 if test $ac_cv_func_getpgrp = yes; then
 895     AC_FUNC_GETPGRP
 896 fi
 897
 898 AC_ARG_ENABLE(iconv-open,
 899     AS_HELP_STRING([--disable-iconv-open],[disable all use of iconv_open() function]),
 900     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 901
 902 if test x"$enable_iconv_open" != x"no"; then
 903     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 904 fi
 905
 906 AC_ARG_ENABLE(iconv,
 907     AS_HELP_STRING([--disable-iconv],[disable rsync's --iconv option]),
 908     [], [enable_iconv=$enable_iconv_open])
 909 AH_TEMPLATE([ICONV_OPTION],
 910 [Define if you want the --iconv option.  Specifying a value will set the
 911 default iconv setting (a NULL means no --iconv processing by default).])
 912 if test x"$enable_iconv" != x"no"; then
 913         if test x"$enable_iconv" = x"yes"; then
 914                 AC_DEFINE(ICONV_OPTION, NULL)
 915         else
 916                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 917         fi
 918         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 919 fi
 920
 921 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 922   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 923 #if HAVE_UNISTD_H
 924 # include <unistd.h>
 925 #endif
 926 #include <stdlib.h>
 927 #include <errno.h>
 928 int main(void) {
 929         char const *dangling_symlink = "conftest.dangle";
 930         unlink(dangling_symlink);
 931         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 932         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) return 1;
 933         return 0;
 934     }]])],[rsync_cv_chown_modifies_symlink=yes],[rsync_cv_chown_modifies_symlink=no],[rsync_cv_chown_modifies_symlink=no])])
 935 if test $rsync_cv_chown_modifies_symlink = yes; then
 936   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 937 fi
 938
 939 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 940   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 941 #if HAVE_UNISTD_H
 942 # include <unistd.h>
 943 #endif
 944 #include <stdlib.h>
 945 #include <errno.h>
 946 #define FILENAME "conftest.dangle"
 947 int main(void) {
 948         unlink(FILENAME);
 949         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 950         unlink(FILENAME "2");
 951         if (link(FILENAME, FILENAME "2") < 0) return 1;
 952         return 0;
 953     }]])],[rsync_cv_can_hardlink_symlink=yes],[rsync_cv_can_hardlink_symlink=no],[rsync_cv_can_hardlink_symlink=no])])
 954 if test $rsync_cv_can_hardlink_symlink = yes; then
 955   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 956 fi
 957
 958 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 959   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 960 #if HAVE_UNISTD_H
 961 # include <unistd.h>
 962 #endif
 963 #ifdef HAVE_SYS_STAT_H
 964 #include <sys/stat.h>
 965 #endif
 966 #include <stdlib.h>
 967 #include <errno.h>
 968 #define FILENAME "conftest.fifi"
 969 int main(void) {
 970         unlink(FILENAME);
 971         if (mkfifo(FILENAME, 0777) < 0) abort();
 972         unlink(FILENAME "2");
 973         if (link(FILENAME, FILENAME "2") < 0) return 1;
 974         return 0;
 975     }]])],[rsync_cv_can_hardlink_special=yes],[rsync_cv_can_hardlink_special=no],[rsync_cv_can_hardlink_special=no])])
 976 if test $rsync_cv_can_hardlink_special = yes; then
 977     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 978 fi
 979
 980 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 981 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 982 #include <sys/types.h>
 983 #include <sys/socket.h>
 984
 985 int main(void) {
 986        int fd[2];
 987        return (socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1;
 988 }]])],[rsync_cv_HAVE_SOCKETPAIR=yes],[rsync_cv_HAVE_SOCKETPAIR=no],[rsync_cv_HAVE_SOCKETPAIR=cross])])
 989 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 990     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 991 fi
 992
 993 AC_REPLACE_FUNCS([getpass])
 994
 995 if test x"$with_included_popt" != x"yes"; then
 996     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 997 fi
 998 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
 999     # If the system has /usr/include/popt/popt.h, we enable the
1000     # included popt because an attempt to "#include <popt/popt.h>"
1001     # would use our included header file anyway (due to -I.), and
1002     # might conflict with the system popt.
1003     with_included_popt=yes
1004 elif test x"$ac_cv_header_popt_h" != x"yes"; then
1005     with_included_popt=yes
1006 fi
1007
1008 AC_MSG_CHECKING([whether to use included libpopt])
1009 if test x"$with_included_popt" = x"yes"; then
1010     AC_MSG_RESULT($srcdir/popt)
1011     BUILD_POPT='$(popt_OBJS)'
1012     CFLAGS="-I$srcdir/popt $CFLAGS"
1013     if test x"$ALLOCA" != x
1014     then
1015         # this can be removed when/if we add an included alloca.c;
1016         #  see autoconf documentation on AC_FUNC_ALLOCA
1017         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
1018     fi
1019 else
1020     AC_MSG_RESULT(no)
1021 fi
1022
1023 # We default to using our zlib unless --with-included-zlib=no is given.
1024 if test x"$with_included_zlib" != x"no"; then
1025     with_included_zlib=yes
1026 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
1027     with_included_zlib=yes
1028 fi
1029 if test x"$with_included_zlib" != x"yes"; then
1030     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
1031 fi
1032
1033 AC_MSG_CHECKING([whether to use included zlib])
1034 if test x"$with_included_zlib" = x"yes"; then
1035     AC_MSG_RESULT($srcdir/zlib)
1036     BUILD_ZLIB='$(zlib_OBJS)'
1037     CFLAGS="-I$srcdir/zlib $CFLAGS"
1038 else
1039     AC_DEFINE(EXTERNAL_ZLIB, 1, [Define to 1 if using external zlib])
1040     AC_MSG_RESULT(no)
1041 fi
1042
1043 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
1044 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[signed char *s = ""]])],[rsync_cv_SIGNED_CHAR_OK=yes],[rsync_cv_SIGNED_CHAR_OK=no])])
1045 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
1046     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
1047 fi
1048
1049 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
1050 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <sys/types.h>
1051 #include <dirent.h>
1052 int main(void) { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
1053 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
1054 di->d_name[0] == 0) return 0; return 1;} ]])],[rsync_cv_HAVE_BROKEN_READDIR=yes],[rsync_cv_HAVE_BROKEN_READDIR=no],[rsync_cv_HAVE_BROKEN_READDIR=cross])])
1055 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
1056     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
1057 fi
1058
1059 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
1060 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1061 #include <utime.h>]], [[struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; return utime("foo.c",&tbuf);]])],[rsync_cv_HAVE_STRUCT_UTIMBUF=yes],[rsync_cv_HAVE_STRUCT_UTIMBUF=no])])
1062 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
1063     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
1064 fi
1065
1066 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
1067 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/time.h>
1068 #include <unistd.h>]], [[struct timeval tv; return gettimeofday(&tv, NULL);]])],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=no])])
1069 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
1070     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
1071 fi
1072
1073 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
1074 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1075 #include <sys/types.h>
1076 #include <stdarg.h>
1077 #include <stdio.h>
1078 #include <stdlib.h>
1079 #include <string.h>
1080 void foo(const char *format, ...) {
1081        va_list ap;
1082        int len;
1083        static char buf[] = "12345678901234567890";
1084
1085        va_start(ap, format);
1086        len = vsnprintf(0, 0, format, ap);
1087        va_end(ap);
1088        if (len != 5) exit(1);
1089
1090        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
1091 }
1092 int main(void) { foo("hello"); return 0; }
1093 ]])],[rsync_cv_HAVE_C99_VSNPRINTF=yes],[rsync_cv_HAVE_C99_VSNPRINTF=no],[rsync_cv_HAVE_C99_VSNPRINTF=cross])])
1094 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
1095     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
1096 fi
1097
1098
1099 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
1100 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1101 #include <sys/types.h>
1102 #include <sys/stat.h>
1103 #include <unistd.h>
1104 int main(void) {
1105   struct stat st;
1106   char tpl[20]="/tmp/test.XXXXXX";
1107   int fd = mkstemp(tpl);
1108   if (fd == -1) return 1;
1109   unlink(tpl);
1110   if (fstat(fd, &st) != 0) return 1;
1111   if ((st.st_mode & 0777) != 0600) return 1;
1112   return 0;
1113 }]])],[rsync_cv_HAVE_SECURE_MKSTEMP=yes],[rsync_cv_HAVE_SECURE_MKSTEMP=no],[rsync_cv_HAVE_SECURE_MKSTEMP=cross])])
1114 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
1115     case $host_os in
1116     hpux*)
1117         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
1118         dnl so we noisily skip using it.  See HP change request JAGaf34426
1119         dnl for details. (sbonds)
1120         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
1121         ;;
1122     *)
1123         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
1124         ;;
1125     esac
1126 fi
1127
1128
1129 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
1130 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1131 #include <stdio.h>
1132 #include <sys/stat.h>
1133 #include <errno.h>
1134 #if HAVE_UNISTD_H
1135 # include <unistd.h>
1136 #endif
1137 int main(void) { int rc, ec; char *fn = "fifo-test";
1138 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
1139 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1140 return 0;}]])],[rsync_cv_MKNOD_CREATES_FIFOS=yes],[rsync_cv_MKNOD_CREATES_FIFOS=no],[rsync_cv_MKNOD_CREATES_FIFOS=cross])])
1141 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
1142     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
1143 fi
1144
1145 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
1146 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1147 #include <stdio.h>
1148 #include <sys/stat.h>
1149 #include <errno.h>
1150 #if HAVE_UNISTD_H
1151 # include <unistd.h>
1152 #endif
1153 int main(void) { int rc, ec; char *fn = "sock-test";
1154 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
1155 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1156 return 0;}]])],[rsync_cv_MKNOD_CREATES_SOCKETS=yes],[rsync_cv_MKNOD_CREATES_SOCKETS=no],[rsync_cv_MKNOD_CREATES_SOCKETS=cross])])
1157 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
1158     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
1159 fi
1160
1161 #
1162 # The following test was mostly taken from the tcl/tk plus patches
1163 #
1164 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
1165 rm -rf conftest*
1166 cat > conftest.$ac_ext <<EOF
1167 int main(void) { return 0; }
1168 EOF
1169 ${CC-cc} -c -o conftest..o conftest.$ac_ext
1170 if test -f conftest..o; then
1171     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
1172 else
1173     rsync_cv_DASHC_WORKS_WITH_DASHO=no
1174 fi
1175 rm -rf conftest*
1176 ])
1177 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
1178     OBJ_SAVE="#"
1179     OBJ_RESTORE="#"
1180     CC_SHOBJ_FLAG='-o $@'
1181 else
1182     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
1183     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
1184     CC_SHOBJ_FLAG=""
1185 fi
1186
1187 AC_SUBST(OBJ_SAVE)
1188 AC_SUBST(OBJ_RESTORE)
1189 AC_SUBST(CC_SHOBJ_FLAG)
1190 AC_SUBST(BUILD_POPT)
1191 AC_SUBST(BUILD_ZLIB)
1192 AC_SUBST(MAKE_MAN)
1193
1194 AC_CHECK_FUNCS(_acl __acl _facl __facl)
1195 #################################################
1196 # check for ACL support
1197
1198 AC_MSG_CHECKING([whether to support ACLs])
1199 AC_ARG_ENABLE(acl-support,
1200         AS_HELP_STRING([--disable-acl-support],[disable ACL support]))
1201
1202 if test x"$enable_acl_support" = x"no"; then
1203     AC_MSG_RESULT(no)
1204 else
1205     case "$host_os" in
1206     *sysv5*)
1207         AC_MSG_RESULT(Using UnixWare ACLs)
1208         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
1209         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
1210         ;;
1211     solaris*)
1212         AC_MSG_RESULT(Using solaris ACLs)
1213         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
1214         AC_DEFINE(SUPPORT_ACLS, 1)
1215         ;;
1216     *hpux*)
1217         AC_MSG_RESULT(Using HPUX ACLs)
1218         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
1219         AC_DEFINE(SUPPORT_ACLS, 1)
1220         ;;
1221     *irix*)
1222         AC_MSG_RESULT(Using IRIX ACLs)
1223         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
1224         AC_DEFINE(SUPPORT_ACLS, 1)
1225         ;;
1226     *aix*)
1227         AC_MSG_RESULT(Using AIX ACLs)
1228         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
1229         AC_DEFINE(SUPPORT_ACLS, 1)
1230         ;;
1231     *osf*)
1232         AC_MSG_RESULT(Using Tru64 ACLs)
1233         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
1234         AC_DEFINE(SUPPORT_ACLS, 1)
1235         LIBS="$LIBS -lpacl"
1236         ;;
1237     darwin*)
1238         AC_MSG_RESULT(Using OS X ACLs)
1239         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
1240         AC_DEFINE(SUPPORT_ACLS, 1)
1241         ;;
1242     *)
1243         AC_MSG_RESULT(running tests:)
1244         AC_CHECK_LIB(acl,acl_get_file)
1245         AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
1246             AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1247 #include <sys/acl.h>]], [[ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);]])],[samba_cv_HAVE_POSIX_ACLS=yes],[samba_cv_HAVE_POSIX_ACLS=no])])
1248         AC_MSG_CHECKING(ACL test results)
1249         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
1250             AC_MSG_RESULT(Using posix ACLs)
1251             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
1252             AC_DEFINE(SUPPORT_ACLS, 1)
1253             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
1254                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1255 #include <sys/acl.h>]], [[ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);]])],[samba_cv_HAVE_ACL_GET_PERM_NP=yes],[samba_cv_HAVE_ACL_GET_PERM_NP=no])])
1256             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
1257                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1258             fi
1259         else
1260             if test x"$enable_acl_support" = x"yes"; then
1261                 AC_MSG_ERROR(Failed to find ACL support)
1262             else
1263                 AC_MSG_RESULT(No ACL support found)
1264             fi
1265         fi
1266         ;;
1267     esac
1268 fi
1269
1270 #################################################
1271 # check for extended attribute support
1272 AC_MSG_CHECKING(whether to support extended attributes)
1273 AC_ARG_ENABLE(xattr-support,
1274     AS_HELP_STRING([--disable-xattr-support],[disable extended attributes]),
1275     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1276         *yes*) enable_xattr_support=maybe ;;
1277         *) enable_xattr_support=no ;;
1278         esac])
1279 AH_TEMPLATE([SUPPORT_XATTRS],
1280 [Define to 1 to add support for extended attributes])
1281 if test x"$enable_xattr_support" = x"no"; then
1282     AC_MSG_RESULT(no)
1283 else
1284     case "$host_os" in
1285     *linux*|*netbsd*)
1286         AC_MSG_RESULT(Using Linux xattrs)
1287         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs (or equivalent)])
1288         AC_DEFINE(SUPPORT_XATTRS, 1)
1289         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1290         AC_CHECK_LIB(attr,getxattr)
1291         ;;
1292     darwin*)
1293         AC_MSG_RESULT(Using OS X xattrs)
1294         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1295         AC_DEFINE(SUPPORT_XATTRS, 1)
1296         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1297         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1298         ;;
1299     freebsd*)
1300         AC_MSG_RESULT(Using FreeBSD extattrs)
1301         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1302         AC_DEFINE(SUPPORT_XATTRS, 1)
1303         ;;
1304     solaris*)
1305         AC_MSG_RESULT(Using Solaris xattrs)
1306         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1307         AC_DEFINE(SUPPORT_XATTRS, 1)
1308         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1309         ;;
1310     *)
1311         if test x"$enable_xattr_support" = x"yes"; then
1312             AC_MSG_ERROR(Failed to find extended attribute support)
1313         else
1314             AC_MSG_RESULT(No extended attribute support found)
1315         fi
1316         ;;
1317     esac
1318 fi
1319
1320 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
1321     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1322     OLD_CFLAGS="$CFLAGS"
1323     CFLAGS="$CFLAGS -Wno-unused-parameter"
1324     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[printf("hello\n");]])],[rsync_warn_flag=yes],[rsync_warn_flag=no])
1325     AC_MSG_RESULT([$rsync_warn_flag])
1326     if test x"$rsync_warn_flag" = x"no"; then
1327         CFLAGS="$OLD_CFLAGS"
1328     fi
1329 fi
1330
1331 case "$CC" in
1332 ' checker'*|checker*)
1333     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1334     ;;
1335 esac
1336
1337 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1338 AC_OUTPUT
1339
1340 AC_MSG_RESULT()
1341 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
1342 AC_MSG_RESULT()