media-sound/quodlibet/quodlibet-2.6.3.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: /var/cvsroot/gentoo-x86/media-sound/quodlibet/quodlibet-2.6.3.ebuild,v 1.2 2015/04/19 07:09:22 yngwin Exp $
   4
   5 EAPI=5
   6 PYTHON_COMPAT=( python2_7 )
   7 inherit distutils-r1 gnome2-utils fdo-mime
   8
   9 DESCRIPTION="audio library tagger, manager, and player for GTK+"
  10 HOMEPAGE="http://code.google.com/p/quodlibet/"
  11 SRC_URI="http://bitbucket.org/lazka/${PN}-files/raw/default/releases/${P}.tar.gz"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS="amd64 ppc ppc64 x86"
  16 IUSE="+dbus gstreamer ipod +udev"
  17
  18 COMMON_DEPEND=">=dev-python/pygtk-2.24[${PYTHON_USEDEP}]"
  19 RDEPEND="${COMMON_DEPEND}
  20         dev-libs/keybinder:0
  21         dev-python/feedparser[${PYTHON_USEDEP}]
  22         dev-python/pygobject:2[${PYTHON_USEDEP}]
  23         >=media-libs/mutagen-1.20[${PYTHON_USEDEP}]
  24         gstreamer? (
  25                 >=dev-python/gst-python-0.10.2:0.10[${PYTHON_USEDEP}]
  26                 media-libs/gst-plugins-good:0.10
  27                 media-plugins/gst-plugins-meta:0.10
  28                 )
  29         !gstreamer? ( media-libs/xine-lib )
  30         dbus? (
  31                 app-misc/media-player-info
  32                 dev-python/dbus-python[${PYTHON_USEDEP}]
  33                 )
  34         ipod? ( media-libs/libgpod[python,${PYTHON_USEDEP}] )
  35         udev? ( virtual/udev )"
  36 DEPEND="${COMMON_DEPEND}
  37         dev-util/intltool"
  38 REQUIRED_USE="ipod? ( dbus )"
  39
  40 src_prepare() {
  41         sed -i -e '/usr.*bin.*env/s:python:python2:' {exfalso,quodlibet}.py || die
  42
  43         local qlconfig=${PN}/config.py
  44
  45         if ! use gstreamer; then
  46                 sed -i -e '/backend/s:gstbe:xinebe:' ${qlconfig} || die
  47         fi
  48
  49         sed -i -e '/gst_pipeline/s:"":"alsasink":' ${qlconfig} || die
  50
  51         distutils-r1_src_prepare
  52 }
  53
  54 src_install() {
  55         distutils-r1_src_install
  56         dodoc NEWS README
  57 }
  58
  59 pkg_preinst() {
  60         gnome2_icon_savelist
  61 }
  62
  63 pkg_postinst() {
  64         fdo-mime_desktop_database_update
  65         gnome2_icon_cache_update
  66 }
  67
  68 pkg_postrm() {
  69         fdo-mime_desktop_database_update
  70         gnome2_icon_cache_update
  71 }