contrib/sb-posix/interface.lisp

   1 (cl:in-package :sb-posix)
   2
   3 (defmacro define-protocol-class
   4     (name alien-type superclasses slots &rest options)
   5   (let ((to-protocol (intern (format nil "ALIEN-TO-~A" name)))
   6         (to-alien (intern (format nil "~A-TO-ALIEN" name))))
   7     `(progn
   8       (defclass ,name ,superclasses
   9         ,(loop for slotd in slots
  10                collect (ldiff slotd (member :array-length slotd)))
  11         ,@options)
  12       (declaim (inline ,to-alien ,to-protocol))
  13       (declaim (inline ,to-protocol ,to-alien))
  14       (defun ,to-protocol (alien &optional instance)
  15         (declare (type (sb-alien:alien (* ,alien-type)) alien)
  16                  (type (or null ,name) instance))
  17         (unless instance
  18           (setf instance (make-instance ',name)))
  19         ,@(loop for slotd in slots
  20                 ;; FIXME: slotds in source are more complicated in general
  21                 ;;
  22                 ;; FIXME: baroque construction of intricate fragility
  23                 for array-length = (getf (cdr slotd) :array-length)
  24                 if array-length
  25                   collect `(progn
  26                              (let ((array (make-array ,array-length)))
  27                                (setf (slot-value instance ',(car slotd))
  28                                      array)
  29                                (dotimes (i ,array-length)
  30                                  (setf (aref array i)
  31                                        (sb-alien:deref
  32                                         (sb-alien:slot alien ',(car slotd))
  33                                         i)))))
  34                 else
  35                   collect `(setf (slot-value instance ',(car slotd))
  36                                  (sb-alien:slot alien ',(car slotd))))
  37         instance)
  38       (defun ,to-alien (instance &optional alien)
  39         (declare (type (or null (sb-alien:alien (* ,alien-type))) alien)
  40                  (type ,name instance))
  41         (unless alien
  42           (setf alien (sb-alien:make-alien ,alien-type)))
  43         ,@(loop for slotd in slots
  44                 for array-length = (getf (cdr slotd) :array-length)
  45                 if array-length
  46                   collect `(progn
  47                              (let ((array (slot-value instance ',(car slotd))))
  48                                (dotimes (i ,array-length)
  49                                  (setf (sb-alien:deref
  50                                         (sb-alien:slot alien ',(car slotd))
  51                                         i)
  52                                        (aref array i)))))
  53                 else
  54                   collect `(setf (sb-alien:slot alien ',(car slotd))
  55                                  (slot-value instance ',(car slotd)))))
  56       (find-class ',name))))
  57
  58 (define-condition sb-posix:syscall-error (error)
  59   ((errno :initarg :errno :reader sb-posix:syscall-errno))
  60   (:report (lambda (c s)
  61              (let ((errno (sb-posix:syscall-errno c)))
  62                (format s "System call error ~A (~A)"
  63                        errno (sb-int:strerror errno))))))
  64
  65 (defun syscall-error ()
  66   (error 'sb-posix:syscall-error :errno (get-errno)))
  67
  68 (declaim (inline never-fails))
  69 (defun never-fails (&rest args)
  70   (declare (ignore args))
  71   nil)
  72
  73 ;;; Some systems may need C-level wrappers, which can live in the
  74 ;;; runtime (so that save-lisp-and-die can produce standalone
  75 ;;; executables).  See REAL-C-NAME in macros.lisp for the use of this
  76 ;;; variable.
  77 (eval-when (:compile-toplevel :load-toplevel)
  78   (setf *c-functions-in-runtime*
  79         '`(#+netbsd ,@("stat" "lstat" "fstat" "readdir" "opendir"))))
  80
  81
  82 ;;; filesystem access
  83 (defmacro define-call* (name &rest arguments)
  84   #-win32 `(define-call ,name ,@arguments)
  85   #+win32 `(define-call ,(if (consp name)
  86                              `(,(concatenate 'string "_" (car name))
  87                                 ,@(cdr name))
  88                              (concatenate 'string "_" name))
  89                ,@arguments))
  90
  91 (define-call* "access" int minusp (pathname filename) (mode int))
  92 (define-call* "chdir" int minusp (pathname filename))
  93 (define-call* "chmod" int minusp (pathname filename) (mode mode-t))
  94 (define-call* "close" int minusp (fd file-descriptor))
  95 (define-call* "creat" int minusp (pathname filename) (mode mode-t))
  96 (define-call* "dup" int minusp (oldfd file-descriptor))
  97 (define-call* "dup2" int minusp (oldfd file-descriptor)
  98               (newfd file-descriptor))
  99 (define-call* ("lseek" :options :largefile)
 100     off-t minusp (fd file-descriptor) (offset off-t)
 101     (whence int))
 102 (define-call* "mkdir" int minusp (pathname filename) (mode mode-t))
 103 (macrolet ((def (x)
 104                `(progn
 105                  (define-call-internally open-with-mode ,x int minusp
 106                    (pathname filename) (flags int) (mode mode-t))
 107                  (define-call-internally open-without-mode ,x int minusp
 108                    (pathname filename) (flags int))
 109                  (define-entry-point ,x
 110                      (pathname flags &optional (mode nil mode-supplied))
 111                    (if mode-supplied
 112                        (open-with-mode pathname flags mode)
 113                        (open-without-mode pathname flags))))))
 114     (def #-win32 "open" #+win32 "_open"))
 115 (define-call "rename" int minusp (oldpath filename) (newpath filename))
 116 (define-call* "rmdir" int minusp (pathname filename))
 117 (define-call* "unlink" int minusp (pathname filename))
 118 (define-call #-netbsd "opendir" #+netbsd "_opendir"
 119     (* t) null-alien (pathname filename))
 120 (define-call (#-netbsd "readdir" #+netbsd "_readdir" :options :largefile)
 121   (* dirent)
 122   ;; readdir() has the worst error convention in the world.  It's just
 123   ;; too painful to support.  (return is NULL _and_ errno "unchanged"
 124   ;; is not an error, it's EOF).
 125   not
 126   (dir (* t)))
 127 (define-call "closedir" int minusp (dir (* t)))
 128 ;; need to do this here because we can't do it in the DEFPACKAGE
 129 (define-call* "umask" mode-t never-fails (mode mode-t))
 130 (define-call* "getpid" pid-t never-fails)
 131
 132 #-win32
 133 (progn
 134   (define-call "chown" int minusp (pathname filename)
 135                (owner uid-t) (group gid-t))
 136   (define-call "chroot" int minusp (pathname filename))
 137   (define-call "fchdir" int minusp (fd file-descriptor))
 138   (define-call "fchmod" int minusp (fd file-descriptor) (mode mode-t))
 139   (define-call "fchown" int minusp (fd file-descriptor)
 140                (owner uid-t)  (group gid-t))
 141   (define-call "fdatasync" int minusp (fd file-descriptor))
 142   (define-call ("ftruncate" :options :largefile)
 143       int minusp (fd file-descriptor) (length off-t))
 144   (define-call "fsync" int minusp (fd file-descriptor))
 145   (define-call "lchown" int minusp (pathname filename)
 146                (owner uid-t)  (group gid-t))
 147   (define-call "link" int minusp (oldpath filename) (newpath filename))
 148   (define-call "lockf" int minusp (fd file-descriptor) (cmd int) (len off-t))
 149   (define-call "mkfifo" int minusp (pathname filename) (mode mode-t))
 150   (define-call "symlink" int minusp (oldpath filename) (newpath filename))
 151   (define-call "sync" void never-fails)
 152   (define-call ("truncate" :options :largefile)
 153       int minusp (pathname filename) (length off-t))
 154   ;; FIXME: Windows does have _mktemp, which has a slightlty different
 155   ;; interface
 156   (defun mkstemp (template)
 157     ;; we are emulating sb-alien's charset conversion for strings
 158     ;; here, to accommodate for the call-by-reference nature of
 159     ;; mkstemp's template strings.
 160     (let ((arg (sb-ext:string-to-octets
 161                 (filename template)
 162                 :external-format sb-alien::*default-c-string-external-format*)))
 163       (sb-sys:with-pinned-objects (arg)
 164         (let ((result (alien-funcall (extern-alien "mkstemp"
 165                                                    (function int c-string))
 166                                      (sap-alien (sb-alien::vector-sap arg)
 167                                                 (* char)))))
 168           (when (minusp result)
 169             (syscall-error))
 170           (values result
 171                   (sb-ext:octets-to-string
 172                    arg
 173                    :external-format sb-alien::*default-c-string-external-format*))))))
 174   (define-call-internally ioctl-without-arg "ioctl" int minusp
 175                           (fd file-descriptor) (cmd int))
 176   (define-call-internally ioctl-with-int-arg "ioctl" int minusp
 177                           (fd file-descriptor) (cmd int) (arg int))
 178   (define-call-internally ioctl-with-pointer-arg "ioctl" int minusp
 179                           (fd file-descriptor) (cmd int)
 180                           (arg alien-pointer-to-anything-or-nil))
 181   (define-entry-point "ioctl" (fd cmd &optional (arg nil argp))
 182     (if argp
 183         (etypecase arg
 184           ((alien int) (ioctl-with-int-arg fd cmd arg))
 185           ((or (alien (* t)) null) (ioctl-with-pointer-arg fd cmd arg)))
 186         (ioctl-without-arg fd cmd)))
 187   (define-call-internally fcntl-without-arg "fcntl" int minusp
 188                           (fd file-descriptor) (cmd int))
 189   (define-call-internally fcntl-with-int-arg "fcntl" int minusp
 190                           (fd file-descriptor) (cmd int) (arg int))
 191   (define-call-internally fcntl-with-pointer-arg "fcntl" int minusp
 192                           (fd file-descriptor) (cmd int)
 193                           (arg alien-pointer-to-anything-or-nil))
 194   (define-entry-point "fcntl" (fd cmd &optional (arg nil argp))
 195     (if argp
 196         (etypecase arg
 197           ((alien int) (fcntl-with-int-arg fd cmd arg))
 198           ((or (alien (* t)) null) (fcntl-with-pointer-arg fd cmd arg)))
 199         (fcntl-without-arg fd cmd)))
 200
 201   ;; uid, gid
 202   (define-call "geteuid" uid-t never-fails) ; "always successful", it says
 203   (define-call "getresuid" uid-t never-fails)
 204   (define-call "getuid" uid-t never-fails)
 205   (define-call "seteuid" int minusp (uid uid-t))
 206   (define-call "setfsuid" int minusp (uid uid-t))
 207   (define-call "setreuid" int minusp (ruid uid-t) (euid uid-t))
 208   (define-call "setresuid" int minusp (ruid uid-t) (euid uid-t) (suid uid-t))
 209   (define-call "setuid" int minusp (uid uid-t))
 210   (define-call "getegid" gid-t never-fails)
 211   (define-call "getgid" gid-t never-fails)
 212   (define-call "getresgid" gid-t never-fails)
 213   (define-call "setegid" int minusp (gid gid-t))
 214   (define-call "setfsgid" int minusp (gid gid-t))
 215   (define-call "setgid" int minusp (gid gid-t))
 216   (define-call "setregid" int minusp (rgid gid-t) (egid gid-t))
 217   (define-call "setresgid" int minusp (rgid gid-t) (egid gid-t) (sgid gid-t))
 218
 219   ;; processes, signals
 220   (define-call "alarm" int never-fails (seconds unsigned))
 221
 222
 223
 224   #+mach-exception-handler
 225   (progn
 226     ;; FIXME this is a lie, of course this can fail, but there's no
 227     ;; error handling here yet!
 228     (define-call "setup_mach_exceptions" void never-fails)
 229     (define-call ("posix_fork" :c-name "fork") pid-t minusp)
 230     (defun fork ()
 231       (let ((pid (posix-fork)))
 232         (when (= pid 0)
 233           (setup-mach-exceptions))
 234         pid))
 235     (export 'fork :sb-posix))
 236
 237   #-mach-exception-handler
 238   (define-call "fork" pid-t minusp)
 239
 240   (define-call "getpgid" pid-t minusp (pid pid-t))
 241   (define-call "getppid" pid-t never-fails)
 242   (define-call "getpgrp" pid-t never-fails)
 243   (define-call "getsid" pid-t minusp  (pid pid-t))
 244   (define-call "kill" int minusp (pid pid-t) (signal int))
 245   (define-call "killpg" int minusp (pgrp int) (signal int))
 246   (define-call "pause" int minusp)
 247   (define-call "setpgid" int minusp (pid pid-t) (pgid pid-t))
 248   (define-call "setpgrp" int minusp))
 249
 250 (defmacro with-growing-c-string ((buffer size) &body body)
 251   (sb-int:with-unique-names (c-string-block)
 252     `(block ,c-string-block
 253        (let (,buffer)
 254          (flet ((,buffer (&optional (size-incl-null))
 255                   (when size-incl-null
 256                     (setf (sb-sys:sap-ref-8 (sb-alien:alien-sap ,buffer) size-incl-null)
 257                           0))
 258                   (return-from ,c-string-block
 259                     (sb-alien::c-string-to-string
 260                      (sb-alien:alien-sap ,buffer)
 261                      (sb-impl::default-external-format)
 262                      'character))))
 263            (loop for ,size = 128 then (* 2 ,size)
 264                  do (unwind-protect
 265                          (progn
 266                            (setf ,buffer (make-alien c-string ,size))
 267                            ,@body)
 268                       (when ,buffer
 269                         (free-alien ,buffer)))))))))
 270
 271 #-win32
 272 (progn
 273   (export 'readlink :sb-posix)
 274   (defun readlink (pathspec)
 275     (flet ((%readlink (path buf length)
 276              (alien-funcall
 277               (extern-alien "readlink" (function int c-string (* t) int))
 278               path buf length)))
 279       (with-growing-c-string (buf size)
 280         (let ((count (%readlink (filename pathspec) buf size)))
 281           (cond ((minusp count)
 282                  (syscall-error))
 283                 ((< 0 count size)
 284                  (buf count))))))))
 285
 286 (progn
 287   (export 'getcwd :sb-posix)
 288   (defun getcwd ()
 289     (flet ((%getcwd (buffer size)
 290              (alien-funcall
 291               (extern-alien #-win32 "getcwd"
 292                             #+win32 "_getcwd" (function c-string (* t) int))
 293               buffer size)))
 294       (with-growing-c-string (buf size)
 295         (let ((result (%getcwd buf size)))
 296           (cond (result
 297                  (buf))
 298                 ((/= (get-errno) sb-posix:erange)
 299                  (syscall-error))))))))
 300
 301 #-win32
 302 (progn
 303  (export 'wait :sb-posix)
 304  (declaim (inline wait))
 305  (defun wait (&optional statusptr)
 306    (declare (type (or null (simple-array (signed-byte 32) (1))) statusptr))
 307    (let* ((ptr (or statusptr (make-array 1 :element-type '(signed-byte 32))))
 308           (pid (alien-funcall
 309                 (extern-alien "wait" (function pid-t (* int)))
 310                 (sb-sys:vector-sap ptr))))
 311      (if (minusp pid)
 312          (syscall-error)
 313          (values pid (aref ptr 0))))))
 314
 315 #-win32
 316 (progn
 317  (export 'waitpid :sb-posix)
 318  (declaim (inline waitpid))
 319  (defun waitpid (pid options &optional statusptr)
 320    (declare (type (sb-alien:alien pid-t) pid)
 321             (type (sb-alien:alien int) options)
 322             (type (or null (simple-array (signed-byte 32) (1))) statusptr))
 323    (let* ((ptr (or statusptr (make-array 1 :element-type '(signed-byte 32))))
 324           (pid (alien-funcall
 325                 (extern-alien "waitpid" (function pid-t
 326                                                   pid-t (* int) int))
 327                 pid (sb-sys:vector-sap ptr) options)))
 328      (if (minusp pid)
 329          (syscall-error)
 330          (values pid (aref ptr 0)))))
 331  ;; waitpid macros
 332  (define-call "wifexited" boolean never-fails (status int))
 333  (define-call "wexitstatus" int never-fails (status int))
 334  (define-call "wifsignaled" boolean never-fails (status int))
 335  (define-call "wtermsig" int never-fails (status int))
 336  (define-call "wifstopped" boolean never-fails (status int))
 337  (define-call "wstopsig" int never-fails (status int))
 338  #+nil ; see alien/waitpid-macros.c
 339  (define-call "wifcontinued" boolean never-fails (status int)))
 340
 341 ;;; mmap, msync
 342 #-win32
 343 (progn
 344  (define-call ("mmap" :options :largefile) sb-sys:system-area-pointer
 345    (lambda (res)
 346      (= (sb-sys:sap-int res) #.(1- (expt 2 sb-vm::n-machine-word-bits))))
 347    (addr sap-or-nil) (length unsigned) (prot unsigned)
 348    (flags unsigned) (fd file-descriptor) (offset off-t))
 349
 350  (define-call "munmap" int minusp
 351    (start sb-sys:system-area-pointer) (length unsigned))
 352
 353 (define-call "msync" int minusp
 354   (addr sb-sys:system-area-pointer) (length unsigned) (flags int)))
 355
 356 #-win32
 357 (define-call "getpagesize" int minusp)
 358 #+win32
 359 ;;; KLUDGE: This could be taken from GetSystemInfo
 360 (export (defun getpagesize () 4096))
 361
 362 ;;; passwd database
 363 #-win32
 364 (define-protocol-class passwd alien-passwd ()
 365   ((name :initarg :name :accessor passwd-name)
 366    (passwd :initarg :passwd :accessor passwd-passwd)
 367    (uid :initarg :uid :accessor passwd-uid)
 368    (gid :initarg :gid :accessor passwd-gid)
 369    (gecos :initarg :gecos :accessor passwd-gecos)
 370    (dir :initarg :dir :accessor passwd-dir)
 371    (shell :initarg :shell :accessor passwd-shell)))
 372
 373 (defmacro define-pw-call (name arg type)
 374   #-win32
 375   ;; FIXME: this isn't the documented way of doing this, surely?
 376   (let ((lisp-name (intern (string-upcase name) :sb-posix)))
 377     `(progn
 378       (export ',lisp-name :sb-posix)
 379       (declaim (inline ,lisp-name))
 380       (defun ,lisp-name (,arg)
 381         (let ((r (alien-funcall (extern-alien ,name ,type) ,arg)))
 382           (if (null r)
 383               r
 384               (alien-to-passwd r)))))))
 385
 386 (define-pw-call "getpwnam" login-name (function (* alien-passwd) c-string))
 387 (define-pw-call "getpwuid" uid (function (* alien-passwd) uid-t))
 388
 389 #-win32
 390 (define-protocol-class timeval alien-timeval ()
 391   ((sec :initarg :tv-sec :accessor timeval-sec)
 392    (usec :initarg :tv-usec :accessor timeval-usec)))
 393
 394 (define-protocol-class stat alien-stat ()
 395   ((mode :initarg :mode :accessor stat-mode)
 396    (ino :initarg :ino :accessor stat-ino)
 397    (dev :initarg :dev :accessor stat-dev)
 398    (nlink :initarg :nlink :accessor stat-nlink)
 399    (uid :initarg :uid :accessor stat-uid)
 400    (gid :initarg :gid :accessor stat-gid)
 401    (size :initarg :size :accessor stat-size)
 402    (atime :initarg :atime :accessor stat-atime)
 403    (mtime :initarg :mtime :accessor stat-mtime)
 404    (ctime :initarg :ctime :accessor stat-ctime)))
 405
 406 (defmacro define-stat-call (name arg designator-fun type)
 407   ;; FIXME: this isn't the documented way of doing this, surely?
 408   (let ((lisp-name (lisp-for-c-symbol name)))
 409     `(progn
 410       (export ',lisp-name :sb-posix)
 411       (declaim (inline ,lisp-name))
 412       (defun ,lisp-name (,arg &optional stat)
 413         (declare (type (or null (sb-alien:alien (* alien-stat))) stat))
 414         (with-alien-stat a-stat ()
 415           (let ((r (alien-funcall
 416                     (extern-alien ,(real-c-name (list name :options :largefile)) ,type)
 417                     (,designator-fun ,arg)
 418                     a-stat)))
 419             (when (minusp r)
 420               (syscall-error))
 421             (alien-to-stat a-stat stat)))))))
 422
 423 (define-stat-call #-win32 "stat" #+win32 "_stat"
 424                   pathname filename
 425                   (function int c-string (* alien-stat)))
 426
 427 #-win32
 428 (define-stat-call "lstat"
 429                   pathname filename
 430                   (function int c-string (* alien-stat)))
 431 ;;; No symbolic links on Windows, so use stat
 432 #+win32
 433 (progn
 434   (declaim (inline lstat))
 435   (export (defun lstat (filename &optional stat)
 436             (if stat (stat filename stat) (stat filename)))))
 437
 438 (define-stat-call #-win32 "fstat" #+win32 "_fstat"
 439                   fd file-descriptor
 440                   (function int int (* alien-stat)))
 441
 442
 443 ;;; mode flags
 444 (define-call "s_isreg" boolean never-fails (mode mode-t))
 445 (define-call "s_isdir" boolean never-fails (mode mode-t))
 446 (define-call "s_ischr" boolean never-fails (mode mode-t))
 447 (define-call "s_isblk" boolean never-fails (mode mode-t))
 448 (define-call "s_isfifo" boolean never-fails (mode mode-t))
 449 (define-call "s_islnk" boolean never-fails (mode mode-t))
 450 (define-call "s_issock" boolean never-fails (mode mode-t))
 451
 452 #-win32
 453 (progn
 454  (export 'pipe :sb-posix)
 455  (declaim (inline pipe))
 456  (defun pipe (&optional filedes2)
 457    (declare (type (or null (simple-array (signed-byte 32) (2))) filedes2))
 458    (unless filedes2
 459      (setq filedes2 (make-array 2 :element-type '(signed-byte 32))))
 460    (let ((r (alien-funcall
 461              ;; FIXME: (* INT)?  (ARRAY INT 2) would be better
 462              (extern-alien "pipe" (function int (* int)))
 463              (sb-sys:vector-sap filedes2))))
 464      (when (minusp r)
 465        (syscall-error)))
 466    (values (aref filedes2 0) (aref filedes2 1))))
 467
 468 #-win32
 469 (define-protocol-class termios alien-termios ()
 470   ((iflag :initarg :iflag :accessor sb-posix:termios-iflag)
 471    (oflag :initarg :oflag :accessor sb-posix:termios-oflag)
 472    (cflag :initarg :cflag :accessor sb-posix:termios-cflag)
 473    (lflag :initarg :lflag :accessor sb-posix:termios-lflag)
 474    (cc :initarg :cc :accessor sb-posix:termios-cc :array-length nccs)))
 475
 476 #-win32
 477 (progn
 478  (export 'tcsetattr :sb-posix)
 479  (declaim (inline tcsetattr))
 480  (defun tcsetattr (fd actions termios)
 481    (declare (type termios termios))
 482    (with-alien-termios a-termios ()
 483      (termios-to-alien termios a-termios)
 484      (let ((fd (file-descriptor fd)))
 485        (let* ((r (alien-funcall
 486                   (extern-alien
 487                    "tcsetattr"
 488                    (function int int int (* alien-termios)))
 489                   fd actions a-termios)))
 490          (when (minusp r)
 491            (syscall-error)))
 492        (values))))
 493  (export 'tcgetattr :sb-posix)
 494  (declaim (inline tcgetattr))
 495  (defun tcgetattr (fd &optional termios)
 496    (declare (type (or null termios) termios))
 497    (with-alien-termios a-termios ()
 498      (let ((r (alien-funcall
 499                (extern-alien "tcgetattr"
 500                              (function int int (* alien-termios)))
 501                (file-descriptor fd)
 502                a-termios)))
 503        (when (minusp r)
 504          (syscall-error))
 505        (setf termios (alien-to-termios a-termios termios))))
 506    termios)
 507  (export 'cfsetispeed :sb-posix)
 508  (declaim (inline cfsetispeed))
 509  (defun cfsetispeed (speed &optional termios)
 510    (declare (type (or null termios) termios))
 511    (with-alien-termios a-termios ()
 512      (let ((r (alien-funcall
 513                (extern-alien "cfsetispeed"
 514                              (function int (* alien-termios) speed-t))
 515                a-termios
 516                speed)))
 517        (when (minusp r)
 518          (syscall-error))
 519        (setf termios (alien-to-termios a-termios termios))))
 520    termios)
 521  (export 'cfsetospeed :sb-posix)
 522  (declaim (inline cfsetospeed))
 523  (defun cfsetospeed (speed &optional termios)
 524    (declare (type (or null termios) termios))
 525    (with-alien-termios a-termios ()
 526      (let ((r (alien-funcall
 527                (extern-alien "cfsetospeed"
 528                              (function int (* alien-termios) speed-t))
 529                a-termios
 530                speed)))
 531        (when (minusp r)
 532          (syscall-error))
 533        (setf termios (alien-to-termios a-termios termios))))
 534    termios)
 535  (export 'cfgetispeed :sb-posix)
 536  (declaim (inline cfgetispeed))
 537  (defun cfgetispeed (termios)
 538    (declare (type termios termios))
 539    (with-alien-termios a-termios ()
 540      (termios-to-alien termios a-termios)
 541      (alien-funcall (extern-alien "cfgetispeed"
 542                                   (function speed-t (* alien-termios)))
 543                     a-termios)))
 544  (export 'cfgetospeed :sb-posix)
 545  (declaim (inline cfgetospeed))
 546  (defun cfgetospeed (termios)
 547    (declare (type termios termios))
 548    (with-alien-termios a-termios ()
 549      (termios-to-alien termios a-termios)
 550      (alien-funcall (extern-alien "cfgetospeed"
 551                                  (function speed-t (* alien-termios)))
 552                     a-termios))))
 553
 554
 555 #-win32
 556 (progn
 557   (export 'time :sb-posix)
 558   (defun time ()
 559     (let ((result (alien-funcall (extern-alien "time"
 560                                                (function time-t (* time-t)))
 561                                  nil)))
 562       (if (minusp result)
 563           (syscall-error)
 564           result)))
 565   (export 'utime :sb-posix)
 566   (defun utime (filename &optional access-time modification-time)
 567     (let ((fun (extern-alien "utime" (function int c-string
 568                                                (* alien-utimbuf))))
 569           (name (filename filename)))
 570       (if (not (and access-time modification-time))
 571           (alien-funcall fun name nil)
 572           (with-alien ((utimbuf (struct alien-utimbuf)))
 573             (setf (slot utimbuf 'actime) (or access-time 0)
 574                   (slot utimbuf 'modtime) (or modification-time 0))
 575             (let ((result (alien-funcall fun name (alien-sap utimbuf))))
 576               (if (minusp result)
 577                   (syscall-error)
 578                   result))))))
 579   (export 'utimes :sb-posix)
 580   (defun utimes (filename &optional access-time modification-time)
 581     (flet ((seconds-and-useconds (time)
 582              (multiple-value-bind (integer fractional)
 583                  (cl:truncate time)
 584                (values integer (cl:truncate (* fractional 1000000)))))
 585            (maybe-syscall-error (value)
 586              (if (minusp value)
 587                  (syscall-error)
 588                  value)))
 589       (let ((fun (extern-alien "utimes" (function int c-string
 590                                                   (* (array alien-timeval 2)))))
 591             (name (filename filename)))
 592         (if (not (and access-time modification-time))
 593             (maybe-syscall-error (alien-funcall fun name nil))
 594             (with-alien ((buf (array alien-timeval 2)))
 595               (let ((actime (deref buf 0))
 596                     (modtime (deref buf 1)))
 597                 (setf (values (slot actime 'sec)
 598                               (slot actime 'usec))
 599                       (seconds-and-useconds (or access-time 0))
 600                       (values (slot modtime 'sec)
 601                               (slot modtime 'usec))
 602                       (seconds-and-useconds (or modification-time 0)))
 603                 (maybe-syscall-error (alien-funcall fun name
 604                                                     (alien-sap buf))))))))))
 605
 606
 607 ;;; environment
 608
 609 (export 'getenv :sb-posix)
 610 (defun getenv (name)
 611   (let ((r (alien-funcall
 612             (extern-alien "getenv" (function (* char) c-string))
 613             name)))
 614     (declare (type (alien (* char)) r))
 615     (unless (null-alien r)
 616       (cast r c-string))))
 617 (define-call "putenv" int minusp (string c-string))
 618
 619 ;;; syslog
 620 #-win32
 621 (progn
 622   (export 'openlog :sb-posix)
 623   (export 'syslog :sb-posix)
 624   (export 'closelog :sb-posix)
 625   (defun openlog (ident options &optional (facility log-user))
 626     (alien-funcall (extern-alien
 627                     "openlog" (function void c-string int int))
 628                    ident options facility))
 629   (defun syslog (priority format &rest args)
 630     "Send a message to the syslog facility, with severity level
 631 PRIORITY.  The message will be formatted as by CL:FORMAT (rather
 632 than C's printf) with format string FORMAT and arguments ARGS."
 633     (flet ((syslog1 (priority message)
 634              (alien-funcall (extern-alien
 635                              "syslog" (function void int c-string c-string))
 636                             priority "%s" message)))
 637       (syslog1 priority (apply #'format nil format args))))
 638   (define-call "closelog" void never-fails))