sdcc/device/lib/mcs51/gptr_cmp.asm

   1 ;--------------------------------------------------------------------------
   2 ;  gptr_cmp.asm - C run-time: compare two generic pointers
   3 ;
   4 ;  Copyright (C) 2011, Maarten Brock
   5 ;
   6 ;  This library is free software; you can redistribute it and/or modify it
   7 ;  under the terms of the GNU General Public License as published by the
   8 ;  Free Software Foundation; either version 2, or (at your option) any
   9 ;  later version.
  10 ;
  11 ;  This library is distributed in the hope that it will be useful,
  12 ;  but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 ;  GNU General Public License for more details.
  15 ;
  16 ;  You should have received a copy of the GNU General Public License
  17 ;  along with this library; see the file COPYING. If not, write to the
  18 ;  Free Software Foundation, 51 Franklin Street, Fifth Floor, Boston,
  19 ;   MA 02110-1301, USA.
  20 ;
  21 ;  As a special exception, if you link this library with other files,
  22 ;  some of which are compiled with SDCC, to produce an executable,
  23 ;  this library does not by itself cause the resulting executable to
  24 ;  be covered by the GNU General Public License. This exception does
  25 ;  not however invalidate any other reasons why the executable file
  26 ;  might be covered by the GNU General Public License.
  27 ;--------------------------------------------------------------------------
  28
  29         .area HOME    (CODE)
  30         .area GSINIT0 (CODE)
  31         .area GSINIT1 (CODE)
  32         .area GSINIT2 (CODE)
  33         .area GSINIT3 (CODE)
  34         .area GSINIT4 (CODE)
  35         .area GSINIT5 (CODE)
  36         .area GSINIT  (CODE)
  37         .area GSFINAL (CODE)
  38         .area CSEG    (CODE)
  39
  40         .area HOME    (CODE)
  41
  42 ; compares two generic pointers.
  43 ; if p1 < p2  return NZ and C
  44 ; if p1 == p2 return  Z and NC
  45 ; if p1 > p2  return NZ and NC
  46 ; if both are a NULL pointer (yes, we have several) also return Z and NC
  47 ; assumes that banks never map to address 0x0000
  48 ; so it suffices to check dptr part only and ignore b
  49
  50 ___gptr_cmp::
  51         mov  a,sp
  52         add  a,#0xfc
  53         clr  c
  54         xch  a,r0
  55         push acc
  56         mov  a,@r0
  57         inc  r0
  58         orl  a,@r0
  59         jnz  00001$
  60         mov  a,dpl
  61         orl  a,dph
  62 ; if both are NULL, return Z and NC
  63         jz   00002$
  64 00001$:
  65         push dpl
  66         dec  r0
  67         mov  a,dpl
  68         subb a,@r0
  69         mov  dpl,a
  70         inc  r0
  71         mov  a,dph
  72         subb a,@r0
  73         orl  dpl,a
  74         inc  r0
  75         mov  a,b
  76         subb a,@r0
  77         orl  a,dpl
  78 ; p2 < p1, return NZ and C
  79 ; p2 = p1, return Z and NC
  80 ; p2 > p1, return NZ and NC
  81         pop  dpl
  82 00002$:
  83         xch  a,r0
  84         pop  acc
  85         xch  a,r0
  86         ret