sdcc/device/lib/sm83/setjmp.s

   1 ;--------------------------------------------------------------------------
   2 ;  setjmp.s
   3 ;
   4 ;  Copyright (C) 2011-2021, Philipp Klaus Krause
   5 ;  Copyright (C) 2021-2022, Sebastian 'basxto' Riedel (sdcc@basxto.de)
   6 ;
   7 ;  This library is free software; you can redistribute it and/or modify it
   8 ;  under the terms of the GNU General Public License as published by the
   9 ;  Free Software Foundation; either version 2, or (at your option) any
  10 ;  later version.
  11 ;
  12 ;  This library is distributed in the hope that it will be useful,
  13 ;  but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 ;  GNU General Public License for more details.
  16 ;
  17 ;  You should have received a copy of the GNU General Public License
  18 ;  along with this library; see the file COPYING. If not, write to the
  19 ;  Free Software Foundation, 51 Franklin Street, Fifth Floor, Boston,
  20 ;   MA 02110-1301, USA.
  21 ;
  22 ;  As a special exception, if you link this library with other files,
  23 ;  some of which are compiled with SDCC, to produce an executable,
  24 ;  this library does not by itself cause the resulting executable to
  25 ;  be covered by the GNU General Public License. This exception does
  26 ;  not however invalidate any other reasons why the executable file
  27 ;   might be covered by the GNU General Public License.
  28 ;--------------------------------------------------------------------------
  29
  30         .area   _CODE
  31
  32         .globl ___setjmp
  33
  34 ___setjmp:
  35
  36         ldhl sp, #0
  37
  38         ; Load return address into bc.
  39         ld      a, (hl+)
  40         ld      c, a
  41         ld      a, (hl+)
  42         ld      b, a
  43
  44         ; Load env into hl, sp+2 into de
  45         ld      a, h
  46         ld      h, d
  47         ld      d, a
  48
  49         ld      a, l
  50         ld      l, e
  51
  52         ; Store stack pointer.
  53         ld      (hl+), a
  54         ld      a, d
  55         ld      (hl+), a
  56
  57         ; Store return address.
  58         ld      a, c
  59         ld      (hl+), a
  60         ld      (hl), b
  61
  62         ; Return 0.
  63         ld      bc, #0
  64         ret
  65
  66 .globl _longjmp
  67
  68 _longjmp:
  69         ; Ensure that return value is non-zero.
  70         ld      a, c
  71         or      a, b
  72         jr      NZ, 0001$
  73         inc     bc
  74
  75 0001$:
  76         ; Get stack pointer.
  77         ld      a, (de)
  78         ld      l, a
  79         inc     de
  80         ld      a, (de)
  81         ld      h, a
  82         inc     de
  83
  84         ; Restore stack pointer.
  85         ld      sp, hl
  86
  87         ; Get return address.
  88         ld      l, e
  89         ld      h, d
  90         ld      a, (hl+)
  91         ld      h, (hl)
  92         ld      l, a
  93
  94         ; Return value is in bc.
  95
  96         ; Jump.
  97         jp      (hl)
  98