src/code/typedefs.lisp

   1 ;;;; This file contains the definition of the CTYPE (Compiler TYPE)
   2 ;;;; structure and related macros used for manipulating it. This is
   3 ;;;; sort of a mini object system with rather odd dispatching rules.
   4 ;;;; Other compile-time definitions needed by multiple files are also
   5 ;;;; here.
   6 ;;;;
   7 ;;;; FIXME: The comment above about what's in this file is no longer so
   8 ;;;; true now that I've split off type-class.lisp. Perhaps we should
   9 ;;;; split off CTYPE into the same file as type-class.lisp, rename that
  10 ;;;; file to ctype.lisp, move the current comment to the head of that file,
  11 ;;;; and write a new comment for this file saying how this file holds
  12 ;;;; concrete types.
  13
  14 ;;;; This software is part of the SBCL system. See the README file for
  15 ;;;; more information.
  16 ;;;;
  17 ;;;; This software is derived from the CMU CL system, which was
  18 ;;;; written at Carnegie Mellon University and released into the
  19 ;;;; public domain. The software is in the public domain and is
  20 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  21 ;;;; files for more information.
  22
  23 (in-package "SB!KERNEL")
  24
  25 (!begin-collecting-cold-init-forms)
  26
  27 ;;; Define the translation from a type-specifier to a type structure for
  28 ;;; some particular type. Syntax is identical to DEFTYPE.
  29 (defmacro !def-type-translator (name arglist &body body)
  30   (declare (type symbol name))
  31   ;; FIXME: Now that the T%CL hack is ancient history and we just use CL
  32   ;; instead, we can probably return to using PARSE-DEFMACRO here.
  33   ;;
  34   ;; was:
  35   ;;   This song and dance more or less emulates PARSE-DEFMACRO. The reason for
  36   ;;   doing this emulation instead of just calling PARSE-DEFMACRO is just that
  37   ;;   at cross-compile time PARSE-DEFMACRO expects lambda-list keywords in the
  38   ;;   T%CL package, which is not what we have here. Maybe there's a tidier
  39   ;;   solution.. (Other than wishing that ANSI had used symbols in the KEYWORD
  40   ;;   package as lambda list keywords, rather than using symbols in the LISP
  41   ;;   package!)
  42   (multiple-value-bind (whole wholeless-arglist)
  43       (if (eq '&whole (car arglist))
  44           (values (cadr arglist) (cddr arglist))
  45           (values (gensym) arglist))
  46     (multiple-value-bind (forms decls)
  47         (parse-body body :doc-string-allowed nil)
  48       `(progn
  49          (!cold-init-forms
  50           (setf (info :type :translator ',name)
  51                 (lambda (,whole)
  52                   (block ,name
  53                     (destructuring-bind ,wholeless-arglist
  54                         (rest ,whole) ; discarding NAME
  55                       ,@decls
  56                       ,@forms)))))
  57          ',name))))
  58
  59 ;;; DEFVARs for these come later, after we have enough stuff defined.
  60 (declaim (special *wild-type* *universal-type* *empty-type*))
  61 \f
  62 ;;; the base class for the internal representation of types
  63 (def!struct (ctype (:conc-name type-)
  64                    (:constructor nil)
  65                    (:make-load-form-fun make-type-load-form)
  66                    #-sb-xc-host (:pure t))
  67   ;; the class of this type
  68   ;;
  69   ;; FIXME: It's unnecessarily confusing to have a structure accessor
  70   ;; named TYPE-CLASS-INFO which is an accessor for the CTYPE structure
  71   ;; even though the TYPE-CLASS structure also exists in the system.
  72   ;; Rename this slot: TYPE-CLASS or ASSOCIATED-TYPE-CLASS or something.
  73   (class-info (missing-arg) :type type-class)
  74   ;; True if this type has a fixed number of members, and as such
  75   ;; could possibly be completely specified in a MEMBER type. This is
  76   ;; used by the MEMBER type methods.
  77   (enumerable nil :read-only t)
  78   ;; an arbitrary hash code used in EQ-style hashing of identity
  79   ;; (since EQ hashing can't be done portably)
  80   (hash-value (random #.(ash 1 20))
  81               :type (and fixnum unsigned-byte)
  82               :read-only t)
  83   ;; Can this object contain other types? A global property of our
  84   ;; implementation (which unfortunately seems impossible to enforce
  85   ;; with assertions or other in-the-code checks and constraints) is
  86   ;; that subclasses which don't contain other types correspond to
  87   ;; disjoint subsets (except of course for the NAMED-TYPE T, which
  88   ;; covers everything). So NUMBER-TYPE is disjoint from CONS-TYPE is
  89   ;; is disjoint from MEMBER-TYPE and so forth. But types which can
  90   ;; contain other types, like HAIRY-TYPE and INTERSECTION-TYPE, can
  91   ;; violate this rule.
  92   (might-contain-other-types-p nil :read-only t))
  93 (def!method print-object ((ctype ctype) stream)
  94   (print-unreadable-object (ctype stream :type t)
  95     (prin1 (type-specifier ctype) stream)))
  96
  97 ;;; Just dump it as a specifier. (We'll convert it back upon loading.)
  98 (defun make-type-load-form (type)
  99   (declare (type ctype type))
 100   `(specifier-type ',(type-specifier type)))
 101 \f
 102 ;;;; miscellany
 103
 104 ;;; Look for nice relationships for types that have nice relationships
 105 ;;; only when one is a hierarchical subtype of the other.
 106 (defun hierarchical-intersection2 (type1 type2)
 107   (multiple-value-bind (subtypep1 win1) (csubtypep type1 type2)
 108     (multiple-value-bind (subtypep2 win2) (csubtypep type2 type1)
 109       (cond (subtypep1 type1)
 110             (subtypep2 type2)
 111             ((and win1 win2) *empty-type*)
 112             (t nil)))))
 113 (defun hierarchical-union2 (type1 type2)
 114   (cond ((csubtypep type1 type2) type2)
 115         ((csubtypep type2 type1) type1)
 116         (t nil)))
 117
 118 ;;; Hash two things (types) down to 8 bits. In CMU CL this was an EQ
 119 ;;; hash, but since it now needs to run in vanilla ANSI Common Lisp at
 120 ;;; cross-compile time, it's now based on the CTYPE-HASH-VALUE field
 121 ;;; instead.
 122 ;;;
 123 ;;; FIXME: This was a macro in CMU CL, and is now an INLINE function. Is
 124 ;;; it important for it to be INLINE, or could be become an ordinary
 125 ;;; function without significant loss? -- WHN 19990413
 126 #!-sb-fluid (declaim (inline type-cache-hash))
 127 (declaim (ftype (function (ctype ctype) (unsigned-byte 8)) type-cache-hash))
 128 (defun type-cache-hash (type1 type2)
 129   (logand (logxor (ash (type-hash-value type1) -3)
 130                   (type-hash-value type2))
 131           #xFF))
 132 #!-sb-fluid (declaim (inline type-list-cache-hash))
 133 (declaim (ftype (function (list) (unsigned-byte 8)) type-list-cache-hash))
 134 (defun type-list-cache-hash (types)
 135   (logand (loop with res = 0
 136              for type in types
 137              for hash = (type-hash-value type)
 138              do (setq res (logxor res hash))
 139              finally (return res))
 140           #xFF))
 141 \f
 142 ;;;; cold loading initializations
 143
 144 (!defun-from-collected-cold-init-forms !typedefs-cold-init)