sdcc/device/lib/pic16/libc/utils/cvtdec.S

   1 ;--------------------------------------------------------------------------
   2 ;  cvtdec.S - convert a 16-bit binary word to 5 BCD bytes
   3 ;
   4 ;  Copyright (C) 2004, George Gallant <ggallant571 AT verizon.net>
   5 ;
   6 ;  This library is free software; you can redistribute it and/or modify it
   7 ;  under the terms of the GNU General Public License as published by the
   8 ;  Free Software Foundation; either version 2, or (at your option) any
   9 ;  later version.
  10 ;
  11 ;  This library is distributed in the hope that it will be useful,
  12 ;  but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 ;  GNU General Public License for more details.
  15 ;
  16 ;  You should have received a copy of the GNU General Public License
  17 ;  along with this library; see the file COPYING. If not, write to the
  18 ;  Free Software Foundation, 51 Franklin Street, Fifth Floor, Boston,
  19 ;   MA 02110-1301, USA.
  20 ;
  21 ;  As a special exception, if you link this library with other files,
  22 ;  some of which are compiled with SDCC, to produce an executable,
  23 ;  this library does not by itself cause the resulting executable to
  24 ;  be covered by the GNU General Public License. This exception does
  25 ;  not however invalidate any other reasons why the executable file
  26 ;  might be covered by the GNU General Public License.
  27 ;--------------------------------------------------------------------------
  28
  29 ;--
  30 ;
  31 ;       File:   cvtdec.asm
  32 ;       Author: George Gallant
  33 ;       Date:   19OCT04
  34 ;
  35 ;       This routine is based on the code and algorithm by
  36 ;       Nikolai Golovchenko and Scott Dattalo presented in
  37 ;       the piclist webb site on radix conversion methods.
  38 ;       Modified to support integers from 0 to 65535 and coded
  39 ;       for the pic18 chip set.
  40 ;
  41 ;                          Digit
  42 ;       BIT  Weight  4   3   2   1   0
  43 ;       ---  ------ --- --- --- --- ---
  44 ;        0      1    0   0   0   0   1
  45 ;        1      2    0   0   0   0   2
  46 ;        2      4    0   0   0   0   4
  47 ;        3      8    0   0   0   0   8
  48 ;
  49 ;        4     16    0   0   0   1   6
  50 ;        5     32    0   0   0   3   2
  51 ;        6     64    0   0   0   6   4
  52 ;        7    128    0   0   1   2   8
  53 ;
  54 ;        8    256    0   0   2   5   6
  55 ;        9    512    0   0   5   1   2
  56 ;       10   1024    0   1   0   2   4
  57 ;       11   2048    0   2   0   4   8
  58 ;
  59 ;       12   4096    0   4   0   9   6
  60 ;       13   8192    0   8   1   9   2
  61 ;       14  16384    1   6   3   8   4
  62 ;       15  32768    3   2   7   6   8
  63 ;
  64 ;--
  65                 nolist
  66                 include <p18fxxx.inc>
  67                 list
  68
  69
  70                 global  cvt_dec_word
  71
  72                 udata
  73
  74                 global  digits
  75
  76 digits:         res     6
  77
  78                 code
  79
  80
  81 ;--
  82 ;
  83 ;       Convert a 16-bit binary word to 5 BCD bytes
  84 ;
  85 ;       On Call
  86 ;               PROD    16 bit word
  87 ;               FSR0    pointer to ascii buffer
  88 ;
  89 ;       On Return
  90 ;               digits[4:0] contain the BCD integers
  91 ;
  92 ;       Notes:  1. strip leading zeros
  93 ;               2. only positive integers on input
  94 ;               3. FSR0, PROD & W are modified and not preserved
  95 ;
  96 ;--
  97 cvt_dec_word:   clrw                            ;calculate digit 0 - lsd
  98
  99                 btfsc   PRODL,0                 ;bit0
 100                 addlw   1
 101
 102                 btfsc   PRODL,1                 ;bit1
 103                 addlw   2
 104
 105                 btfsc   PRODL,2                 ;bit2
 106                 addlw   4
 107
 108                 btfsc   PRODL,3                 ;bit3
 109                 addlw   8
 110
 111                 btfsc   PRODL,4                 ;bit4
 112                 addlw   6
 113
 114                 btfsc   PRODL,5                 ;bit5
 115                 addlw   2
 116
 117                 btfsc   PRODL,6                 ;bit6
 118                 addlw   4
 119
 120                 btfsc   PRODL,7                 ;bit7
 121                 addlw   8
 122
 123                 btfsc   PRODH,0                 ;bit8
 124                 addlw   6
 125
 126                 btfsc   PRODH,1                 ;bit9
 127                 addlw   2
 128
 129                 btfsc   PRODH,2                 ;bit10
 130                 addlw   4
 131
 132                 btfsc   PRODH,3                 ;bit11
 133                 addlw   8
 134
 135                 btfsc   PRODH,4                 ;bit12
 136                 addlw   6
 137
 138                 btfsc   PRODH,5                 ;bit13
 139                 addlw   2
 140
 141                 btfsc   PRODH,6                 ;bit14
 142                 addlw   4
 143
 144                 btfsc   PRODH,7                 ;bit15
 145                 addlw   8
 146
 147                 clrf    digits+1                ;setup for carry in 10's
 148 @1:             addlw   -10
 149                 bnc     @2
 150                 incf    digits+1,f
 151                 bra     @1
 152
 153 @2:             addlw   10
 154                 movwf   digits+0
 155
 156 ;       calculate digit 1
 157
 158                 movf    digits+1,w
 159
 160                 btfsc   PRODL,4                 ;bit4
 161                 addlw   1
 162
 163                 btfsc   PRODL,5                 ;bit5
 164                 addlw   3
 165
 166                 btfsc   PRODL,6                 ;bit6
 167                 addlw   6
 168
 169                 btfsc   PRODL,7                 ;bit7
 170                 addlw   2
 171
 172                 btfsc   PRODH,0                 ;bit8
 173                 addlw   5
 174
 175                 btfsc   PRODH,1                 ;bit9
 176                 addlw   1
 177
 178                 btfsc   PRODH,2                 ;bit10
 179                 addlw   2
 180
 181                 btfsc   PRODH,3                 ;bit11
 182                 addlw   4
 183
 184                 btfsc   PRODH,4                 ;bit12
 185                 addlw   9
 186
 187                 btfsc   PRODH,5                 ;bit13
 188                 addlw   9
 189
 190                 btfsc   PRODH,6                 ;bit14
 191                 addlw   8
 192
 193                 btfsc   PRODH,7                 ;bit15
 194                 addlw   6
 195
 196                 clrf    digits+2                ;setup for carry into 100's
 197 @3:             addlw   -10
 198                 bnc     @4
 199                 incf    digits+2,f
 200                 bra     @3
 201
 202 @4:             addlw   10
 203                 movwf   digits+1
 204
 205 ;       calculate digit 2
 206
 207                 movf    digits+2,w
 208
 209                 btfsc   PRODL,7                 ;bit7
 210                 addlw   1
 211
 212                 btfsc   PRODH,0                 ;bit8
 213                 addlw   2
 214
 215                 btfsc   PRODH,1                 ;bit9
 216                 addlw   5
 217
 218                 btfsc   PRODH,5                 ;bit13
 219                 addlw   1
 220
 221                 btfsc   PRODH,6                 ;bit14
 222                 addlw   3
 223
 224                 btfsc   PRODH,7                 ;bit15
 225                 addlw   7
 226
 227                 clrf    digits+3                ;setup for carry into 1000's
 228 @5:             addlw   -10
 229                 bnc     @6
 230                 incf    digits+3,f
 231                 bra     @5
 232 @6:             addlw   10
 233
 234                 movwf   digits+2
 235
 236 ;       calculate digit 3
 237
 238                 movf    digits+3,w
 239
 240                 btfsc   PRODH,2                 ;bit10
 241                 addlw   1
 242
 243                 btfsc   PRODH,3                 ;bit11
 244                 addlw   2
 245
 246                 btfsc   PRODH,4                 ;bit12
 247                 addlw   4
 248
 249                 btfsc   PRODH,5                 ;bit13
 250                 addlw   8
 251
 252                 btfsc   PRODH,6                 ;bit14
 253                 addlw   6
 254
 255                 btfsc   PRODH,7                 ;bit15
 256                 addlw   2
 257
 258                 clrf    digits+4                ;setup for carry into 10000's
 259 @7:             addlw   -10
 260                 bnc     @8
 261                 incf    digits+4,f
 262                 bra     @7
 263
 264 @8:             addlw   10
 265                 movwf   digits+3
 266
 267 ;       calculate digit 4
 268
 269                 movf    digits+4,w
 270
 271                 btfsc   PRODH,6                 ;bit14
 272                 addlw   1
 273
 274                 btfsc   PRODH,7                 ;bit15
 275                 addlw   3
 276
 277 @9:             addlw   -10
 278                 bc      @9
 279
 280                 addlw   10
 281 ;               movwf   digits+4
 282
 283 ;               movf    digits+4,w
 284                 bnz     @11
 285                 movf    digits+3,w
 286                 bnz     @12
 287                 movf    digits+2,w
 288                 bnz     @13
 289                 movf    digits+1,w
 290                 bnz     @14
 291                 bra     @15
 292
 293 @11:            addlw   0x30
 294                 movwf   POSTINC0
 295
 296                 movf    digits+3,w
 297 @12:            addlw   0x30
 298                 movwf   POSTINC0
 299
 300                 movf    digits+2,w
 301 @13:            addlw   0x30
 302                 movwf   POSTINC0
 303
 304                 movf    digits+1,w
 305 @14:            addlw   0x30
 306                 movwf   POSTINC0
 307
 308 @15:            movf    digits+0,w
 309                 addlw   0x30
 310                 movwf   POSTINC0
 311
 312                 return
 313
 314                 end