sdcc/device/lib/z80/__uitobcd.s

   1 ;--------------------------------------------------------------------------
   2 ;  __uitobcd.s
   3 ;
   4 ;  Copyright (C) 2020-2021, Sergey Belyashov
   5 ;
   6 ;  This library is free software; you can redistribute it and/or modify it
   7 ;  under the terms of the GNU General Public License as published by the
   8 ;  Free Software Foundation; either version 2, or (at your option) any
   9 ;  later version.
  10 ;
  11 ;  This library is distributed in the hope that it will be useful,
  12 ;  but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 ;  GNU General Public License for more details.
  15 ;
  16 ;  You should have received a copy of the GNU General Public License
  17 ;  along with this library; see the file COPYING. If not, write to the
  18 ;  Free Software Foundation, 51 Franklin Street, Fifth Floor, Boston,
  19 ;   MA 02110-1301, USA.
  20 ;
  21 ;  As a special exception, if you link this library with other files,
  22 ;  some of which are compiled with SDCC, to produce an executable,
  23 ;  this library does not by itself cause the resulting executable to
  24 ;  be covered by the GNU General Public License. This exception does
  25 ;  not however invalidate any other reasons why the executable file
  26 ;   might be covered by the GNU General Public License.
  27 ;--------------------------------------------------------------------------
  28
  29         .module __uitobcd
  30         .optsdcc -mz80 sdcccall(1)
  31
  32         .area   _CODE
  33
  34         .globl ___uitobcd
  35 ;
  36 ; void __uitobcd (unsigned int v, unsigned char bcd[3])
  37 ; __uitobcd converts v to BCD representation to the bcd.
  38 ; bcd[] will contain BCD value.
  39 ;
  40 ___uitobcd:
  41         push    de
  42 ;
  43         ld      bc, #0x1000
  44         ld      d, c
  45         ld      e, c
  46 ;
  47 ;--- begin speed optimization
  48 ;
  49         ld      a, h
  50         or      a, a
  51         jr      NZ, 100$
  52 ;
  53         ld      h, l
  54         srl     b
  55 ;
  56 ;--- end speed optimization
  57 ;
  58 ; HL - binary value
  59 ; CDE - future BCD value
  60 ; B - bits count (16)
  61 100$:
  62         add     hl, hl
  63         ld      a, e
  64         adc     a, a
  65         daa
  66         ld      e, a
  67         ld      a, d
  68         adc     a, a
  69         daa
  70         ld      d, a
  71         ld      a, c
  72         adc     a, a
  73         daa
  74         ld      c, a
  75         djnz    100$
  76 ;
  77         pop     hl
  78         ld      (hl), e
  79         inc     hl
  80         ld      (hl), d
  81         inc     hl
  82         ld      (hl), c
  83 ;
  84         ret