x11-terms/st-wl/st-wl-9999.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 inherit eutils git-r3 multilib savedconfig toolchain-funcs
   7
   8 DESCRIPTION="simple terminal implementation for Wayland"
   9 HOMEPAGE="http://st.suckless.org/"
  10 EGIT_REPO_URI="https://github.com/michaelforney/st.git"
  11 EGIT_BRANCH="wayland"
  12
  13 LICENSE="MIT-with-advertising"
  14 SLOT="0"
  15 IUSE="savedconfig"
  16
  17 RDEPEND="
  18         !<sys-libs/ncurses-6.0
  19         media-libs/fontconfig
  20         dev-libs/wayland
  21         dev-libs/wld[wayland]
  22         x11-libs/libxkbcommon
  23 "
  24 DEPEND="
  25         ${RDEPEND}
  26         virtual/pkgconfig
  27         x11-proto/xextproto
  28         x11-proto/xproto
  29 "
  30
  31 src_prepare() {
  32         epatch "${FILESDIR}/rename-with-wl-suffix.patch"
  33         epatch_user
  34
  35         sed -e '/^CFLAGS/s:[[:space:]]-Wall[[:space:]]: :' \
  36                 -e '/^CFLAGS/s:[[:space:]]-O[^[:space:]]*[[:space:]]: :' \
  37                 -e '/^LDFLAGS/{s:[[:space:]]-s[[:space:]]: :}' \
  38                 -e '/^X11INC/{s:/usr/X11R6/include:/usr/include/X11:}' \
  39                 -e "/^X11LIB/{s:/usr/X11R6/lib:/usr/$(get_libdir)/X11:}" \
  40                 -i config.mk || die
  41         sed -e '/@echo/!s:@::' \
  42                 -e '/tic/d' \
  43                 -i Makefile || die
  44         tc-export CC
  45
  46         restore_config config.h
  47 }
  48
  49 src_install() {
  50         emake DESTDIR="${D}" PREFIX="${EPREFIX}"/usr install
  51         dodoc TODO
  52
  53         save_config config.h
  54 }
  55
  56 pkg_postinst() {
  57         if ! [[ "${REPLACING_VERSIONS}" ]]; then
  58                 elog "Please ensure a usable font is installed, like"
  59                 elog "    media-fonts/corefonts"
  60                 elog "    media-fonts/dejavu"
  61                 elog "    media-fonts/urw-fonts"
  62         fi
  63 }