net-nds/rpcbind/rpcbind-0.2.3-r2.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="5"
   6
   7 inherit eutils systemd
   8
   9 if [[ ${PV} == "9999" ]] ; then
  10         EGIT_REPO_URI="git://linux-nfs.org/~steved/rpcbind.git"
  11         inherit autotools git-r3
  12 else
  13         SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
  14         KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~mips ppc ppc64 ~s390 ~sh sparc x86"
  15 fi
  16
  17 DESCRIPTION="portmap replacement which supports RPC over various protocols"
  18 HOMEPAGE="http://sourceforge.net/projects/rpcbind/"
  19
  20 LICENSE="BSD"
  21 SLOT="0"
  22 IUSE="debug selinux systemd tcpd warmstarts"
  23
  24 CDEPEND=">=net-libs/libtirpc-0.2.3:=
  25         systemd? ( sys-apps/systemd:= )
  26         tcpd? ( sys-apps/tcp-wrappers )"
  27 DEPEND="${CDEPEND}
  28         virtual/pkgconfig"
  29 RDEPEND="${CDEPEND}
  30         selinux? ( sec-policy/selinux-rpcbind )"
  31
  32 src_prepare() {
  33         [[ ${PV} == "9999" ]] && eautoreconf
  34         epatch "${FILESDIR}"/${P}-libtirpc.patch
  35         epatch "${FILESDIR}"/${P}-mem-corrupt.patch #560990
  36         epatch "${FILESDIR}/${P}-avoid-cdefs.h.patch"
  37         epatch "${FILESDIR}/${P}-make-musl-happier.patch"
  38         epatch_user
  39 }
  40
  41 src_configure() {
  42         econf \
  43                 --bindir="${EPREFIX}"/sbin \
  44                 --with-statedir="${EPREFIX}"/run/${PN} \
  45                 --with-rpcuser=root \
  46                 --with-systemdsystemunitdir=$(usex systemd "$(systemd_get_unitdir)" "no") \
  47                 $(use_enable tcpd libwrap) \
  48                 $(use_enable debug) \
  49                 $(use_enable warmstarts)
  50 }
  51
  52 src_install() {
  53         default
  54
  55         newinitd "${FILESDIR}"/${PN}.initd ${PN}
  56         newconfd "${FILESDIR}"/${PN}.confd ${PN}
  57
  58         systemd_dounit "${FILESDIR}"/${PN}.service
  59 }