contrib/sigrok-cli_cross.nsi.in

   1 ##
   2 ## This file is part of the sigrok-cli project.
   3 ##
   4 ## Copyright (C) 2011-2014 Uwe Hermann <uwe@hermann-uwe.de>
   5 ##
   6 ## This program is free software; you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation; either version 2 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program; if not, write to the Free Software
  18 ## Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301 USA
  19 ##
  20
  21 #
  22 # This file is used to create the sigrok-cli Windows installer via NSIS.
  23 # It is meant for use in a cross-compile setup (not for native builds).
  24 # See the 'sigrok-cross-mingw' script in the sigrok-util repo for details.
  25 #
  26 # NSIS documentation:
  27 # http://nsis.sourceforge.net/Docs/
  28 # http://nsis.sourceforge.net/Docs/Modern%20UI%202/Readme.html
  29 #
  30
  31 # Include the "Modern UI" header, which gives us the usual Windows look-n-feel.
  32 !include "MUI2.nsh"
  33
  34
  35 # --- Global stuff ------------------------------------------------------------
  36
  37 # Installer/product name.
  38 Name "@PACKAGE_NAME@"
  39
  40 # Filename of the installer executable.
  41 OutFile "@PACKAGE_NAME@-@PACKAGE_VERSION@-installer.exe"
  42
  43 # Where to install the application.
  44 InstallDir "$PROGRAMFILES\sigrok\@PACKAGE_NAME@"
  45
  46 # Request admin privileges for Windows Vista and Windows 7.
  47 # http://nsis.sourceforge.net/Docs/Chapter4.html
  48 RequestExecutionLevel admin
  49
  50 # Local helper definitions.
  51 !define REGSTR "Software\Microsoft\Windows\CurrentVersion\Uninstall\@PACKAGE_NAME@"
  52
  53
  54 # --- MUI interface configuration ---------------------------------------------
  55
  56 # Use the following icon for the installer EXE file.
  57 !define MUI_ICON "sigrok-logo-notext.ico"
  58
  59 # Show a nice image at the top of each installer page.
  60 !define MUI_HEADERIMAGE
  61
  62 # Don't automatically go to the Finish page so the user can check the log.
  63 !define MUI_FINISHPAGE_NOAUTOCLOSE
  64
  65 # Upon "cancel", ask the user if he really wants to abort the installer.
  66 !define MUI_ABORTWARNING
  67
  68 # Don't force the user to accept the license, just show it.
  69 # Details: http://trac.videolan.org/vlc/ticket/3124
  70 !define MUI_LICENSEPAGE_BUTTON $(^NextBtn)
  71 !define MUI_LICENSEPAGE_TEXT_BOTTOM "Click Next to continue."
  72
  73 # Path where the cross-compiled sigrok tools and libraries are located.
  74 # Change this to where-ever you installed libsigrok.a and so on.
  75 !define CROSS "$%HOME%/sr_mingw"
  76
  77 # Path where the cross-compiled MXE tools and libraries are located.
  78 # Change this to where-ever you installed MXE (and the files it built).
  79 !define MXE "$%HOME%/mxe-git/usr/i686-pc-mingw32"
  80
  81
  82 # --- MUI pages ---------------------------------------------------------------
  83
  84 # Show a nice "Welcome to the ... Setup Wizard" page.
  85 !insertmacro MUI_PAGE_WELCOME
  86
  87 # Show the license of the project.
  88 !insertmacro MUI_PAGE_LICENSE "../COPYING"
  89
  90 # Show a screen which allows the user to select which components to install.
  91 !insertmacro MUI_PAGE_COMPONENTS
  92
  93 # Allow the user to select a different install directory.
  94 !insertmacro MUI_PAGE_DIRECTORY
  95
  96 # Perform the actual installation, i.e. install the files.
  97 !insertmacro MUI_PAGE_INSTFILES
  98
  99 # Show a final "We're done, click Finish to close this wizard" message.
 100 !insertmacro MUI_PAGE_FINISH
 101
 102 # Pages used for the uninstaller.
 103 !insertmacro MUI_UNPAGE_WELCOME
 104 !insertmacro MUI_UNPAGE_CONFIRM
 105 !insertmacro MUI_UNPAGE_INSTFILES
 106 !insertmacro MUI_UNPAGE_FINISH
 107
 108
 109 # --- MUI language files ------------------------------------------------------
 110
 111 # Select an installer language (required!).
 112 !insertmacro MUI_LANGUAGE "English"
 113
 114
 115 # --- Default section ---------------------------------------------------------
 116
 117 Section "@PACKAGE_NAME@ (required)" Section1
 118
 119         # This section is gray (can't be disabled) in the component list.
 120         SectionIn RO
 121
 122         # Install the file(s) specified below into the specified directory.
 123         SetOutPath "$INSTDIR"
 124
 125         # License file.
 126         File "../COPYING"
 127
 128         # sigrok-cli.exe.
 129         File "${CROSS}/bin/@PACKAGE_NAME@.exe"
 130
 131         # libusb0.dll (needed for libusb-0.1).
 132         File "${CROSS}/libusb0.dll"
 133
 134         # Zadig (used for installing libusb-win32 and WinUSB drivers).
 135         File "${CROSS}/zadig.exe"
 136         File "${CROSS}/zadig_xp.exe"
 137
 138         # Python
 139         File "${CROSS}/python32.dll"
 140         File "${CROSS}/python32.zip"
 141
 142         # Protocol decoders.
 143         SetOutPath "$INSTDIR\decoders"
 144         File /r /x "__pycache__" "${CROSS}/share/libsigrokdecode/decoders/*"
 145
 146         # Firmware files.
 147         SetOutPath "$INSTDIR\firmware"
 148         File /r "${CROSS}/share/sigrok-firmware/*"
 149
 150         # Example *.sr files.
 151         SetOutPath "$INSTDIR\examples"
 152         File /r "${CROSS}/share/sigrok-dumps/*"
 153
 154         # Generate the uninstaller executable.
 155         WriteUninstaller "$INSTDIR\Uninstall.exe"
 156
 157         # Create a sub-directory in the start menu.
 158         CreateDirectory "$SMPROGRAMS\sigrok"
 159         CreateDirectory "$SMPROGRAMS\sigrok\@PACKAGE_NAME@"
 160
 161         # Create a shortcut for sigrok-cli (this merely opens a "DOS box").
 162         # Set the working directory (where the user will be placed into when
 163         # the DOS box starts) to the installation directory.
 164         SetOutPath "$INSTDIR"
 165         CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\sigrok command-line tool.lnk" \
 166                 "$SYSDIR\cmd.exe" \
 167                 "/K echo For instructions run @PACKAGE_NAME@ --help." \
 168                 "$SYSDIR\cmd.exe" 0 \
 169                 SW_SHOWNORMAL "" "Run @PACKAGE_NAME@"
 170
 171         # Create a shortcut for the uninstaller.
 172         CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Uninstall.lnk" \
 173                 "$INSTDIR\Uninstall.exe" "" "$INSTDIR\Uninstall.exe" 0 \
 174                 SW_SHOWNORMAL "" "Uninstall @PACKAGE_NAME@"
 175
 176         # Create registry keys for "Add/remove programs" in the control panel.
 177         WriteRegStr HKLM "${REGSTR}" "DisplayName" "@PACKAGE_STRING@"
 178         WriteRegStr HKLM "${REGSTR}" "UninstallString" \
 179                 "$\"$INSTDIR\Uninstall.exe$\""
 180         WriteRegStr HKLM "${REGSTR}" "InstallLocation" "$\"$INSTDIR$\""
 181         WriteRegStr HKLM "${REGSTR}" "DisplayIcon" \
 182                 "$\"$INSTDIR\sigrok-logo-notext.ico$\""
 183         WriteRegStr HKLM "${REGSTR}" "Publisher" "sigrok"
 184         WriteRegStr HKLM "${REGSTR}" "HelpLink" \
 185                 "http://sigrok.org/wiki/Sigrok-cli"
 186         WriteRegStr HKLM "${REGSTR}" "URLUpdateInfo" \
 187                 "http://sigrok.org/wiki/Downloads"
 188         WriteRegStr HKLM "${REGSTR}" "URLInfoAbout" "http://sigrok.org"
 189         WriteRegStr HKLM "${REGSTR}" "DisplayVersion" "@PACKAGE_VERSION@"
 190         WriteRegStr HKLM "${REGSTR}" "Contact" \
 191                 "sigrok-devel@lists.sourceforge.org"
 192         WriteRegStr HKLM "${REGSTR}" "Comments" \
 193                 "This is the sigrok command-line application."
 194
 195         # Display "Remove" instead of "Modify/Remove" in the control panel.
 196         WriteRegDWORD HKLM "${REGSTR}" "NoModify" 1
 197         WriteRegDWORD HKLM "${REGSTR}" "NoRepair" 1
 198
 199         # TODO: Add sigrok-cli directory to the PATH env. variable.
 200
 201 SectionEnd
 202
 203
 204 # --- Uninstaller section -----------------------------------------------------
 205
 206 Section "Uninstall"
 207
 208         # Always delete the uninstaller first (yes, this really works).
 209         Delete "$INSTDIR\Uninstall.exe"
 210
 211         # Delete the application, the application data, and related libs.
 212         Delete "$INSTDIR\COPYING"
 213         Delete "$INSTDIR\@PACKAGE_NAME@.exe"
 214         Delete "$INSTDIR\libusb0.dll"
 215         Delete "$INSTDIR\zadig.exe"
 216         Delete "$INSTDIR\zadig_xp.exe"
 217         Delete "$INSTDIR\python32.dll"
 218         Delete "$INSTDIR\python32.zip"
 219
 220         # Delete all decoders and everything else in decoders/.
 221         # There could be *.pyc files or __pycache__ subdirs and so on.
 222         RMDir /r "$INSTDIR\decoders\*"
 223
 224         # Delete the firmware files.
 225         RMDir /r "$INSTDIR\firmware\*"
 226
 227         # Delete the example *.sr files.
 228         RMDir /r "$INSTDIR\examples\*"
 229
 230         # Delete the install directory and its sub-directories.
 231         RMDir "$INSTDIR\decoders"
 232         RMDir "$INSTDIR\firmware"
 233         RMDir "$INSTDIR\examples"
 234         RMDir "$INSTDIR"
 235
 236         # Delete the links from the start menu.
 237         Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\sigrok command-line tool.lnk"
 238         Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Uninstall.lnk"
 239
 240         # Delete the sub-directory in the start menu.
 241         RMDir "$SMPROGRAMS\sigrok\@PACKAGE_NAME@"
 242         RMDir "$SMPROGRAMS\sigrok"
 243
 244         # Delete the registry key(s).
 245         DeleteRegKey HKLM "${REGSTR}"
 246
 247 SectionEnd
 248
 249
 250 # --- Component selection section descriptions --------------------------------
 251
 252 LangString DESC_Section1 ${LANG_ENGLISH} "This installs the sigrok command-line tool, some firmware files, the protocol decoders, some example files, and all required libraries."
 253
 254 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 255 !insertmacro MUI_DESCRIPTION_TEXT ${Section1} $(DESC_Section1)
 256 !insertmacro MUI_FUNCTION_DESCRIPTION_END
 257