app-text/enchant/enchant-2.2.8-r99.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 DESCRIPTION="Spellchecker wrapping library"
   7 HOMEPAGE="https://abiword.github.io/enchant/"
   8 SRC_URI="https://github.com/AbiWord/enchant/releases/download/v${PV}/${P}.tar.gz"
   9
  10 LICENSE="LGPL-2.1+"
  11 SLOT="2"
  12 KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ppc ppc64 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
  13
  14 IUSE="aspell +hunspell nuspell"
  15 REQUIRED_USE="|| ( hunspell aspell nuspell )"
  16
  17 # FIXME: depends on unittest++ but through pkgconfig which is a Debian hack, bug #629742
  18 RDEPEND="
  19         >=dev-libs/glib-2.6:2
  20         aspell? ( app-text/aspell )
  21         nuspell? ( app-text/nuspell )
  22         hunspell? ( >=app-text/hunspell-1.2.1:0= )"
  23 DEPEND="${RDEPEND}"
  24 BDEPEND="virtual/pkgconfig"
  25
  26 #       test? ( dev-libs/unittest++ )
  27 RESTRICT="test"
  28
  29 src_configure() {
  30         econf \
  31                 --datadir="${EPREFIX}"/usr/share/enchant-2 \
  32                 --disable-static \
  33                 $(use_with aspell) \
  34                 $(use_with hunspell) \
  35                 $(use_with nuspell) \
  36                 --without-hspell \
  37                 --without-voikko \
  38                 --without-applespell \
  39                 --without-zemberek \
  40                 --with-hunspell-dir="${EPREFIX}"/usr/share/hunspell/
  41 }
  42
  43 src_install() {
  44         default
  45         find "${D}" -name '*.la' -delete || die
  46 }