| blob | 9e6da5e56a898eacf446c25d31c4fb464ffb199a |
1 dnl Process this file with autoconf to produce a configure script.
3 AC_INIT()
4 AC_CONFIG_SRCDIR([byteorder.h])
5 AC_CONFIG_HEADER(config.h)
6 AC_PREREQ(2.59)
8 RSYNC_VERSION=3.1.0dev
9 AC_SUBST(RSYNC_VERSION)
10 AC_MSG_NOTICE([Configuring rsync $RSYNC_VERSION])
12 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$RSYNC_VERSION"], [rsync release version])
14 LDFLAGS=${LDFLAGS-""}
16 AC_CANONICAL_HOST
18 # We must decide this before testing the compiler.
20 # Please allow this to default to yes, so that your users have more
21 # chance of getting a useful stack trace if problems occur.
23 AC_MSG_CHECKING([whether to include debugging symbols])
24 AC_ARG_ENABLE(debug,
25 AC_HELP_STRING([--disable-debug],
26 [disable debugging symbols and features]))
28 if test x"$enable_debug" = x"no"; then
29 AC_MSG_RESULT(no)
30 ac_cv_prog_cc_g=no
31 else
32 AC_MSG_RESULT([yes])
33 dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
34 # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
35 fi
37 dnl Checks for programs.
38 AC_PROG_CC
39 AC_PROG_CPP
40 AC_PROG_EGREP
41 AC_PROG_INSTALL
42 AC_PROG_CC_STDC
43 AC_SUBST(SHELL)
45 AC_DEFINE([_GNU_SOURCE], 1,
46 [Define _GNU_SOURCE so that we get all necessary prototypes])
48 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
49 AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
50 fi
52 AC_ARG_ENABLE(profile,
53 AC_HELP_STRING([--enable-profile],
54 [turn on CPU profiling]))
55 if test x"$enable_profile" = x"yes"; then
56 CFLAGS="$CFLAGS -pg"
57 fi
60 # Specifically, this turns on panic_action handling.
61 AC_ARG_ENABLE(maintainer-mode,
62 AC_HELP_STRING([--enable-maintainer-mode],
63 [turn on extra debug features]))
64 if test x"$enable_maintainer_mode" = x"yes"; then
65 CFLAGS="$CFLAGS -DMAINTAINER_MODE"
66 fi
69 # This is needed for our included version of popt. Kind of silly, but
70 # I don't want our version too far out of sync.
71 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
73 # If GCC, turn on warnings.
74 if test x"$GCC" = x"yes"; then
75 CFLAGS="$CFLAGS -Wall -W"
76 fi
78 AC_ARG_WITH(included-popt,
79 AC_HELP_STRING([--with-included-popt], [use bundled popt library, not from system]))
81 AC_ARG_WITH(protected-args,
82 AC_HELP_STRING([--with-protected-args], [make --protected-args option the default]))
83 if test x"$with_protected_args" = x"yes"; then
84 AC_DEFINE_UNQUOTED(RSYNC_USE_PROTECTED_ARGS, 1, [Define to 1 if --protected-args should be the default])
85 fi
87 AC_ARG_WITH(rsync-path,
88 AC_HELP_STRING([--with-rsync-path=PATH], [set default --rsync-path to PATH (default: rsync)]),
89 [ RSYNC_PATH="$with_rsync_path" ],
90 [ RSYNC_PATH="rsync" ])
92 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
94 AC_ARG_WITH(rsyncd-conf,
95 AC_HELP_STRING([--with-rsyncd-conf=PATH], [set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
96 [ if test ! -z "$with_rsyncd_conf" ; then
97 case $with_rsyncd_conf in
98 yes|no)
99 RSYNCD_SYSCONF="/etc/rsyncd.conf"
100 ;;
101 /*)
102 RSYNCD_SYSCONF="$with_rsyncd_conf"
103 ;;
104 *)
105 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
106 ;;
107 esac
108 else
109 RSYNCD_SYSCONF="/etc/rsyncd.conf"
110 fi ],
111 [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
113 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
115 AC_ARG_WITH(rsh,
116 AC_HELP_STRING([--with-rsh=CMD], [set remote shell command to CMD (default: ssh)]))
118 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
119 if test x$HAVE_REMSH = x1; then
120 AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
121 fi
123 if test x"$with_rsh" != x; then
124 RSYNC_RSH="$with_rsh"
125 else
126 RSYNC_RSH="ssh"
127 fi
128 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
130 AC_CHECK_PROG(HAVE_YODL2MAN, yodl2man, 1, 0)
131 if test x$HAVE_YODL2MAN = x1; then
132 MAKE_MAN=man
133 else
134 MAKE_MAN=man-copy
135 fi
137 AC_ARG_WITH(nobody-group,
138 AC_HELP_STRING([--with-nobody-group=GROUP],
139 [set the default unprivileged group (default nobody or nogroup)]),
140 [ NOBODY_GROUP="$with_nobody_group" ])
142 if test x"$with_nobody_group" = x; then
143 AC_MSG_CHECKING([the group for user "nobody"])
144 if grep '^nobody:' /etc/group >/dev/null 2>&1; then
145 NOBODY_GROUP=nobody
146 elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
147 NOBODY_GROUP=nogroup
148 else
149 NOBODY_GROUP=nobody # test for others?
150 fi
151 AC_MSG_RESULT($NOBODY_GROUP)
152 fi
154 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
155 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
157 # arrgh. libc in some old debian version screwed up the largefile
158 # stuff, getting byte range locking wrong
159 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
160 AC_TRY_RUN([
161 #define _FILE_OFFSET_BITS 64
162 #include <stdio.h>
163 #include <fcntl.h>
164 #include <sys/types.h>
165 #include <sys/wait.h>
167 int main(void)
168 {
169 struct flock lock;
170 int status;
171 char tpl[32] = "/tmp/locktest.XXXXXX";
172 int fd = mkstemp(tpl);
173 if (fd < 0) {
174 strcpy(tpl, "conftest.dat");
175 fd = open(tpl, O_CREAT|O_RDWR, 0600);
176 }
178 lock.l_type = F_WRLCK;
179 lock.l_whence = SEEK_SET;
180 lock.l_start = 0;
181 lock.l_len = 1;
182 lock.l_pid = 0;
183 fcntl(fd,F_SETLK,&lock);
184 if (fork() == 0) {
185 lock.l_start = 1;
186 _exit(fcntl(fd,F_SETLK,&lock) == 0);
187 }
188 wait(&status);
189 unlink(tpl);
190 exit(WEXITSTATUS(status));
191 }
192 ],
193 rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)])
194 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
195 AC_SYS_LARGEFILE
196 fi
198 ipv6type=unknown
199 ipv6lib=none
200 ipv6trylibc=yes
202 AC_ARG_ENABLE(ipv6,
203 AC_HELP_STRING([--disable-ipv6],
204 [do not even try to use IPv6]))
205 if test x"$enable_ipv6" != x"no"; then
206 AC_MSG_CHECKING([ipv6 stack type])
207 for i in inria kame linux-glibc linux-inet6 solaris toshiba v6d zeta cygwin; do
208 case $i in
209 inria)
210 # http://www.kame.net/
211 AC_EGREP_CPP(yes, [
212 #include <netinet/in.h>
213 #ifdef IPV6_INRIA_VERSION
214 yes
215 #endif],
216 [ipv6type=$i;
217 AC_DEFINE(INET6, 1, [true if you have IPv6])
218 ])
219 ;;
220 kame)
221 # http://www.kame.net/
222 AC_EGREP_CPP(yes, [
223 #include <netinet/in.h>
224 #ifdef __KAME__
225 yes
226 #endif],
227 [ipv6type=$i;
228 AC_DEFINE(INET6, 1, [true if you have IPv6])])
229 ;;
230 linux-glibc)
231 # http://www.v6.linux.or.jp/
232 AC_EGREP_CPP(yes, [
233 #include <features.h>
234 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
235 yes
236 #endif],
237 [ipv6type=$i;
238 AC_DEFINE(INET6, 1, [true if you have IPv6])])
239 ;;
240 linux-inet6)
241 # http://www.v6.linux.or.jp/
242 if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
243 ipv6type=$i
244 ipv6lib=inet6
245 ipv6libdir=/usr/inet6/lib
246 ipv6trylibc=yes;
247 AC_DEFINE(INET6, 1, [true if you have IPv6])
248 CFLAGS="-I/usr/inet6/include $CFLAGS"
249 fi
250 ;;
251 solaris)
252 # http://www.sun.com
253 AC_EGREP_CPP(yes, [
254 #include <netinet/ip6.h>
255 #ifdef __sun
256 yes
257 #endif],
258 [ipv6type=$i;
259 AC_DEFINE(INET6, 1, [true if you have IPv6])])
260 ;;
261 toshiba)
262 AC_EGREP_CPP(yes, [
263 #include <sys/param.h>
264 #ifdef _TOSHIBA_INET6
265 yes
266 #endif],
267 [ipv6type=$i;
268 ipv6lib=inet6;
269 ipv6libdir=/usr/local/v6/lib;
270 AC_DEFINE(INET6, 1, [true if you have IPv6])])
271 ;;
272 v6d)
273 AC_EGREP_CPP(yes, [
274 #include </usr/local/v6/include/sys/v6config.h>
275 #ifdef __V6D__
276 yes
277 #endif],
278 [ipv6type=$i;
279 ipv6lib=v6;
280 ipv6libdir=/usr/local/v6/lib;
281 AC_DEFINE(INET6, 1, [true if you have IPv6])])
282 ;;
283 zeta)
284 AC_EGREP_CPP(yes, [
285 #include <sys/param.h>
286 #ifdef _ZETA_MINAMI_INET6
287 yes
288 #endif],
289 [ipv6type=$i;
290 ipv6lib=inet6;
291 ipv6libdir=/usr/local/v6/lib;
292 AC_DEFINE(INET6, 1, [true if you have IPv6])])
293 ;;
294 cygwin)
295 AC_EGREP_CPP(yes, [
296 #include <netinet/in.h>
297 #ifdef _CYGWIN_IN6_H
298 yes
299 #endif],
300 [ipv6type=$i;
301 AC_DEFINE(INET6, 1, [true if you have IPv6])])
302 ;;
303 esac
304 if test "$ipv6type" != "unknown"; then
305 break
306 fi
307 done
308 AC_MSG_RESULT($ipv6type)
310 AC_SEARCH_LIBS(getaddrinfo, inet6)
311 fi
313 dnl Do you want to disable use of locale functions
314 AC_ARG_ENABLE([locale],
315 AC_HELP_STRING([--disable-locale],
316 [disable locale features]))
317 AH_TEMPLATE([CONFIG_LOCALE],
318 [Undefine if you do not want locale features. By default this is defined.])
319 if test x"$enable_locale" != x"no"; then
320 AC_DEFINE(CONFIG_LOCALE)
321 fi
323 AC_MSG_CHECKING([whether to call shutdown on all sockets])
324 case $host_os in
325 *cygwin* ) AC_MSG_RESULT(yes)
326 AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
327 [Define to 1 if sockets need to be shutdown])
328 ;;
329 * ) AC_MSG_RESULT(no);;
330 esac
332 AC_C_BIGENDIAN
333 AC_HEADER_DIRENT
334 AC_HEADER_TIME
335 AC_HEADER_SYS_WAIT
336 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
337 unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
338 sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
339 sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
340 netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
341 sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h \
342 popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netinet/ip.h)
343 AC_HEADER_MAJOR
345 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
346 AC_TRY_RUN([
347 #include <sys/types.h>
348 #ifdef MAJOR_IN_MKDEV
349 #include <sys/mkdev.h>
350 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
351 # define makedev mkdev
352 # endif
353 #elif defined MAJOR_IN_SYSMACROS
354 #include <sys/sysmacros.h>
355 #endif
357 int main(void)
358 {
359 dev_t dev = makedev(0, 5, 7);
360 if (major(dev) != 5 || minor(dev) != 7)
361 exit(1);
362 return 0;
363 }
364 ],
365 rsync_cv_MAKEDEV_TAKES_3_ARGS=yes,rsync_cv_MAKEDEV_TAKES_3_ARGS=no,rsync_cv_MAKEDEV_TAKES_3_ARGS=no)])
366 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
367 AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
368 fi
370 AC_CHECK_SIZEOF(int)
371 AC_CHECK_SIZEOF(long)
372 AC_CHECK_SIZEOF(long long)
373 AC_CHECK_SIZEOF(short)
374 AC_CHECK_SIZEOF(int16_t)
375 AC_CHECK_SIZEOF(uint16_t)
376 AC_CHECK_SIZEOF(int32_t)
377 AC_CHECK_SIZEOF(uint32_t)
378 AC_CHECK_SIZEOF(int64_t)
379 AC_CHECK_SIZEOF(off_t)
380 AC_CHECK_SIZEOF(off64_t)
381 AC_CHECK_SIZEOF(time_t)
383 AC_C_INLINE
384 AC_C_LONG_DOUBLE
386 AC_TYPE_SIGNAL
387 AC_TYPE_UID_T
388 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
389 AC_TYPE_GETGROUPS
390 AC_CHECK_MEMBERS([struct stat.st_rdev,
391 struct stat.st_mtimensec,
392 struct stat.st_mtim.tv_nsec],,,[
393 #ifdef HAVE_SYS_TYPES_H
394 #include <sys/types.h>
395 #endif
396 #ifdef HAVE_SYS_STAT_H
397 #include <sys/stat.h>
398 #endif
399 #ifdef HAVE_UNISTD_H
400 #include <unistd.h>
401 #endif])
403 TYPE_SOCKLEN_T
405 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
406 AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
407 rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
408 if test x"$rsync_cv_errno" = x"yes"; then
409 AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
410 fi
412 # The following test taken from the cvs sources
413 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
414 # These need checks to be before checks for any other functions that
415 # might be in the same libraries.
416 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
417 # libsocket.so which has a bad implementation of gethostbyname (it
418 # only looks in /etc/hosts), so we only look for -lsocket if we need
419 # it.
420 AC_CHECK_FUNCS(connect)
421 if test x"$ac_cv_func_connect" = x"no"; then
422 case "$LIBS" in
423 *-lnsl*) ;;
424 *) AC_CHECK_LIB(nsl_s, printf) ;;
425 esac
426 case "$LIBS" in
427 *-lnsl*) ;;
428 *) AC_CHECK_LIB(nsl, printf) ;;
429 esac
430 case "$LIBS" in
431 *-lsocket*) ;;
432 *) AC_CHECK_LIB(socket, connect) ;;
433 esac
434 case "$LIBS" in
435 *-linet*) ;;
436 *) AC_CHECK_LIB(inet, connect) ;;
437 esac
438 dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
439 dnl has been cached.
440 if test x"$ac_cv_lib_socket_connect" = x"yes" ||
441 test x"$ac_cv_lib_inet_connect" = x"yes"; then
442 # ac_cv_func_connect=yes
443 # don't! it would cause AC_CHECK_FUNC to succeed next time configure is run
444 AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
445 fi
446 fi
448 AC_SEARCH_LIBS(inet_ntop, resolv)
450 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed. We'll
451 # accept either iconv_open or libiconv_open, since some include files map
452 # the former to the latter.
453 AC_SEARCH_LIBS(iconv_open, iconv)
454 AC_SEARCH_LIBS(libiconv_open, iconv)
456 AC_MSG_CHECKING([for iconv declaration])
457 AC_CACHE_VAL(am_cv_proto_iconv, [
458 AC_TRY_COMPILE([
459 #include <stdlib.h>
460 #include <iconv.h>
461 extern
462 #ifdef __cplusplus
463 "C"
464 #endif
465 #if defined(__STDC__) || defined(__cplusplus)
466 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
467 #else
468 size_t iconv();
469 #endif
470 ], [], am_cv_proto_iconv_arg1="", am_cv_proto_iconv_arg1="const")
471 am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
472 am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
473 AC_MSG_RESULT([$]{ac_t:-
474 }[$]am_cv_proto_iconv)
475 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
476 [Define as const if the declaration of iconv() needs const.])
478 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
480 AC_CHECK_FUNCS(inet_ntop, , [AC_LIBOBJ(lib/inet_ntop)])
481 AC_CHECK_FUNCS(inet_pton, , [AC_LIBOBJ(lib/inet_pton)])
483 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
484 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
485 #include <sys/socket.h>])
487 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
488 # builtin getaddrinfo if one of the defines don't exist
489 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
490 rsync_cv_HAVE_GETADDR_DEFINES,[
491 AC_EGREP_CPP(yes, [
492 #include <sys/types.h>
493 #include <sys/socket.h>
494 #include <netdb.h>
495 #ifdef AI_PASSIVE
496 yes
497 #endif],
498 rsync_cv_HAVE_GETADDR_DEFINES=yes,
499 rsync_cv_HAVE_GETADDR_DEFINES=no)])
500 if test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"; then
501 # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
502 # something else so we must include <netdb.h> to get the
503 # redefinition.
504 AC_CHECK_FUNCS(getaddrinfo, ,
505 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
506 AC_TRY_LINK([#include <sys/types.h>
507 #include <sys/socket.h>
508 #include <netdb.h>],[getaddrinfo(NULL, NULL, NULL, NULL);],
509 [AC_MSG_RESULT([yes])
510 AC_DEFINE(HAVE_GETADDRINFO, 1,
511 [Define to 1 if you have the "getaddrinfo" function and required types.])],
512 [AC_MSG_RESULT([no])
513 AC_LIBOBJ(lib/getaddrinfo)])])
514 else
515 AC_LIBOBJ(lib/getaddrinfo)
516 fi
518 AC_CHECK_MEMBER([struct sockaddr.sa_len],
519 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
520 [],
521 [
522 #include <sys/types.h>
523 #include <sys/socket.h>
524 ])
526 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
527 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
528 [],
529 [
530 #include <sys/types.h>
531 #include <sys/socket.h>
532 #include <netinet/in.h>
533 ])
535 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
536 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
537 [],
538 [
539 #include <sys/types.h>
540 #include <sys/socket.h>
541 #include <netinet/in.h>
542 ])
544 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
545 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
546 [],
547 [
548 #include <sys/types.h>
549 #include <sys/socket.h>
550 #include <netinet/in.h>
551 ])
553 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
554 #if HAVE_SYS_TYPES_H
555 # include <sys/types.h>
556 #endif
557 #if HAVE_SYS_STAT_H
558 # include <sys/stat.h>
559 #endif
560 #if STDC_HEADERS
561 # include <stdlib.h>
562 # include <stddef.h>
563 #else
564 # if HAVE_STDLIB_H
565 # include <stdlib.h>
566 # endif
567 #endif
568 ])
570 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
571 #
572 AC_CHECK_FUNCS(strcasecmp)
573 if test x"$ac_cv_func_strcasecmp" = x"no"; then
574 AC_CHECK_LIB(resolv, strcasecmp)
575 fi
577 AC_CHECK_FUNCS(aclsort)
578 if test x"$ac_cv_func_aclsort" = x"no"; then
579 AC_CHECK_LIB(sec, aclsort)
580 fi
582 dnl At the moment we don't test for a broken memcmp(), because all we
583 dnl need to do is test for equality, not comparison, and it seems that
584 dnl every platform has a memcmp that can do at least that.
585 dnl AC_FUNC_MEMCMP
587 AC_FUNC_UTIME_NULL
588 AC_FUNC_ALLOCA
589 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
590 fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
591 memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
592 strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
593 setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
594 seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
595 extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
596 initgroups utimensat posix_fallocate)
598 dnl cygwin iconv.h defines iconv_open as libiconv_open
599 if test x"$ac_cv_func_iconv_open" != x"yes"; then
600 AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
601 fi
603 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
605 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
606 AC_TRY_LINK([#include <fcntl.h>
607 #include <sys/types.h>],
608 [fallocate(0, 0, 0, 0);],
609 rsync_cv_have_fallocate=yes,rsync_cv_have_fallocate=no)])
610 if test x"$rsync_cv_have_fallocate" = x"yes"; then
611 AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
612 fi
614 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
615 AC_TRY_COMPILE([#include <sys/syscall.h>
616 #include <sys/types.h>],
617 [syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);],
618 rsync_cv_have_sys_fallocate=yes,rsync_cv_have_sys_fallocate=no)])
619 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
620 AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
621 fi
623 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
624 AC_MSG_CHECKING([whether posix_fallocate is efficient])
625 case $host_os in
626 *cygwin*)
627 AC_MSG_RESULT(yes)
628 AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
629 [Define if posix_fallocate is efficient (Cygwin)])
630 ;;
631 *)
632 AC_MSG_RESULT(no)
633 ;;
634 esac
635 fi
637 dnl End of preallocation stuff
639 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
640 if test $ac_cv_func_getpgrp = yes; then
641 AC_FUNC_GETPGRP
642 fi
644 AC_ARG_ENABLE(iconv-open,
645 AC_HELP_STRING([--disable-iconv-open],
646 [disable all use of iconv_open() function]),
647 [], [enable_iconv_open=$ac_cv_func_iconv_open])
649 if test x"$enable_iconv_open" != x"no"; then
650 AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
651 fi
653 AC_ARG_ENABLE(iconv,
654 AC_HELP_STRING([--disable-iconv],
655 [disable rsync's --iconv option]),
656 [], [enable_iconv=$enable_iconv_open])
657 AH_TEMPLATE([ICONV_OPTION],
658 [Define if you want the --iconv option. Specifing a value will set the
659 default iconv setting (a NULL means no --iconv processing by default).])
660 if test x"$enable_iconv" != x"no"; then
661 if test x"$enable_iconv" = x"yes"; then
662 AC_DEFINE(ICONV_OPTION, NULL)
663 else
664 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
665 fi
666 AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
667 fi
669 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
670 AC_TRY_RUN([
671 #if HAVE_UNISTD_H
672 # include <unistd.h>
673 #endif
674 #include <stdlib.h>
675 #include <errno.h>
676 main() {
677 char const *dangling_symlink = "conftest.dangle";
678 unlink(dangling_symlink);
679 if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
680 if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) exit(1);
681 exit(0);
682 }],
683 rsync_cv_chown_modifies_symlink=yes,rsync_cv_chown_modifies_symlink=no,rsync_cv_chown_modifies_symlink=no)])
684 if test $rsync_cv_chown_modifies_symlink = yes; then
685 AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
686 fi
688 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
689 AC_TRY_RUN([
690 #if HAVE_UNISTD_H
691 # include <unistd.h>
692 #endif
693 #include <stdlib.h>
694 #include <errno.h>
695 #define FILENAME "conftest.dangle"
696 main() {
697 unlink(FILENAME);
698 if (symlink("conftest.no-such", FILENAME) < 0) abort();
699 if (link(FILENAME, FILENAME "2") < 0) exit(1);
700 exit(0);
701 }],
702 rsync_cv_can_hardlink_symlink=yes,rsync_cv_can_hardlink_symlink=no,rsync_cv_can_hardlink_symlink=no)])
703 if test $rsync_cv_can_hardlink_symlink = yes; then
704 AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
705 fi
707 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
708 AC_TRY_RUN([
709 #if HAVE_UNISTD_H
710 # include <unistd.h>
711 #endif
712 #include <stdlib.h>
713 #include <errno.h>
714 #define FILENAME "conftest.fifi"
715 main() {
716 unlink(FILENAME);
717 if (mkfifo(FILENAME, 0777) < 0) abort();
718 if (link(FILENAME, FILENAME "2") < 0) exit(1);
719 exit(0);
720 }],
721 rsync_cv_can_hardlink_special=yes,rsync_cv_can_hardlink_special=no,rsync_cv_can_hardlink_special=no)])
722 if test $rsync_cv_can_hardlink_special = yes; then
723 AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
724 fi
726 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
727 AC_TRY_RUN([
728 #include <sys/types.h>
729 #include <sys/socket.h>
731 main() {
732 int fd[2];
733 #ifdef __CYGWIN__
734 exit(1);
735 #else
736 exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
737 #endif
738 }],
739 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
740 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
741 AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
742 fi
744 if test x"$with_included_popt" != x"yes"; then
745 AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
746 fi
747 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
748 # If the system has /usr/include/popt/popt.h, we enable the
749 # included popt because an attempt to "#include <popt/popt.h>"
750 # would use our included header file anyway (due to -I.), and
751 # might conflict with the system popt.
752 with_included_popt=yes
753 elif test x"$ac_cv_header_popt_h" != x"yes"; then
754 with_included_popt=yes
755 fi
757 AC_MSG_CHECKING([whether to use included libpopt])
758 if test x"$with_included_popt" = x"yes"; then
759 AC_MSG_RESULT($srcdir/popt)
760 BUILD_POPT='$(popt_OBJS)'
761 CFLAGS="$CFLAGS -I$srcdir/popt"
762 if test x"$ALLOCA" != x
763 then
764 # this can be removed when/if we add an included alloca.c;
765 # see autoconf documentation on AC_FUNC_ALLOCA
766 AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
767 fi
768 else
769 AC_MSG_RESULT(no)
770 fi
772 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
773 AC_TRY_COMPILE([],[signed char *s = ""],
774 rsync_cv_SIGNED_CHAR_OK=yes,rsync_cv_SIGNED_CHAR_OK=no)])
775 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
776 AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
777 fi
779 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
780 AC_TRY_RUN([#include <sys/types.h>
781 #include <dirent.h>
782 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
783 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
784 di->d_name[0] == 0) exit(0); exit(1);} ],
785 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
786 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
787 AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
788 fi
790 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
791 AC_TRY_COMPILE([#include <sys/types.h>
792 #include <utime.h>],
793 [struct utimbuf tbuf; tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
794 rsync_cv_HAVE_STRUCT_UTIMBUF=yes,rsync_cv_HAVE_STRUCT_UTIMBUF=no)])
795 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
796 AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
797 fi
799 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
800 AC_TRY_COMPILE([#include <sys/time.h>
801 #include <unistd.h>],
802 [struct timeval tv; exit(gettimeofday(&tv, NULL));],
803 rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no)])
804 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
805 AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
806 fi
808 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
809 AC_TRY_RUN([
810 #include <sys/types.h>
811 #include <stdarg.h>
812 void foo(const char *format, ...) {
813 va_list ap;
814 int len;
815 char buf[5];
817 va_start(ap, format);
818 len = vsnprintf(0, 0, format, ap);
819 va_end(ap);
820 if (len != 5) exit(1);
822 if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
824 exit(0);
825 }
826 main() { foo("hello"); }
827 ],
828 rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)])
829 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
830 AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
831 fi
834 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
835 AC_TRY_RUN([#include <stdlib.h>
836 #include <sys/types.h>
837 #include <sys/stat.h>
838 #include <unistd.h>
839 main() {
840 struct stat st;
841 char tpl[20]="/tmp/test.XXXXXX";
842 int fd = mkstemp(tpl);
843 if (fd == -1) exit(1);
844 unlink(tpl);
845 if (fstat(fd, &st) != 0) exit(1);
846 if ((st.st_mode & 0777) != 0600) exit(1);
847 exit(0);
848 }],
849 rsync_cv_HAVE_SECURE_MKSTEMP=yes,
850 rsync_cv_HAVE_SECURE_MKSTEMP=no,
851 rsync_cv_HAVE_SECURE_MKSTEMP=cross)])
852 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
853 case $host_os in
854 hpux*)
855 dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
856 dnl so we noisily skip using it. See HP change request JAGaf34426
857 dnl for details. (sbonds)
858 AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
859 ;;
860 *)
861 AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
862 ;;
863 esac
864 fi
867 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
868 AC_TRY_RUN([
869 #include <stdio.h>
870 #include <sys/stat.h>
871 #include <errno.h>
872 main() { int rc, ec; char *fn = "fifo-test";
873 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
874 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
875 return 0;}],
876 rsync_cv_MKNOD_CREATES_FIFOS=yes,rsync_cv_MKNOD_CREATES_FIFOS=no,rsync_cv_MKNOD_CREATES_FIFOS=cross)])
877 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
878 AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
879 fi
881 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
882 AC_TRY_RUN([
883 #include <stdio.h>
884 #include <sys/stat.h>
885 #include <errno.h>
886 main() { int rc, ec; char *fn = "sock-test";
887 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
888 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
889 return 0;}],
890 rsync_cv_MKNOD_CREATES_SOCKETS=yes,rsync_cv_MKNOD_CREATES_SOCKETS=no,rsync_cv_MKNOD_CREATES_SOCKETS=cross)])
891 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
892 AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
893 fi
895 #
896 # The following test was mostly taken from the tcl/tk plus patches
897 #
898 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
899 rm -rf conftest*
900 cat > conftest.$ac_ext <<EOF
901 int main() { return 0; }
902 EOF
903 ${CC-cc} -c -o conftest..o conftest.$ac_ext
904 if test -f conftest..o; then
905 rsync_cv_DASHC_WORKS_WITH_DASHO=yes
906 else
907 rsync_cv_DASHC_WORKS_WITH_DASHO=no
908 fi
909 rm -rf conftest*
910 ])
911 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
912 OBJ_SAVE="#"
913 OBJ_RESTORE="#"
914 CC_SHOBJ_FLAG='-o $@'
915 else
916 OBJ_SAVE=' @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
917 OBJ_RESTORE=' @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
918 CC_SHOBJ_FLAG=""
919 fi
921 AC_SUBST(OBJ_SAVE)
922 AC_SUBST(OBJ_RESTORE)
923 AC_SUBST(CC_SHOBJ_FLAG)
924 AC_SUBST(BUILD_POPT)
925 AC_SUBST(MAKE_MAN)
927 AC_CHECK_FUNCS(_acl __acl _facl __facl)
928 #################################################
929 # check for ACL support
931 AC_MSG_CHECKING([whether to support ACLs])
932 AC_ARG_ENABLE(acl-support,
933 AC_HELP_STRING([--disable-acl-support],
934 [disable ACL support]))
936 if test x"$enable_acl_support" = x"no"; then
937 AC_MSG_RESULT(no)
938 else
939 case "$host_os" in
940 *sysv5*)
941 AC_MSG_RESULT(Using UnixWare ACLs)
942 AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
943 AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
944 ;;
945 *solaris*|*cygwin*)
946 AC_MSG_RESULT(Using solaris ACLs)
947 AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
948 AC_DEFINE(SUPPORT_ACLS, 1)
949 ;;
950 *hpux*)
951 AC_MSG_RESULT(Using HPUX ACLs)
952 AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
953 AC_DEFINE(SUPPORT_ACLS, 1)
954 ;;
955 *irix*)
956 AC_MSG_RESULT(Using IRIX ACLs)
957 AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
958 AC_DEFINE(SUPPORT_ACLS, 1)
959 ;;
960 *aix*)
961 AC_MSG_RESULT(Using AIX ACLs)
962 AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
963 AC_DEFINE(SUPPORT_ACLS, 1)
964 ;;
965 *osf*)
966 AC_MSG_RESULT(Using Tru64 ACLs)
967 AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
968 AC_DEFINE(SUPPORT_ACLS, 1)
969 LIBS="$LIBS -lpacl"
970 ;;
971 darwin*)
972 AC_MSG_RESULT(Using OS X ACLs)
973 AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
974 AC_DEFINE(SUPPORT_ACLS, 1)
975 ;;
976 *)
977 AC_MSG_RESULT(running tests:)
978 AC_CHECK_LIB(acl,acl_get_file)
979 AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
980 AC_TRY_LINK([#include <sys/types.h>
981 #include <sys/acl.h>],
982 [ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);],
983 samba_cv_HAVE_POSIX_ACLS=yes,samba_cv_HAVE_POSIX_ACLS=no)])
984 AC_MSG_CHECKING(ACL test results)
985 if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
986 AC_MSG_RESULT(Using posix ACLs)
987 AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
988 AC_DEFINE(SUPPORT_ACLS, 1)
989 AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
990 AC_TRY_LINK([#include <sys/types.h>
991 #include <sys/acl.h>],
992 [ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);],
993 samba_cv_HAVE_ACL_GET_PERM_NP=yes,samba_cv_HAVE_ACL_GET_PERM_NP=no)])
994 if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
995 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
996 fi
997 else
998 if test x"$enable_acl_support" = x"yes"; then
999 AC_MSG_ERROR(Failed to find ACL support)
1000 else
1001 AC_MSG_RESULT(No ACL support found)
1002 fi
1003 fi
1004 ;;
1005 esac
1006 fi
1008 #################################################
1009 # check for extended attribute support
1010 AC_MSG_CHECKING(whether to support extended attributes)
1011 AC_ARG_ENABLE(xattr-support,
1012 AC_HELP_STRING([--disable-xattr-support],
1013 [disable extended attributes]),
1014 [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link" in
1015 *yes*) enable_xattr_support=maybe ;;
1016 *) enable_xattr_support=no ;;
1017 esac])
1018 AH_TEMPLATE([SUPPORT_XATTRS],
1019 [Define to 1 to add support for extended attributes])
1020 if test x"$enable_xattr_support" = x"no"; then
1021 AC_MSG_RESULT(no)
1022 else
1023 case "$host_os" in
1024 *linux*)
1025 AC_MSG_RESULT(Using Linux xattrs)
1026 AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs])
1027 AC_DEFINE(SUPPORT_XATTRS, 1)
1028 AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1029 ;;
1030 darwin*)
1031 AC_MSG_RESULT(Using OS X xattrs)
1032 AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1033 AC_DEFINE(SUPPORT_XATTRS, 1)
1034 AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1035 AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1036 ;;
1037 freebsd*)
1038 AC_MSG_RESULT(Using FreeBSD extattrs)
1039 AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1040 AC_DEFINE(SUPPORT_XATTRS, 1)
1041 ;;
1042 solaris*)
1043 AC_MSG_RESULT(Using Solaris xattrs)
1044 AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1045 AC_DEFINE(SUPPORT_XATTRS, 1)
1046 AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1047 ;;
1048 *)
1049 if test x"$enable_xattr_support" = x"yes"; then
1050 AC_MSG_ERROR(Failed to find extended attribute support)
1051 else
1052 AC_MSG_RESULT(No extended attribute support found)
1053 fi
1054 ;;
1055 esac
1056 fi
1058 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
1059 AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1060 OLD_CFLAGS="$CFLAGS"
1061 CFLAGS="$CFLAGS -Wno-unused-parameter"
1062 AC_TRY_LINK([#include <stdio.h>], [printf("hello\n");], [rsync_warn_flag=yes], [rsync_warn_flag=no])
1063 AC_MSG_RESULT([$rsync_warn_flag])
1064 if test x"$rsync_warn_flag" = x"no"; then
1065 CFLAGS="$OLD_CFLAGS"
1066 fi
1067 fi
1069 case "$CC" in
1070 ' checker'*|checker*)
1071 AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1072 ;;
1073 esac
1075 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1076 AC_OUTPUT
1078 AC_MSG_RESULT()
1079 AC_MSG_RESULT([ rsync ${RSYNC_VERSION} configuration successful])
1080 AC_MSG_RESULT()