configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT()
   4 AC_CONFIG_SRCDIR([byteorder.h])
   5 AC_CONFIG_HEADER(config.h)
   6 AC_PREREQ(2.59)
   7
   8 RSYNC_VERSION=2.6.5cvs
   9 AC_SUBST(RSYNC_VERSION)
  10 AC_MSG_NOTICE([Configuring rsync $RSYNC_VERSION])
  11
  12 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$RSYNC_VERSION"], [rsync release version])
  13
  14 LDFLAGS=${LDFLAGS-""}
  15
  16 AC_CANONICAL_TARGET([])
  17
  18 dnl Checks for programs.
  19 AC_PROG_CC
  20 AC_PROG_CPP
  21 AC_PROG_EGREP
  22 AC_PROG_INSTALL
  23 AC_PROG_CC_STDC
  24 AC_SUBST(SHELL)
  25
  26 AC_DEFINE([_GNU_SOURCE], 1,
  27           [Define _GNU_SOURCE so that we get all necessary prototypes])
  28
  29 if test "x$ac_cv_prog_cc_stdc" = xno
  30 then
  31         AC_MSG_WARN([rsync requires an ANSI C compiler and you don't seem to have one])
  32 fi
  33
  34 # We must decide this before testing the compiler.
  35
  36 # Please allow this to default to yes, so that your users have more
  37 # chance of getting a useful stack trace if problems occur.
  38
  39 AC_MSG_CHECKING([whether to include debugging symbols])
  40 AC_ARG_ENABLE(debug,
  41         AC_HELP_STRING([--enable-debug],
  42                 [including debugging symbols and features (default yes)]),
  43                 [], [])
  44
  45 if test x"$enable_debug" = x"no"
  46 then
  47     AC_MSG_RESULT(no)
  48     CFLAGS=${CFLAGS-"-O"}
  49 else
  50     AC_MSG_RESULT([yes])
  51     # leave CFLAGS alone; AC_PROG_CC will try to include -g if it can
  52     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  53     dnl CFLAGS=${CFLAGS-"-g"}
  54 fi
  55
  56
  57
  58
  59 AC_ARG_ENABLE(profile,
  60         AC_HELP_STRING([--enable-profile],
  61                 [turn on CPU profiling (default no)],
  62                 [], []))
  63 if test x"$enable_profile" = xyes
  64 then
  65         CFLAGS="$CFLAGS -pg"
  66 fi
  67
  68
  69 # Specifically, this turns on panic_action handling.
  70 AC_ARG_ENABLE(maintainer-mode,
  71         AC_HELP_STRING([--enable-maintainer-mode],
  72                 [turn on extra debug features],
  73                 [], []))
  74 if test x"$enable_maintainer_mode" = xyes
  75 then
  76         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
  77 fi
  78
  79
  80 # This is needed for our included version of popt.  Kind of silly, but
  81 # I don't want our version too far out of sync.
  82 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  83
  84 # If GCC, turn on warnings.
  85 if test x"$GCC" = x"yes"
  86 then
  87         CFLAGS="$CFLAGS -Wall -W"
  88 fi
  89
  90 AC_ARG_WITH(included-popt,
  91         [  --with-included-popt    use bundled popt library, not from system])
  92
  93 AC_ARG_WITH(rsync-path,
  94         [  --with-rsync-path=PATH  set default --rsync-path to PATH (default: rsync)],
  95         [ RSYNC_PATH="$with_rsync_path" ],
  96         [ RSYNC_PATH="rsync" ])
  97
  98 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
  99
 100 AC_ARG_WITH(rsyncd-conf,
 101         AC_HELP_STRING([--with-rsyncd-conf=PATH], [set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 102         [ if test ! -z "$with_rsyncd_conf" ; then
 103                 case $with_rsyncd_conf in
 104                         yes|no)
 105                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 106                                 ;;
 107                         /*)
 108                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 109                                 ;;
 110                         *)
 111                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 112                                 ;;
 113                 esac
 114         else
 115                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 116         fi ],
 117         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 118
 119 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 120
 121 AC_ARG_WITH(rsh,
 122         AC_HELP_STRING([--with-rsh=CMD], [set remote shell command to CMD (default: ssh)]))
 123
 124 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 125 AC_DEFINE_UNQUOTED(HAVE_REMSH, $HAVE_REMSH, [remote shell is remsh not rsh])
 126
 127 if test x"$with_rsh" != x
 128 then
 129         RSYNC_RSH="$with_rsh"
 130 else
 131         RSYNC_RSH="ssh"
 132 fi
 133
 134 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 135
 136 # arrgh. libc in the current debian stable screws up the largefile
 137 # stuff, getting byte range locking wrong
 138 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 139 AC_TRY_RUN([
 140 #define _FILE_OFFSET_BITS 64
 141 #include <stdio.h>
 142 #include <fcntl.h>
 143 #include <sys/types.h>
 144 #include <sys/wait.h>
 145
 146 int main(void)
 147 {
 148         struct flock lock;
 149         int status;
 150         char tpl[32] = "/tmp/locktest.XXXXXX";
 151         int fd = mkstemp(tpl);
 152         if (fd < 0) {
 153                 strcpy(tpl, "conftest.dat");
 154                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 155         }
 156
 157         lock.l_type = F_WRLCK;
 158         lock.l_whence = SEEK_SET;
 159         lock.l_start = 0;
 160         lock.l_len = 1;
 161         lock.l_pid = 0;
 162         fcntl(fd,F_SETLK,&lock);
 163         if (fork() == 0) {
 164                 lock.l_start = 1;
 165                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 166         }
 167         wait(&status);
 168         unlink(tpl);
 169         exit(WEXITSTATUS(status));
 170 }
 171 ],
 172 rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)])
 173 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 174    AC_SYS_LARGEFILE
 175 fi
 176
 177 ipv6type=unknown
 178 ipv6lib=none
 179 ipv6trylibc=yes
 180
 181 AC_ARG_ENABLE(ipv6,
 182         AC_HELP_STRING([--disable-ipv6], [don't even try to use IPv6]))
 183
 184 dnl Do you want to disable use of locale functions
 185 AH_TEMPLATE([CONFIG_LOCALE],
 186 [Undefine if you don't want locale features.  By default this is defined.])
 187 AC_ARG_ENABLE([locale],
 188         AC_HELP_STRING([--disable-locale], [turn off locale features]),
 189 [if test x$enableval = xyes; then
 190   AC_DEFINE(CONFIG_LOCALE)
 191 fi],
 192 AC_DEFINE(CONFIG_LOCALE)
 193 )
 194
 195 if test "x$enable_ipv6" != xno
 196 then
 197         AC_MSG_CHECKING([ipv6 stack type])
 198         for i in inria kame linux-glibc linux-inet6 toshiba v6d zeta; do
 199                 case $i in
 200                 inria)
 201                         # http://www.kame.net/
 202                         AC_EGREP_CPP(yes, [
 203 #include <netinet/in.h>
 204 #ifdef IPV6_INRIA_VERSION
 205 yes
 206 #endif],
 207                                 [ipv6type=$i;
 208                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 209                                 ])
 210                         ;;
 211                 kame)
 212                         # http://www.kame.net/
 213                         AC_EGREP_CPP(yes, [
 214 #include <netinet/in.h>
 215 #ifdef __KAME__
 216 yes
 217 #endif],
 218                                 [ipv6type=$i;
 219                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 220                         ;;
 221                 linux-glibc)
 222                         # http://www.v6.linux.or.jp/
 223                         AC_EGREP_CPP(yes, [
 224 #include <features.h>
 225 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 226 yes
 227 #endif],
 228                                 [ipv6type=$i;
 229 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 230                         ;;
 231                 linux-inet6)
 232                         # http://www.v6.linux.or.jp/
 233                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 234                                 ipv6type=$i
 235                                 ipv6lib=inet6
 236                                 ipv6libdir=/usr/inet6/lib
 237                                 ipv6trylibc=yes;
 238                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 239                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 240                         fi
 241                         ;;
 242                 toshiba)
 243                         AC_EGREP_CPP(yes, [
 244 #include <sys/param.h>
 245 #ifdef _TOSHIBA_INET6
 246 yes
 247 #endif],
 248                                 [ipv6type=$i;
 249                                 ipv6lib=inet6;
 250                                 ipv6libdir=/usr/local/v6/lib;
 251                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 252                         ;;
 253                 v6d)
 254                         AC_EGREP_CPP(yes, [
 255 #include </usr/local/v6/include/sys/v6config.h>
 256 #ifdef __V6D__
 257 yes
 258 #endif],
 259                                 [ipv6type=$i;
 260                                 ipv6lib=v6;
 261                                 ipv6libdir=/usr/local/v6/lib;
 262                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 263                         ;;
 264                 zeta)
 265                         AC_EGREP_CPP(yes, [
 266 #include <sys/param.h>
 267 #ifdef _ZETA_MINAMI_INET6
 268 yes
 269 #endif],
 270                                 [ipv6type=$i;
 271                                 ipv6lib=inet6;
 272                                 ipv6libdir=/usr/local/v6/lib;
 273                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 274                         ;;
 275                 esac
 276                 if test "$ipv6type" != "unknown"; then
 277                         break
 278                 fi
 279         done
 280         AC_MSG_RESULT($ipv6type)
 281
 282         AC_SEARCH_LIBS(getaddrinfo, inet6)
 283 fi
 284
 285 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 286 case $host_os in
 287         *cygwin* ) AC_MSG_RESULT(yes)
 288                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 289                             [Define to 1 if sockets need to be shutdown])
 290                    ;;
 291                * ) AC_MSG_RESULT(no);;
 292 esac
 293
 294 AC_C_BIGENDIAN
 295 AC_HEADER_DIRENT
 296 AC_HEADER_TIME
 297 AC_HEADER_SYS_WAIT
 298 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 299     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 300     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 301     sys/un.h glob.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 302     netdb.h malloc.h float.h)
 303 AC_HEADER_MAJOR
 304
 305 AC_CHECK_SIZEOF(int)
 306 AC_CHECK_SIZEOF(long)
 307 AC_CHECK_SIZEOF(long long)
 308 AC_CHECK_SIZEOF(short)
 309 AC_CHECK_SIZEOF(off_t)
 310 AC_CHECK_SIZEOF(off64_t)
 311
 312 AC_C_INLINE
 313 AC_C_LONG_DOUBLE
 314
 315 AC_TYPE_SIGNAL
 316 AC_TYPE_UID_T
 317 AC_TYPE_MODE_T
 318 AC_TYPE_OFF_T
 319 AC_TYPE_SIZE_T
 320 AC_TYPE_PID_T
 321 AC_TYPE_GETGROUPS
 322 AC_CHECK_MEMBERS([struct stat.st_rdev])
 323
 324 TYPE_SOCKLEN_T
 325
 326 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 327     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
 328         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
 329 if test x"$rsync_cv_errno" = x"yes"; then
 330    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 331 fi
 332
 333 # The following test taken from the cvs sources
 334 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 335 # These need checks to be before checks for any other functions that
 336 #    might be in the same libraries.
 337 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 338 # libsocket.so which has a bad implementation of gethostbyname (it
 339 # only looks in /etc/hosts), so we only look for -lsocket if we need
 340 # it.
 341 AC_CHECK_FUNCS(connect)
 342 if test x"$ac_cv_func_connect" = x"no"; then
 343     case "$LIBS" in
 344     *-lnsl*) ;;
 345     *) AC_CHECK_LIB(nsl_s, printf) ;;
 346     esac
 347     case "$LIBS" in
 348     *-lnsl*) ;;
 349     *) AC_CHECK_LIB(nsl, printf) ;;
 350     esac
 351     case "$LIBS" in
 352     *-lsocket*) ;;
 353     *) AC_CHECK_LIB(socket, connect) ;;
 354     esac
 355     case "$LIBS" in
 356     *-linet*) ;;
 357     *) AC_CHECK_LIB(inet, connect) ;;
 358     esac
 359     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 360     dnl has been cached.
 361     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 362        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 363         # ac_cv_func_connect=yes
 364         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 365         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 366     fi
 367 fi
 368
 369 AC_CHECK_LIB(resolv, inet_ntop)
 370
 371 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 372
 373 AC_CHECK_FUNCS(inet_ntop, , [AC_LIBOBJ(lib/inet_ntop)])
 374 AC_CHECK_FUNCS(inet_pton, , [AC_LIBOBJ(lib/inet_pton)])
 375
 376 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 377 #   builtin getaddrinfo if one of the defines don't exist
 378 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 379                rsync_cv_HAVE_GETADDR_DEFINES,[
 380                         AC_EGREP_CPP(yes, [
 381                         #include <sys/types.h>
 382                         #include <sys/socket.h>
 383                         #include <netdb.h>
 384                         #ifdef AI_PASSIVE
 385                         yes
 386                         #endif],
 387                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 388                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 389 if test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes"; then
 390         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 391         # something else so we must include <netdb.h> to get the
 392         # redefinition.
 393         AC_CHECK_FUNCS(getaddrinfo, ,
 394                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 395                 AC_TRY_LINK([#include <sys/types.h>
 396                 #include <sys/socket.h>
 397                 #include <netdb.h>],[getaddrinfo(NULL, NULL, NULL, NULL);],
 398                         [AC_MSG_RESULT([yes])
 399                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 400                                 [Define to 1 if you have the "getaddrinfo" function.])],
 401                         [AC_MSG_RESULT([no])
 402                         AC_LIBOBJ(lib/getaddrinfo)])])
 403         AC_CHECK_FUNCS(getnameinfo, , [AC_LIBOBJ(lib/getnameinfo)])
 404 else
 405         AC_LIBOBJ(lib/getaddrinfo)
 406         AC_LIBOBJ(lib/getnameinfo)
 407 fi
 408
 409 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 410                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 411                 [],
 412                 [
 413 #include <sys/types.h>
 414 #include <sys/socket.h>
 415 ])
 416
 417 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 418                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 419                 [],
 420                 [
 421 #include <sys/types.h>
 422 #include <sys/socket.h>
 423 #include <netinet/in.h>
 424 ])
 425
 426 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 427                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 428                 [],
 429                 [
 430 #include <sys/types.h>
 431 #include <sys/socket.h>
 432 #include <netinet/in.h>
 433 ])
 434
 435 AC_MSG_CHECKING(struct sockaddr_storage)
 436 AC_TRY_COMPILE([#include <sys/types.h>
 437 #include <sys/socket.h>],
 438 [struct sockaddr_storage x;],
 439         AC_MSG_RESULT(yes)
 440         AC_DEFINE(HAVE_SOCKADDR_STORAGE, 1,
 441                 [Define to 1 if you have struct sockaddr_storage.] ),
 442         AC_MSG_RESULT(no))
 443
 444 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 445                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 446                 [],
 447                 [
 448 #include <sys/types.h>
 449 #include <sys/socket.h>
 450 #include <netinet/in.h>
 451 ])
 452
 453 AC_MSG_CHECKING(struct stat64)
 454 AC_TRY_COMPILE([#include <stdio.h>
 455 #if HAVE_SYS_TYPES_H
 456 # include <sys/types.h>
 457 #endif
 458 #if HAVE_SYS_STAT_H
 459 # include <sys/stat.h>
 460 #endif
 461 #if STDC_HEADERS
 462 # include <stdlib.h>
 463 # include <stddef.h>
 464 #else
 465 # if HAVE_STDLIB_H
 466 #  include <stdlib.h>
 467 # endif
 468 #endif
 469 ],[struct stat64 st;],
 470     AC_MSG_RESULT(yes)
 471         AC_DEFINE(HAVE_STRUCT_STAT64,1,[Define to 1 if you have struct stat64.]),
 472     AC_MSG_RESULT(no))
 473
 474 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 475 #
 476 AC_CHECK_FUNCS(strcasecmp)
 477 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 478     AC_CHECK_LIB(resolv, strcasecmp)
 479 fi
 480
 481 dnl At the moment we don't test for a broken memcmp(), because all we
 482 dnl need to do is test for equality, not comparison, and it seems that
 483 dnl every platform has a memcmp that can do at least that.
 484 dnl AC_FUNC_MEMCMP
 485
 486 AC_FUNC_UTIME_NULL
 487 AC_FUNC_ALLOCA
 488 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup strerror chown chmod mknod mkfifo \
 489     fchmod fstat strchr readlink link utime utimes strftime mtrace ftruncate \
 490     memmove lchown vsnprintf snprintf vasprintf asprintf setsid glob strpbrk \
 491     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 492     setlocale setmode open64 lseek64 mkstemp64 va_copy __va_copy)
 493
 494 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 495 if test $ac_cv_func_getpgrp = yes; then
 496     AC_FUNC_GETPGRP
 497 fi
 498
 499 # Determine whether chown follows symlinks (it should).
 500 AC_CACHE_CHECK([whether chown() dereferences symlinks],rsync_cv_chown_follows_symlink,[
 501   AC_TRY_RUN([
 502 #if HAVE_UNISTD_H
 503 # include <unistd.h>
 504 #endif
 505 #include <stdlib.h>
 506 #include <errno.h>
 507     main() {
 508         char const *dangling_symlink = "conftest.dangle";
 509         unlink(dangling_symlink);
 510         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 511         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) exit(0);
 512         exit(1);
 513     }],
 514   rsync_cv_chown_follows_symlink=yes,rsync_cv_chown_follows_symlink=no,rsync_cv_chown_follows_symlink=yes)])
 515 if test $rsync_cv_chown_follows_symlink = no; then
 516   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 517 fi
 518
 519 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 520 AC_TRY_RUN([
 521 #include <sys/types.h>
 522 #include <sys/socket.h>
 523
 524 main() {
 525        int fd[2];
 526        exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
 527 }],
 528 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
 529 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 530     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 531 fi
 532
 533 if test x"$with_included_popt" != x"yes"
 534 then
 535     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 536 fi
 537
 538 AC_MSG_CHECKING([whether to use included libpopt])
 539 if test x"$with_included_popt" = x"yes"
 540 then
 541     AC_MSG_RESULT($srcdir/popt)
 542     BUILD_POPT='$(popt_OBJS)'
 543     CFLAGS="$CFLAGS -I$srcdir/popt"
 544     if test x"$ALLOCA" != x
 545     then
 546         # this can be removed when/if we add an included alloca.c;
 547         #  see autoconf documentation on AC_FUNC_ALLOCA
 548         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 549     fi
 550 else
 551     AC_MSG_RESULT(no)
 552 fi
 553
 554 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
 555 AC_TRY_COMPILE([],[signed char *s = ""],
 556 rsync_cv_SIGNED_CHAR_OK=yes,rsync_cv_SIGNED_CHAR_OK=no)])
 557 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
 558     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
 559 fi
 560
 561 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 562 AC_TRY_RUN([#include <sys/types.h>
 563 #include <dirent.h>
 564 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 565 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 566 di->d_name[0] == 0) exit(0); exit(1);} ],
 567 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
 568 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 569     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
 570 fi
 571
 572 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_UTIMBUF,[
 573 AC_TRY_COMPILE([#include <sys/types.h>
 574 #include <utime.h>],
 575 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 576 rsync_cv_HAVE_UTIMBUF=yes,rsync_cv_HAVE_UTIMBUF=no)])
 577 if test x"$rsync_cv_HAVE_UTIMBUF" = x"yes"; then
 578     AC_DEFINE(HAVE_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
 579 fi
 580
 581 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 582 AC_TRY_COMPILE([#include <sys/time.h>
 583 #include <unistd.h>],
 584 [struct timeval tv; exit(gettimeofday(&tv, NULL));],
 585 rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no)])
 586 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
 587     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
 588 fi
 589
 590 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 591 AC_TRY_RUN([
 592 #include <sys/types.h>
 593 #include <stdarg.h>
 594 void foo(const char *format, ...) {
 595        va_list ap;
 596        int len;
 597        char buf[5];
 598
 599        va_start(ap, format);
 600        len = vsnprintf(0, 0, format, ap);
 601        va_end(ap);
 602        if (len != 5) exit(1);
 603
 604        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 605
 606        exit(0);
 607 }
 608 main() { foo("hello"); }
 609 ],
 610 rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)])
 611 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 612     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
 613 fi
 614
 615
 616 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 617 AC_TRY_RUN([#include <stdlib.h>
 618 #include <sys/types.h>
 619 #include <sys/stat.h>
 620 #include <unistd.h>
 621 main() {
 622   struct stat st;
 623   char tpl[20]="/tmp/test.XXXXXX";
 624   int fd = mkstemp(tpl);
 625   if (fd == -1) exit(1);
 626   unlink(tpl);
 627   if (fstat(fd, &st) != 0) exit(1);
 628   if ((st.st_mode & 0777) != 0600) exit(1);
 629   exit(0);
 630 }],
 631 rsync_cv_HAVE_SECURE_MKSTEMP=yes,
 632 rsync_cv_HAVE_SECURE_MKSTEMP=no,
 633 rsync_cv_HAVE_SECURE_MKSTEMP=cross)])
 634 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 635     case $target_os in
 636     hpux*)
 637         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
 638         dnl so we noisily skip using it.  See HP change request JAGaf34426
 639         dnl for details. (sbonds)
 640         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
 641         ;;
 642     *)
 643         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
 644         ;;
 645     esac
 646 fi
 647
 648
 649 AC_CACHE_CHECK([for broken inet_ntoa],rsync_cv_REPLACE_INET_NTOA,[
 650 AC_TRY_RUN([
 651 #include <stdio.h>
 652 #include <sys/types.h>
 653 #include <netinet/in.h>
 654 #include <arpa/inet.h>
 655 main() { struct in_addr ip; ip.s_addr = 0x12345678;
 656 if (strcmp(inet_ntoa(ip),"18.52.86.120") &&
 657     strcmp(inet_ntoa(ip),"120.86.52.18")) { exit(1); }
 658 exit(0);}],
 659            rsync_cv_REPLACE_INET_NTOA=no,rsync_cv_REPLACE_INET_NTOA=yes,rsync_cv_REPLACE_INET_NTOA=cross)])
 660 if test x"$rsync_cv_REPLACE_INET_NTOA" = x"yes"; then
 661     AC_DEFINE(REPLACE_INET_NTOA, 1, [Define to 1 if inet_ntoa() needs to be replaced])
 662 fi
 663
 664
 665 AC_CACHE_CHECK([for broken inet_aton],rsync_cv_REPLACE_INET_ATON,[
 666 AC_TRY_RUN([
 667 #include <stdio.h>
 668 #include <sys/types.h>
 669 #include <netinet/in.h>
 670 #include <arpa/inet.h>
 671 main() { struct in_addr ip;
 672 if (inet_aton("example", &ip) == 0) exit(0); exit(1);}],
 673            rsync_cv_REPLACE_INET_ATON=no,rsync_cv_REPLACE_INET_ATON=yes,rsync_cv_REPLACE_INET_ATON=cross)])
 674 if test x"$rsync_cv_REPLACE_INET_ATON" = x"yes"; then
 675     AC_DEFINE(REPLACE_INET_ATON, 1, [Define to 1 if inet_aton() needs to be replaced])
 676 fi
 677
 678 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
 679 AC_TRY_RUN([
 680 #include <stdio.h>
 681 #include <sys/stat.h>
 682 #include <errno.h>
 683 main() { int rc, ec; char *fn = "fifo-test";
 684 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
 685 if (rc) {printf("%d %d\n",rc,ec); return ec;}
 686 return 0;}],
 687            rsync_cv_MKNOD_CREATES_FIFOS=yes,rsync_cv_MKNOD_CREATES_FIFOS=no,rsync_cv_MKNOD_CREATES_FIFOS=cross)])
 688 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
 689     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
 690 fi
 691
 692 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
 693 AC_TRY_RUN([
 694 #include <stdio.h>
 695 #include <sys/stat.h>
 696 #include <errno.h>
 697 main() { int rc, ec; char *fn = "sock-test";
 698 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
 699 if (rc) {printf("%d %d\n",rc,ec); return ec;}
 700 return 0;}],
 701            rsync_cv_MKNOD_CREATES_SOCKETS=yes,rsync_cv_MKNOD_CREATES_SOCKETS=no,rsync_cv_MKNOD_CREATES_SOCKETS=cross)])
 702 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
 703     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
 704 fi
 705
 706 #
 707 # The following test was mostly taken from the tcl/tk plus patches
 708 #
 709 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 710 rm -rf conftest*
 711 cat > conftest.$ac_ext <<EOF
 712 int main() { return 0; }
 713 EOF
 714 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 715 if test -f conftest..o; then
 716     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 717 else
 718     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 719 fi
 720 rm -rf conftest*
 721 ])
 722 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 723     OBJ_SAVE="#"
 724     OBJ_RESTORE="#"
 725     CC_SHOBJ_FLAG='-o $@'
 726 else
 727     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 728     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 729     CC_SHOBJ_FLAG=""
 730 fi
 731
 732 AC_SUBST(OBJ_SAVE)
 733 AC_SUBST(OBJ_RESTORE)
 734 AC_SUBST(CC_SHOBJ_FLAG)
 735 AC_SUBST(BUILD_POPT)
 736
 737 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
 738 AC_OUTPUT
 739
 740 if test x"$with_rsh" = x; then
 741         if test x"$HAVE_REMSH" = x1; then
 742                 rmsh1='remsh:'
 743                 rmsh2='=remsh'
 744         else
 745                 rmsh1='rsh:  '
 746                 rmsh2='=rsh  '
 747         fi
 748         AC_MSG_RESULT()
 749         AC_MSG_RESULT([    **********************************************************************])
 750         AC_MSG_RESULT([    *   As of v2.6.0, the default remote shell is ssh instead of rsh!!   *])
 751         AC_MSG_RESULT([    *   To use previous default of $rmsh1 ./configure --with-rsh$rmsh2   *])
 752         AC_MSG_RESULT([    **********************************************************************])
 753 fi
 754
 755 AC_MSG_RESULT()
 756 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
 757 AC_MSG_RESULT()