app-text/enchant/enchant-2.2.15-r999.ebuild

   1 # Copyright 1999-2021 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 DESCRIPTION="Spellchecker wrapping library"
   7 HOMEPAGE="https://abiword.github.io/enchant/"
   8 SRC_URI="https://github.com/AbiWord/enchant/releases/download/v${PV}/${P}.tar.gz"
   9
  10 LICENSE="LGPL-2.1+"
  11 SLOT="2"
  12 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-solaris"
  13
  14 IUSE="aspell +hunspell nuspell test"
  15 REQUIRED_USE="|| ( hunspell aspell nuspell )"
  16
  17 RDEPEND="
  18         >=dev-libs/glib-2.6:2
  19         aspell? ( app-text/aspell )
  20         nuspell? ( app-text/nuspell )
  21         hunspell? ( >=app-text/hunspell-1.2.1:0= )"
  22 DEPEND="${RDEPEND}
  23         test? ( >=dev-libs/unittest++-2.0.0-r2 )"
  24 BDEPEND="virtual/pkgconfig"
  25
  26 RESTRICT="test" # Tests fail
  27
  28 src_configure() {
  29         # TODO: Add app-text/nuspell support
  30         econf \
  31                 --datadir="${EPREFIX}"/usr/share/enchant-2 \
  32                 --disable-static \
  33                 $(use_enable test relocatable) \
  34                 $(use_with aspell) \
  35                 $(use_with hunspell) \
  36                 $(use_with nuspell) \
  37                 --without-hspell \
  38                 --without-voikko \
  39                 --without-applespell \
  40                 --without-zemberek \
  41                 --with-hunspell-dir="${EPREFIX}"/usr/share/hunspell/
  42 }
  43
  44 src_install() {
  45         default
  46         find "${D}" -name '*.la' -delete || die
  47 }