sys-apps/s6-rc/s6-rc-0.0.3.0.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6
   7 DESCRIPTION="Service manager for the s6 supervision suite"
   8 HOMEPAGE="http://www.skarnet.org/software/s6-rc/"
   9 SRC_URI="http://www.skarnet.org/software/${PN}/${P}.tar.gz"
  10
  11 LICENSE="ISC"
  12 SLOT="0"
  13 KEYWORDS="~amd64 ~x86"
  14 IUSE="static static-libs"
  15
  16 DEPEND="
  17         static? (
  18                 >=dev-lang/execline-2.1.4.5[static-libs]
  19                 >=dev-libs/skalibs-2.3.8.3[static-libs]
  20                 >=sys-apps/s6-2.2.4.2[static-libs]
  21         )
  22         !static? (
  23                 >=dev-lang/execline-2.1.4.5
  24                 >=dev-libs/skalibs-2.3.8.3
  25                 >=sys-apps/s6-2.2.4.2
  26         )
  27         "
  28 RDEPEND="
  29         !static? (
  30                 >=dev-lang/execline-2.1.4.5
  31                 >=dev-libs/skalibs-2.3.8.3
  32                 >=sys-apps/s6-2.2.4.2
  33         )
  34         "
  35
  36 DOCS=("examples/")
  37 HTML_DOCS=("doc/.")
  38
  39 src_prepare()
  40 {
  41         # Remove QA warning about LDFLAGS addition
  42         sed -i "s~tryldflag LDFLAGS_AUTO -Wl,--hash-style=both~:~" "${S}/configure" || die
  43
  44         eapply_user
  45 }
  46
  47 src_configure()
  48 {
  49         econf \
  50                 $(use_enable !static shared) \
  51                 $(use_enable static-libs static) \
  52                 $(use_enable static allstatic) \
  53                 --bindir=/bin \
  54                 --sbindir=/sbin \
  55                 --dynlibdir=/$(get_libdir) \
  56                 --libdir=/usr/$(get_libdir)/${PN} \
  57                 --datadir=/etc \
  58                 --sysdepdir=/usr/$(get_libdir)/${PN} \
  59                 --with-dynlib=/$(get_libdir) \
  60                 --with-sysdeps=/usr/$(get_libdir)/skalibs
  61 }