media-gfx/fbida/fbida-2.12-r1.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 inherit eutils toolchain-funcs
   7
   8 DESCRIPTION="Image viewers for the framebuffer console (fbi) and X11 (ida)"
   9 HOMEPAGE="http://www.kraxel.org/blog/linux/fbida/"
  10 SRC_URI="
  11         http://www.kraxel.org/releases/${PN}/${P}.tar.gz
  12         mirror://gentoo/ida.png.bz2
  13 "
  14 LICENSE="GPL-2 IJG"
  15 SLOT="0"
  16 KEYWORDS="alpha ~amd64 arm ~hppa ~ppc ~ppc64 ~sh ~sparc ~x86"
  17 IUSE="curl fbcon +gif lirc pdf +png scanner +tiff X +webp"
  18 REQUIRED_USE="
  19         pdf? ( tiff )
  20 "
  21
  22 RDEPEND="
  23         !media-gfx/fbi
  24         >=media-libs/fontconfig-2.2
  25         >=media-libs/freetype-2.0
  26         media-libs/libexif
  27         curl? ( net-misc/curl )
  28         gif? ( media-libs/giflib:= )
  29         lirc? ( app-misc/lirc )
  30         png? ( media-libs/libpng:* )
  31         scanner? ( media-gfx/sane-backends )
  32         tiff? ( media-libs/tiff:* )
  33         virtual/jpeg:*
  34         virtual/ttf-fonts
  35         webp? ( media-libs/libwebp )
  36         X? (
  37                 >=x11-libs/motif-2.3:0
  38                 x11-libs/libX11
  39                 x11-libs/libXpm
  40                 x11-libs/libXt
  41         )
  42 "
  43
  44 DEPEND="
  45         ${RDEPEND}
  46         X? ( x11-proto/xextproto x11-proto/xproto )
  47         pdf? ( app-text/ghostscript-gpl )
  48 "
  49
  50 src_prepare() {
  51         epatch \
  52                 "${FILESDIR}"/ida-desktop.patch \
  53                 "${FILESDIR}"/${PN}-2.10-giflib-4.2.patch \
  54                 "${FILESDIR}"/${PN}-2.10-fprintf-format.patch
  55
  56         tc-export CC CPP
  57
  58         # upstream omission?
  59         echo ${PV} > VERSION
  60 }
  61
  62 src_configure() {
  63         # Let autoconf do its job and then fix things to build fbida
  64         # according to our specifications
  65         emake Make.config
  66
  67         gentoo_fbida() {
  68                 local useflag=${1}
  69                 local config=${2}
  70
  71                 local option="no"
  72                 use ${useflag} && option="yes"
  73
  74                 sed -i \
  75                         -e "s|HAVE_${config}.*|HAVE_${config} := ${option}|" \
  76                         "${S}/Make.config" || die
  77         }
  78
  79         gentoo_fbida X MOTIF
  80         gentoo_fbida curl LIBCURL
  81         gentoo_fbida fbcon LINUX_FB_H
  82         gentoo_fbida gif LIBUNGIF
  83         gentoo_fbida lirc LIBLIRC
  84         gentoo_fbida pdf LIBTIFF
  85         gentoo_fbida png LIBPNG
  86         gentoo_fbida scanner LIBSANE
  87         gentoo_fbida tiff LIBTIFF
  88         gentoo_fbida webp LIBWEBP
  89 }
  90
  91 src_compile() {
  92         emake verbose=yes
  93 }
  94
  95 src_install() {
  96         emake \
  97                 DESTDIR="${D}" \
  98                 STRIP="" \
  99                 prefix=/usr \
 100                 install
 101
 102         dodoc README
 103
 104         if use fbcon && ! use pdf; then
 105                 rm "${D}"/usr/bin/fbpdf \
 106                    "${D}"/usr/bin/fbgs \
 107                    "${D}"/usr/share/man/man1/fbgs.1 || die
 108         fi
 109
 110         if use X ; then
 111                 doicon "${WORKDIR}"/ida.png
 112                 domenu desktop/ida.desktop
 113         fi
 114 }