sdcc/device/lib/mos6502-stack-auto/_setjmp.c

   1 /*-------------------------------------------------------------------------
   2    setjmp.c - source file for ANSI routines setjmp & longjmp
   3
   4    Copyright (C) 2020, Steven Hugg. hugg@efasterlight.com
   5
   6    This library is free software; you can redistribute it and/or modify it
   7    under the terms of the GNU General Public License as published by the
   8    Free Software Foundation; either version 2, or (at your option) any
   9    later version.
  10
  11    This library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14    GNU General Public License for more details.
  15
  16    You should have received a copy of the GNU General Public License
  17    along with this library; see the file COPYING. If not, write to the
  18    Free Software Foundation, 51 Franklin Street, Fifth Floor, Boston,
  19    MA 02110-1301, USA.
  20
  21    As a special exception, if you link this library with other files,
  22    some of which are compiled with SDCC, to produce an executable,
  23    this library does not by itself cause the resulting executable to
  24    be covered by the GNU General Public License. This exception does
  25    not however invalidate any other reasons why the executable file
  26    might be covered by the GNU General Public License.
  27 -------------------------------------------------------------------------*/
  28
  29 #include <sdcc-lib.h>
  30 #define __SDCC_HIDE_LONGJMP
  31 #include <setjmp.h>
  32
  33 static void dummy (void) __naked
  34 {
  35         __asm
  36
  37 ;--------------------------------------------------------
  38 ; extended address mode data
  39 ;--------------------------------------------------------
  40         .area BSS
  41 _longjmp_PARM_2:
  42         .ds 2
  43 ;--------------------------------------------------------
  44 ; code
  45 ;--------------------------------------------------------
  46         .area CODE
  47 ;------------------------------------------------------------
  48 ;Allocation info for local variables in function '__setjmp'
  49 ;------------------------------------------------------------
  50 ;buf                       Allocated with name '___setjmp_buf'
  51 ;------------------------------------------------------------
  52 ;_setjmp.c:205: int __setjmp (jmp_buf buf)
  53 ;       -----------------------------------------
  54 ;        function __setjmp
  55 ;       -----------------------------------------
  56 ;       Stack space usage: 1 bytes.
  57         .globl ___setjmp
  58 ___setjmp:
  59         stx     *(DPTR + 1)             ; msb(buf)
  60         sta     *(DPTR + 0)             ; lsb(buf)
  61
  62         ; save stack pointer
  63         tsx
  64         ldy     #0
  65         txa
  66         sta     [DPTR],y
  67
  68         ; save return address
  69         lda     0x101,x
  70         iny
  71         sta     [DPTR],y
  72         lda     0x102,x
  73         iny
  74         sta     [DPTR],y
  75
  76         ; return 0
  77         lda     #0
  78         tax
  79         rts
  80
  81 ;------------------------------------------------------------
  82 ;Allocation info for local variables in function 'longjmp'
  83 ;------------------------------------------------------------
  84 ;rv                        Allocated with name '_longjmp_PARM_2'
  85 ;buf                       Allocated with name '_longjmp_buf'
  86 ;------------------------------------------------------------
  87 ;_setjmp.c:216: int longjmp (jmp_buf buf, int rv)
  88 ;       -----------------------------------------
  89 ;        function longjmp
  90 ;       -----------------------------------------
  91 ;       Stack space usage: 1 bytes.
  92         .globl _longjmp
  93         .globl _longjmp_PARM_2
  94 _longjmp:
  95         stx     *(DPTR + 1)             ; msb(buf)
  96         sta     *(DPTR + 0)             ; lsb(buf)
  97
  98         ; restore stack pointer
  99         ldy     #0
 100         lda     [DPTR],y
 101         tax
 102         txs
 103
 104         ; set return address
 105         iny
 106         lda     [DPTR],y
 107         sta     0x101,x
 108         iny
 109         lda     [DPTR],y
 110         sta     0x102,x
 111
 112 ;_setjmp.c:224: return rv ? rv : 1;
 113         ldx     (_longjmp_PARM_2 + 1)
 114         txa
 115         ora     (_longjmp_PARM_2 + 0)
 116         beq     0001$
 117         lda     (_longjmp_PARM_2 + 0)
 118         rts
 119 0001$:
 120         lda     #0x01
 121         rts
 122
 123         __endasm;
 124 }