sys-apps/s6-linux-init/s6-linux-init-0.1.0.0.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6
   7 DESCRIPTION="Generates an init binary for s6-based init systems"
   8 HOMEPAGE="http://www.skarnet.org/software/s6-linux-init/"
   9 SRC_URI="http://www.skarnet.org/software/${PN}/${P}.tar.gz"
  10
  11 LICENSE="ISC"
  12 SLOT="0"
  13 KEYWORDS="~amd64 ~x86 ~arm"
  14 IUSE="static"
  15
  16 DEPEND="
  17         static? ( >=dev-libs/skalibs-2.3.8.0[static-libs] )
  18         !static? ( >=dev-libs/skalibs-2.3.8.0 )
  19         "
  20 RDEPEND="
  21         !static? ( >=dev-libs/skalibs-2.3.8.0 )
  22         "
  23
  24 DOCS=(INSTALL examples/)
  25 HTML_DOCS=(doc/.)
  26
  27 src_prepare()
  28 {
  29         # Remove QA warning about LDFLAGS addition
  30         sed -i "s~tryldflag LDFLAGS_AUTO -Wl,--hash-style=both~:~" "${S}/configure" || die
  31
  32         eapply_user
  33 }
  34
  35 src_configure()
  36 {
  37         econf \
  38                 $(use_enable !static shared) \
  39                 $(use_enable static) \
  40                 $(use_enable static allstatic) \
  41                 --bindir=/bin \
  42                 --sbindir=/sbin \
  43                 --dynlibdir=/$(get_libdir) \
  44                 --libdir=/usr/$(get_libdir)/${PN} \
  45                 --datadir=/etc \
  46                 --sysdepdir=/usr/$(get_libdir)/${PN} \
  47                 --with-dynlib=/$(get_libdir) \
  48                 --with-sysdeps=/usr/$(get_libdir)/skalibs
  49 }
  50
  51 pkg_postinst()
  52 {
  53         einfo "The generated init script requires additional packages."
  54         einfo "Read ${ROOT}usr/share/doc/${PF}/INSTALL for details."
  55 }