sdcc/device/lib/s08-stack-auto/_setjmp.c

   1 /*-------------------------------------------------------------------------
   2    setjmp.c - source file for ANSI routines setjmp & longjmp
   3
   4    Copyright (C) 2016, Maarten Brock. sourceforge.brock AT dse.nl
   5
   6    This library is free software; you can redistribute it and/or modify it
   7    under the terms of the GNU General Public License as published by the
   8    Free Software Foundation; either version 2, or (at your option) any
   9    later version.
  10
  11    This library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14    GNU General Public License for more details.
  15
  16    You should have received a copy of the GNU General Public License
  17    along with this library; see the file COPYING. If not, write to the
  18    Free Software Foundation, 51 Franklin Street, Fifth Floor, Boston,
  19    MA 02110-1301, USA.
  20
  21    As a special exception, if you link this library with other files,
  22    some of which are compiled with SDCC, to produce an executable,
  23    this library does not by itself cause the resulting executable to
  24    be covered by the GNU General Public License. This exception does
  25    not however invalidate any other reasons why the executable file
  26    might be covered by the GNU General Public License.
  27 -------------------------------------------------------------------------*/
  28
  29 #include <sdcc-lib.h>
  30 #define __SDCC_HIDE_LONGJMP
  31 #include <setjmp.h>
  32
  33 static void dummy (void) __naked
  34 {
  35         __asm
  36
  37 ;--------------------------------------------------------
  38 ; overlayable items in ram
  39 ;--------------------------------------------------------
  40         .area   OSEG    (PAG, OVR)
  41 ___setjmp_buf:
  42         .ds 2
  43         .area   OSEG    (PAG, OVR)
  44 _longjmp_buf:
  45         .ds 2
  46 ;--------------------------------------------------------
  47 ; extended address mode data
  48 ;--------------------------------------------------------
  49         .area XSEG
  50 _longjmp_PARM_2:
  51         .ds 2
  52 ;--------------------------------------------------------
  53 ; code
  54 ;--------------------------------------------------------
  55         .area CSEG    (CODE)
  56 ;------------------------------------------------------------
  57 ;Allocation info for local variables in function '__setjmp'
  58 ;------------------------------------------------------------
  59 ;buf                       Allocated with name '___setjmp_buf'
  60 ;------------------------------------------------------------
  61 ;_setjmp.c:205: int __setjmp (jmp_buf buf)
  62 ;       -----------------------------------------
  63 ;        function __setjmp
  64 ;       -----------------------------------------
  65 ;       Stack space usage: 1 bytes.
  66         .globl ___setjmp
  67 ___setjmp:
  68         stx     (___setjmp_buf + 0)             ; msb(buf)
  69         sta     (___setjmp_buf + 1)             ; lsb(buf)
  70
  71         ; save stack pointer
  72         tsx
  73         pshh
  74         txa
  75         ldhx    (___setjmp_buf)
  76         sta     1,x
  77         pula
  78         sta     0,x
  79
  80         ; save return address
  81         lda     1,s
  82         sta     2,x
  83         lda     2,s
  84         sta     3,x
  85
  86         ; return 0
  87         clra
  88         tax
  89         rts
  90
  91 ;------------------------------------------------------------
  92 ;Allocation info for local variables in function 'longjmp'
  93 ;------------------------------------------------------------
  94 ;rv                        Allocated with name '_longjmp_PARM_2'
  95 ;buf                       Allocated with name '_longjmp_buf'
  96 ;------------------------------------------------------------
  97 ;_setjmp.c:216: int longjmp (jmp_buf buf, int rv)
  98 ;       -----------------------------------------
  99 ;        function longjmp
 100 ;       -----------------------------------------
 101 ;       Stack space usage: 1 bytes.
 102         .globl _longjmp
 103         .globl _longjmp_PARM_2
 104 _longjmp:
 105         stx     (_longjmp_buf + 0)              ; msb(buf)
 106         sta     (_longjmp_buf + 1)              ; lsb(buf)
 107
 108         ; Since rv is on the current stack, we need to move it to
 109         ; where we can still access it after switching stack pointer.
 110         lda     3,s
 111         sta     (_longjmp_PARM_2 + 0)
 112         lda     4,s
 113         sta     (_longjmp_PARM_2 + 1)
 114
 115         ; restore stack pointer
 116         ldhx    (_longjmp_buf)
 117         lda     0,x
 118         psha
 119         ldx     1,x
 120         pulh
 121         txs
 122
 123         ; set return address
 124         ldhx    (_longjmp_buf)
 125         lda     2,x
 126         sta     1,s
 127         lda     3,x
 128         sta     2,s
 129
 130 ;_setjmp.c:224: return rv ? rv : 1;
 131         ldx     (_longjmp_PARM_2 + 0)
 132         txa
 133         ora     (_longjmp_PARM_2 + 1)
 134         beq     0001$
 135         lda     (_longjmp_PARM_2 + 1)
 136         rts
 137 0001$:
 138         lda     #0x01
 139         rts
 140
 141         __endasm;
 142 }