contrib/sigrok-cli_cross.nsi.in

   1 ##
   2 ## This file is part of the sigrok-cli project.
   3 ##
   4 ## Copyright (C) 2011-2020 Uwe Hermann <uwe@hermann-uwe.de>
   5 ##
   6 ## This program is free software; you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation; either version 2 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program; if not, see <http://www.gnu.org/licenses/>.
  18 ##
  19
  20 #
  21 # This file is used to create the sigrok-cli Windows installer via NSIS.
  22 # It is meant for use in a cross-compile setup (not for native builds).
  23 # See the 'sigrok-cross-mingw' script in the sigrok-util repo for details.
  24 #
  25 # NSIS documentation:
  26 # http://nsis.sourceforge.net/Docs/
  27 # http://nsis.sourceforge.net/Docs/Modern%20UI%202/Readme.html
  28 #
  29
  30 # Include the "Modern UI" header, which gives us the usual Windows look-n-feel.
  31 !include "MUI2.nsh"
  32
  33
  34 # --- Global stuff ------------------------------------------------------------
  35
  36 # Installer/product name.
  37 Name "@PACKAGE_NAME@"
  38
  39 # Filename of the installer executable.
  40 OutFile "@PACKAGE_NAME@-@SC_PACKAGE_VERSION@-installer.exe"
  41
  42 # Where to install the application.
  43 InstallDir "$PROGRAMFILES\sigrok\@PACKAGE_NAME@"
  44
  45 # Request admin privileges for Windows Vista and Windows 7.
  46 # http://nsis.sourceforge.net/Docs/Chapter4.html
  47 RequestExecutionLevel admin
  48
  49 # Local helper definitions.
  50 !define REGSTR "Software\Microsoft\Windows\CurrentVersion\Uninstall\@PACKAGE_NAME@"
  51
  52
  53 # --- MUI interface configuration ---------------------------------------------
  54
  55 # Use the following icon for the installer EXE file.
  56 !define MUI_ICON "@top_srcdir@/contrib/sigrok-logo-notext.ico"
  57
  58 # Show a nice image at the top of each installer page.
  59 !define MUI_HEADERIMAGE
  60
  61 # Don't automatically go to the Finish page so the user can check the log.
  62 !define MUI_FINISHPAGE_NOAUTOCLOSE
  63
  64 # Upon "cancel", ask the user if he really wants to abort the installer.
  65 !define MUI_ABORTWARNING
  66
  67 # Don't force the user to accept the license, just show it.
  68 # Details: http://trac.videolan.org/vlc/ticket/3124
  69 !define MUI_LICENSEPAGE_BUTTON $(^NextBtn)
  70 !define MUI_LICENSEPAGE_TEXT_BOTTOM "Click Next to continue."
  71
  72 # Path where the cross-compiled sigrok tools and libraries are located.
  73 # Change this to where-ever you installed libsigrok.a and so on.
  74 !define CROSS "@prefix@"
  75
  76
  77 # --- MUI pages ---------------------------------------------------------------
  78
  79 # Show a nice "Welcome to the ... Setup Wizard" page.
  80 !insertmacro MUI_PAGE_WELCOME
  81
  82 # Show the license of the project.
  83 !insertmacro MUI_PAGE_LICENSE "@top_srcdir@/COPYING"
  84
  85 # Show a screen which allows the user to select which components to install.
  86 !insertmacro MUI_PAGE_COMPONENTS
  87
  88 # Allow the user to select a different install directory.
  89 !insertmacro MUI_PAGE_DIRECTORY
  90
  91 # Perform the actual installation, i.e. install the files.
  92 !insertmacro MUI_PAGE_INSTFILES
  93
  94 # Show a final "We're done, click Finish to close this wizard" message.
  95 !insertmacro MUI_PAGE_FINISH
  96
  97 # Pages used for the uninstaller.
  98 !insertmacro MUI_UNPAGE_WELCOME
  99 !insertmacro MUI_UNPAGE_CONFIRM
 100 !insertmacro MUI_UNPAGE_INSTFILES
 101 !insertmacro MUI_UNPAGE_FINISH
 102
 103
 104 # --- MUI language files ------------------------------------------------------
 105
 106 # Select an installer language (required!).
 107 !insertmacro MUI_LANGUAGE "English"
 108
 109
 110 # --- Default section ---------------------------------------------------------
 111
 112 Section "@PACKAGE_NAME@ (required)" Section1
 113         # This section is gray (can't be disabled) in the component list.
 114         SectionIn RO
 115
 116         # Install the file(s) specified below into the specified directory.
 117         SetOutPath "$INSTDIR"
 118
 119         # License file.
 120         File "@top_srcdir@/COPYING"
 121
 122         # sigrok-cli.exe.
 123         File "${CROSS}/bin/@PACKAGE_NAME@.exe"
 124
 125         # Zadig (used for installing WinUSB drivers).
 126         File "${CROSS}/zadig.exe"
 127         File "${CROSS}/zadig_xp.exe"
 128
 129         # Python
 130         File "${CROSS}/python34.dll"
 131         File "${CROSS}/python34.zip"
 132         File "${CROSS}/*.pyd"
 133
 134         SetOutPath "$INSTDIR\share"
 135
 136         # Protocol decoders.
 137         File /r /x "__pycache__" /x "*.pyc" "${CROSS}/share/libsigrokdecode"
 138
 139         # Firmware files.
 140         File /r "${CROSS}/share/sigrok-firmware"
 141
 142         # Generate the uninstaller executable.
 143         WriteUninstaller "$INSTDIR\Uninstall.exe"
 144
 145         # Create a sub-directory in the start menu.
 146         CreateDirectory "$SMPROGRAMS\sigrok"
 147         CreateDirectory "$SMPROGRAMS\sigrok\@PACKAGE_NAME@"
 148
 149         # Create a shortcut for sigrok-cli (this merely opens a "DOS box").
 150         # Set the working directory (where the user will be placed into when
 151         # the DOS box starts) to the installation directory.
 152         SetOutPath "$INSTDIR"
 153         CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\sigrok command-line tool.lnk" \
 154                 "$SYSDIR\cmd.exe" \
 155                 "/K echo For instructions run @PACKAGE_NAME@ --help." \
 156                 "$SYSDIR\cmd.exe" 0 \
 157                 SW_SHOWNORMAL "" "Run @PACKAGE_NAME@"
 158
 159         # Create a shortcut for the uninstaller.
 160         CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Uninstall @PACKAGE_NAME@.lnk" \
 161                 "$INSTDIR\Uninstall.exe" "" "$INSTDIR\Uninstall.exe" 0 \
 162                 SW_SHOWNORMAL "" "Uninstall @PACKAGE_NAME@"
 163
 164         # Create a shortcut for the Zadig executable.
 165         CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Zadig (@PACKAGE_NAME@).lnk" \
 166                 "$INSTDIR\zadig.exe" "" "$INSTDIR\zadig.exe" 0 \
 167                 SW_SHOWNORMAL "" "Zadig"
 168
 169         # Create a shortcut for the Zadig executable (for Win XP).
 170         CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Zadig (@PACKAGE_NAME@, Win XP).lnk" \
 171                 "$INSTDIR\zadig_xp.exe" "" "$INSTDIR\zadig_xp.exe" 0 \
 172                 SW_SHOWNORMAL "" "Zadig (Win XP)"
 173
 174         # Create registry keys for "Add/remove programs" in the control panel.
 175         WriteRegStr HKLM "${REGSTR}" "DisplayName" "@PACKAGE_STRING@"
 176         WriteRegStr HKLM "${REGSTR}" "UninstallString" \
 177                 "$\"$INSTDIR\Uninstall.exe$\""
 178         WriteRegStr HKLM "${REGSTR}" "InstallLocation" "$\"$INSTDIR$\""
 179         WriteRegStr HKLM "${REGSTR}" "DisplayIcon" \
 180                 "$\"$INSTDIR\sigrok-logo-notext.ico$\""
 181         WriteRegStr HKLM "${REGSTR}" "Publisher" "sigrok"
 182         WriteRegStr HKLM "${REGSTR}" "HelpLink" \
 183                 "http://sigrok.org/wiki/Sigrok-cli"
 184         WriteRegStr HKLM "${REGSTR}" "URLUpdateInfo" \
 185                 "http://sigrok.org/wiki/Downloads"
 186         WriteRegStr HKLM "${REGSTR}" "URLInfoAbout" "http://sigrok.org"
 187         WriteRegStr HKLM "${REGSTR}" "DisplayVersion" "@SC_PACKAGE_VERSION@"
 188         WriteRegStr HKLM "${REGSTR}" "Contact" \
 189                 "sigrok-devel@lists.sourceforge.org"
 190         WriteRegStr HKLM "${REGSTR}" "Comments" \
 191                 "This is the sigrok command-line application."
 192
 193         # Display "Remove" instead of "Modify/Remove" in the control panel.
 194         WriteRegDWORD HKLM "${REGSTR}" "NoModify" 1
 195         WriteRegDWORD HKLM "${REGSTR}" "NoRepair" 1
 196
 197         # TODO: Add sigrok-cli directory to the PATH env. variable.
 198 SectionEnd
 199
 200 Section /o "Example data" Section2
 201         # Example *.sr files.
 202         SetOutPath "$INSTDIR\examples"
 203
 204         File "${CROSS}/share/sigrok-dumps/arm_trace/stm32f105/trace_example.sr"
 205         File "${CROSS}/share/sigrok-dumps/am230x/am2301/am2301_1mhz.sr"
 206         File "${CROSS}/share/sigrok-dumps/avr_isp/atmega88/isp_atmega88_erase_chip.sr"
 207         File "${CROSS}/share/sigrok-dumps/can/microchip_mcp2515dm-bm/mcp2515dm-bm-125kbits_msg_222_5bytes.sr"
 208         File "${CROSS}/share/sigrok-dumps/dcf77/pollin_dcf1_module/dcf77_120s.sr"
 209         File "${CROSS}/share/sigrok-dumps/i2c/eeprom_24xx/microchip_24lc02b/hantek_6022be_powerup.sr"
 210         File "${CROSS}/share/sigrok-dumps/i2c/eeprom_24xx/microchip_24lc64/sainsmart_dds120_powerup_scl_sda_analog.sr"
 211         File "${CROSS}/share/sigrok-dumps/i2c/potentiometer/analog_devices_ad5258/ad5258_read_once_write_continuously_triangle.sr"
 212         File "${CROSS}/share/sigrok-dumps/mdio/lan8720a/lan8720a_read_write_read.sr"
 213         File "${CROSS}/share/sigrok-dumps/onewire/owfs/ds28ea00.sr"
 214         File "${CROSS}/share/sigrok-dumps/sdcard/sd_mode/rcar-h2/cmd23_cmd18.sr"
 215         File "${CROSS}/share/sigrok-dumps/spi/mx25l1605d/mx25l1605d_read.sr"
 216         File "${CROSS}/share/sigrok-dumps/uart/gps/mtk3339/mtk3339_8n1_9600.sr"
 217         File "${CROSS}/share/sigrok-dumps/usb/hid/mouse/olimex_stm32-h103_usb_hid/olimex_stm32-h103_usb_hid.sr"
 218         File "${CROSS}/share/sigrok-dumps/z80/kc85/kc85-20mhz.sr"
 219
 220         # Create a shortcut for the example data folder.
 221         CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Examples (@PACKAGE_NAME@).lnk" \
 222                 "$INSTDIR\examples" "" "$INSTDIR\examples" 0 \
 223                 SW_SHOWNORMAL "" ""
 224 SectionEnd
 225
 226
 227 # --- Uninstaller section -----------------------------------------------------
 228
 229 Section "Uninstall"
 230         # Always delete the uninstaller first (yes, this really works).
 231         Delete "$INSTDIR\Uninstall.exe"
 232
 233         # Delete the application, the application data, and related libs.
 234         Delete "$INSTDIR\COPYING"
 235         Delete "$INSTDIR\@PACKAGE_NAME@.exe"
 236         Delete "$INSTDIR\zadig.exe"
 237         Delete "$INSTDIR\zadig_xp.exe"
 238         Delete "$INSTDIR\python34.dll"
 239         Delete "$INSTDIR\python34.zip"
 240         Delete "$INSTDIR\*.pyd"
 241
 242         # Delete all decoders and everything else in libsigrokdecode/.
 243         # There could be *.pyc files or __pycache__ subdirs and so on.
 244         RMDir /r "$INSTDIR\share\libsigrokdecode"
 245
 246         # Delete the firmware files.
 247         RMDir /r "$INSTDIR\share\sigrok-firmware"
 248
 249         # Delete the example *.sr files.
 250         RMDir /r "$INSTDIR\examples\*"
 251
 252         # Delete the install directory and its sub-directories.
 253         RMDir "$INSTDIR\share"
 254         RMDir "$INSTDIR\examples"
 255         RMDir "$INSTDIR"
 256
 257         # Delete the links from the start menu.
 258         Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\sigrok command-line tool.lnk"
 259         Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Uninstall @PACKAGE_NAME@.lnk"
 260         Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Zadig (@PACKAGE_NAME@).lnk"
 261         Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Zadig (@PACKAGE_NAME@, Win XP).lnk"
 262         Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Examples (@PACKAGE_NAME@).lnk"
 263
 264         # Delete the sub-directory in the start menu.
 265         RMDir "$SMPROGRAMS\sigrok\@PACKAGE_NAME@"
 266         RMDir "$SMPROGRAMS\sigrok"
 267
 268         # Delete the registry key(s).
 269         DeleteRegKey HKLM "${REGSTR}"
 270 SectionEnd
 271
 272
 273 # --- Component selection section descriptions --------------------------------
 274
 275 LangString DESC_Section1 ${LANG_ENGLISH} "This installs the sigrok command-line tool, some firmware files, the protocol decoders, and all required libraries."
 276 LangString DESC_Section2 ${LANG_ENGLISH} "This installs some example files that you can use to try out the features sigrok has to offer."
 277
 278 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 279         !insertmacro MUI_DESCRIPTION_TEXT ${Section1} $(DESC_Section1)
 280         !insertmacro MUI_DESCRIPTION_TEXT ${Section2} $(DESC_Section2)
 281 !insertmacro MUI_FUNCTION_DESCRIPTION_END
 282