sdcc/device/lib/stm8/strcmp.s

   1 ;--------------------------------------------------------------------------
   2 ;  strcmp.s
   3 ;
   4 ;  Copyright (C) 2016-2021, Philipp Klaus Krause
   5 ;
   6 ;  This library is free software; you can redistribute it and/or modify it
   7 ;  under the terms of the GNU General Public License as published by the
   8 ;  Free Software Foundation; either version 2, or (at your option) any
   9 ;  later version.
  10 ;
  11 ;  This library is distributed in the hope that it will be useful,
  12 ;  but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 ;  GNU General Public License for more details.
  15 ;
  16 ;  You should have received a copy of the GNU General Public License
  17 ;  along with this library; see the file COPYING. If not, write to the
  18 ;  Free Software Foundation, 51 Franklin Street, Fifth Floor, Boston,
  19 ;   MA 02110-1301, USA.
  20 ;
  21 ;  As a special exception, if you link this library with other files,
  22 ;  some of which are compiled with SDCC, to produce an executable,
  23 ;  this library does not by itself cause the resulting executable to
  24 ;  be covered by the GNU General Public License. This exception does
  25 ;  not however invalidate any other reasons why the executable file
  26 ;   might be covered by the GNU General Public License.
  27 ;--------------------------------------------------------------------------
  28
  29         .globl _strcmp
  30
  31         .area CODE
  32
  33 ; int strcmp (const char *s1, const char *s2)
  34 _strcmp:
  35
  36         exgw    x, y
  37         ldw     x, (3, sp)
  38
  39 loop:
  40         ld      a, (y)
  41         jreq    null
  42         cp      a, (x)
  43         jrne    diff
  44
  45         ld      a, (1, y)
  46         jreq    null_1
  47         cp      a, (1, x)
  48         jrne    diff
  49
  50         ld      a, (2, y)
  51         jreq    null_2
  52         cp      a, (2, x)
  53         jrne    diff
  54
  55         addw    y, #3
  56         addw    x, #3
  57
  58         jra     loop
  59
  60 null_2:
  61         incw    x
  62 null_1:
  63         incw    x
  64 null:
  65         tnz     (x)
  66         jrne    less
  67         clrw    x
  68         jra     end
  69
  70 diff:
  71         jrult less
  72         ldw     x, #1
  73         jra     end
  74
  75 less:
  76         ldw     x, #-1
  77
  78 end:
  79         popw    y
  80         addw    sp, #2
  81         jp      (y)
  82