scripts/scons.bat

   1 @REM __COPYRIGHT__
   2 @echo off
   3 set SCONS_ERRORLEVEL=
   4 if "%OS%" == "Windows_NT" goto WinNT
   5
   6 @REM for 9x/Me you better not have more than 9 args
   7 python -c "from os.path import join; import sys; sys.path = [ join(sys.prefix, 'Lib', 'site-packages', 'scons-__VERSION__'), join(sys.prefix, 'Lib', 'site-packages', 'scons'), join(sys.prefix, 'scons-__VERSION__'), join(sys.prefix, 'scons')] + sys.path; import SCons.Script; SCons.Script.main()" %*
   8 @REM no way to set exit status of this script for 9x/Me
   9 goto endscons
  10
  11 @REM Credit where credit is due:  we return the exit code despite our
  12 @REM use of setlocal+endlocal using a technique from Bear's Journal:
  13 @REM http://code-bear.com/bearlog/2007/06/01/getting-the-exit-code-from-a-batch-file-that-is-run-from-a-python-program/
  14
  15 :WinNT
  16 setlocal
  17 @REM ensure the script will be executed with the Python it was installed for
  18 pushd %~dp0..
  19 set path=%~dp0;%CD%;%path%
  20 popd
  21 @REM try the script named as the .bat file in current dir, then in Scripts subdir
  22 set scriptname=%~dp0%~n0.py
  23 if not exist "%scriptname%" set scriptname=%~dp0Scripts\%~n0.py
  24 @REM Handle when running from wheel where the script has no .py extension
  25 if not exist "%scriptname%" set scriptname=%~dp0%~n0
  26 python "%scriptname%" %*
  27 endlocal & set SCONS_ERRORLEVEL=%ERRORLEVEL%
  28
  29 if NOT "%COMSPEC%" == "%SystemRoot%\system32\cmd.exe" goto returncode
  30 if errorlevel 9009 echo you do not have python in your PATH
  31 goto endscons
  32
  33 :returncode
  34 exit /B %SCONS_ERRORLEVEL%
  35
  36 :endscons
  37 call :returncode %SCONS_ERRORLEVEL%