cfg.scm

   1 ;;; generation of control flow graph
   2
   3 ;; special variables whose contents are located in the FSR registers
   4 (define fsr-variables '(SIXPIC_FSR0 SIXPIC_FSR1 SIXPIC_FSR2))
   5
   6 (define-type cfg
   7   bbs
   8   next-label-num)
   9
  10 (define (new-cfg)
  11   (make-cfg '() 0))
  12
  13 (define-type bb
  14   label-num
  15   label-name ; if the block had a label
  16   label
  17   rev-instrs
  18   unprintable:
  19   preds
  20   succs
  21   live-before) ; stored as a set
  22
  23 (define (bb-name bb)
  24   (asm-label-id (bb-label bb)))
  25
  26 (define-type instr
  27   extender: define-type-of-instr
  28   (live-before unprintable:) ; these 2 are stored as sets
  29   (live-after unprintable:)
  30   (hash unprintable:)
  31   id
  32   src1
  33   src2
  34   dst)
  35
  36 (define-type-of-instr call-instr
  37   unprintable:
  38   def-proc)
  39
  40 (define-type-of-instr return-instr
  41   unprintable:
  42   def-proc)
  43
  44 (define (new-instr id src1 src2 dst)
  45   (make-instr (new-empty-set) (new-empty-set) #f id src1 src2 dst))
  46
  47 ;; list of all conditional branching generic instructions
  48 (define conditional-instrs ;; TODO add as we add specialized instructions
  49   '(x==y x!=y x<y x>y x<=y x>=y))
  50
  51 (define (new-call-instr def-proc)
  52   (make-call-instr '() '() #f 'call #f #f #f def-proc))
  53
  54 (define (new-return-instr def-proc)
  55   (make-return-instr '() '() #f 'return #f #f #f def-proc))
  56
  57 (define (add-bb cfg proc id) ;; TODO maybe have the name in the label for named-bbs ? would help debugging
  58   (let* ((label-num (cfg-next-label-num cfg))
  59          (bb (make-bb label-num #f #f '() '() '() (new-empty-set))))
  60     (bb-label-set!
  61      bb
  62      (asm-make-label
  63       (string->symbol
  64        (string-append "$"
  65                       (number->string label-num)
  66                       "$"
  67                       (if proc (symbol->string proc) "")
  68                       "$"
  69                       (if proc (number->string id) "")))))
  70     (cfg-bbs-set! cfg (cons bb (cfg-bbs cfg)))
  71     (cfg-next-label-num-set! cfg (+ 1 (cfg-next-label-num cfg)))
  72     bb))
  73
  74 (define (add-instr bb instr)
  75   (let ((rev-instrs (bb-rev-instrs bb)))
  76     (bb-rev-instrs-set! bb (cons instr rev-instrs))))
  77
  78 (define (add-succ bb succ)
  79   (bb-succs-set! bb (cons succ (bb-succs bb)))
  80   (bb-preds-set! succ (cons bb (bb-preds succ))))
  81
  82 (define (generate-cfg ast)
  83
  84   (define cfg (new-cfg))
  85
  86   (define bb #f) ; current bb
  87
  88   (define (in x) (set! bb x))
  89
  90   (define (new-bb)
  91     (let ((bb (add-bb cfg
  92                       (if current-def-proc (def-id current-def-proc) #f)
  93                       current-def-proc-bb-id)))
  94       (set! current-def-proc-bb-id (+ current-def-proc-bb-id 1))
  95       bb))
  96
  97   (define (emit instr) (add-instr bb instr))
  98
  99   (define current-def-proc #f)
 100   (define (current-def-proc-id)
 101     (if current-def-proc
 102         (def-id current-def-proc)
 103         #f))
 104   (define current-def-proc-bb-id 0)
 105   (define break-stack '())
 106   (define continue-stack '())
 107   (define delayed-post-incdec '())
 108
 109   (define (push-break x) (set! break-stack (cons x break-stack)))
 110   (define (pop-break)    (set! break-stack (cdr break-stack)))
 111
 112   (define (push-continue x) (set! continue-stack (cons x continue-stack)))
 113   (define (pop-continue)    (set! continue-stack (cdr continue-stack)))
 114
 115   (define (push-delayed-post-incdec ast)
 116     (set! delayed-post-incdec (cons ast delayed-post-incdec))
 117     ;; moves the original value to a new location (so it won't be modified)
 118     ;; and returns that location to the original expression
 119     (let ((x (subast1 ast)))
 120       (if (not (ref? x))
 121           (error "assignment target must be a variable")
 122           (let* ((def-var (ref-def-var x))
 123                  (result  (alloc-value (def-variable-type def-var) #f (bb-name bb))))
 124             (move-value (def-variable-value def-var) result)
 125             result))))
 126
 127   ;; TODO instead of carrying types around, use the length instead, or even better, just pass the value-bytes, and calculate the length as needed
 128   (define (extend value type)
 129     ;; literals must be extended with literal 0s, while variables must be
 130     ;; extended with byte cells
 131     (let* ((bytes (value-bytes value))
 132            (lit?  (byte-lit? (car bytes))))
 133       (let loop ((rev-bytes (reverse bytes))
 134                  (n         (max 0 (- (type->bytes type) (length bytes)))))
 135         (if (= n 0)
 136             (new-value (reverse rev-bytes))
 137             (loop (cons (new-byte-lit 0) ;; TODO used to extend with empty byte cells when it expanded a variable. caused weird bugs.
 138                         rev-bytes)
 139                   (- n 1))))))
 140
 141   (define (program ast)
 142     (let loop ((asts (ast-subasts ast)))
 143       (if (not (null? asts))
 144           (let ((ast (car asts)))
 145             (if (null? (cdr asts))
 146                 (let ((value (expression ast)))
 147                   (return-with-no-new-bb value))
 148                 (begin
 149                   (toplevel ast)
 150                   (loop (cdr asts))))))))
 151
 152   (define (toplevel ast)
 153     (cond ((def-variable? ast)
 154            (def-variable ast))
 155           ((def-procedure? ast)
 156            (def-procedure ast))
 157           (else
 158            (statement ast))))
 159
 160   (define (def-variable ast) ;; FOO set the fun for each byte-cell
 161     (let ((subasts (ast-subasts ast)))
 162       (if (not (null? subasts)) ; if needed, set the variable
 163           (let ((value (expression (subast1 ast))))
 164             (let ((ext-value (extend value (def-variable-type ast))))
 165               (move-value value (def-variable-value ast)))))))
 166
 167   ;; resolve the C gotos by setting the appropriate successor to their bb
 168   (define (resolve-all-gotos start table)
 169     (let loop ((start start)
 170                (visited (new-empty-set)))
 171       (if (not (set-member? visited start)) ; not visited
 172           (begin (for-each
 173                   (lambda (x)
 174                     (if (and (eq? (instr-id x) 'goto)
 175                              (instr-dst x)) ; unresolved label
 176                         (let ((target (assoc (instr-dst x) table))) ;; TODO use a set, but not urgent, not a bottleneck
 177                           (if target
 178                               (begin (add-succ start (cdr target))
 179                                      (instr-dst-set! x #f))
 180                               (error "invalid goto target" (instr-dst x))))))
 181                   (bb-rev-instrs start))
 182                  (for-each (lambda (x)
 183                              (set-add! visited start)
 184                              (loop x visited))
 185                            (bb-succs start))))))
 186
 187   (define (def-procedure ast) ;; FOO set the fun for the parameters, and maybe also return value
 188     (set! current-def-proc-bb-id 0)
 189     (set! current-def-proc ast)
 190     (let ((old-bb bb)
 191           (entry (new-bb)))
 192       (def-procedure-entry-set! ast entry)
 193       (in entry)
 194       (for-each statement (ast-subasts ast))
 195       (return-with-no-new-bb ast)
 196       (set! current-def-proc #f)
 197       (resolve-all-gotos entry (list-named-bbs entry))
 198       (in old-bb)))
 199
 200   ;; returns a list of all named bbs in the successor-tree of a given bb
 201   (define (list-named-bbs start)
 202     (let ((visited (new-empty-set)))
 203       (let loop ((start start) ;; TODO not really a loop, it's tree recursion
 204                  (named '()))
 205         (if (set-member? visited start)
 206             named
 207             (let ((succs
 208                    (apply append
 209                           (map (lambda (bb)
 210                                  (set-add! visited start)
 211                                  (loop bb named))
 212                                (bb-succs start)))))
 213               (if (bb-label-name start)
 214                   (cons (cons (bb-label-name start) start) succs)
 215                   succs))))))
 216
 217   (define (statement ast)
 218     (cond ((def-variable? ast) (def-variable ast))
 219           ((block? ast)        (block ast))
 220           ((return? ast)       (return ast))
 221           ((if? ast)           (if (null? (cddr (ast-subasts ast)))
 222                                    (if1 ast)
 223                                    (if2 ast)))
 224           ((while? ast)        (while ast))
 225           ((do-while? ast)     (do-while ast))
 226           ((for? ast)          (for ast))
 227           ((switch? ast)       (switch ast))
 228           ((break? ast)        (break ast))
 229           ((continue? ast)     (continue ast))
 230           ((goto? ast)         (goto ast))
 231           (else                (expression ast))))
 232
 233   (define (block ast)
 234     (if (block-name ast) ; named block ?
 235         (begin (let ((new (new-bb)))
 236                  (gen-goto new)
 237                  (in new))
 238                (bb-label-name-set! bb (block-name ast))))
 239     (for-each statement (ast-subasts ast)))
 240
 241   (define (move from to)
 242     (emit (new-instr 'move from #f to)))
 243
 244   (define (move-value from to)
 245     (let loop ((from (value-bytes from))
 246                (to   (value-bytes to)))
 247       (cond ((null? to))  ; done, we truncate the rest
 248             ((null? from) ; promote the value by padding
 249              (move (new-byte-lit 0) (car to))
 250              (loop from (cdr to)))
 251             (else
 252              (move (car from) (car to))
 253              (loop (cdr from) (cdr to))))))
 254
 255   (define (return-with-no-new-bb def-proc)
 256     (emit (new-return-instr def-proc)))
 257
 258   (define (return ast)
 259     (if (null? (ast-subasts ast))
 260         (return-with-no-new-bb current-def-proc)
 261         (let ((value (expression (subast1 ast))))
 262           (let ((ext-value (extend value (def-procedure-type current-def-proc))))
 263             (move-value value (def-procedure-value current-def-proc))
 264             (return-with-no-new-bb current-def-proc))))
 265     (in (new-bb)))
 266
 267   (define (if1 ast)
 268     (let* ((bb-join (new-bb))
 269            (bb-then (new-bb)))
 270       (test-expression (subast1 ast) bb-then bb-join)
 271       (in bb-then)
 272       (statement (subast2 ast))
 273       (gen-goto bb-join)
 274       (in bb-join)))
 275
 276   (define (if2 ast)
 277     (let* ((bb-join (new-bb))
 278            (bb-then (new-bb))
 279            (bb-else (new-bb)))
 280       (test-expression (subast1 ast) bb-then bb-else)
 281       (in bb-then)
 282       (statement (subast2 ast))
 283       (gen-goto bb-join)
 284       (in bb-else)
 285       (statement (subast3 ast))
 286       (gen-goto bb-join)
 287       (in bb-join)))
 288
 289   (define (while ast)
 290     (let* ((bb-cont (new-bb))
 291            (bb-exit (new-bb))
 292            (bb-body (new-bb)))
 293       (push-continue bb-cont)
 294       (push-break bb-exit)
 295       (gen-goto bb-cont)
 296       (in bb-cont)
 297       (test-expression (subast1 ast) bb-body bb-exit)
 298       (in bb-body)
 299       (statement (subast2 ast))
 300       (gen-goto bb-cont)
 301       (in bb-exit)
 302       (pop-continue)
 303       (pop-break)))
 304
 305   (define (do-while ast)
 306     (let* ((bb-body (new-bb))
 307            (bb-cont (new-bb))
 308            (bb-exit (new-bb)))
 309       (push-continue bb-cont)
 310       (push-break bb-exit)
 311       (gen-goto bb-body)
 312       (in bb-body)
 313       (statement (subast1 ast))
 314       (gen-goto bb-cont)
 315       (in bb-cont)
 316       (test-expression (subast2 ast) bb-body bb-exit)
 317       (in bb-exit)
 318       (pop-continue)
 319       (pop-break)))
 320
 321   (define (for ast)
 322     (let* ((bb-loop (new-bb))
 323            (bb-body (new-bb))
 324            (bb-cont (new-bb))
 325            (bb-exit (new-bb)))
 326       (statement (subast1 ast))
 327       (gen-goto bb-loop)
 328       (push-continue bb-cont)
 329       (push-break bb-exit)
 330       (in bb-loop)
 331       (test-expression (subast2 ast) bb-body bb-exit)
 332       (in bb-body)
 333       (statement (subast4 ast))
 334       (gen-goto bb-cont)
 335       (in bb-cont)
 336       (statement (subast3 ast))
 337       (gen-goto bb-loop)
 338       (in bb-exit)
 339       (pop-continue)
 340       (pop-break)))
 341
 342   ;; switchs with branch tables
 343   ;; since offsets are calculated using one byte, switches are limited to
 344   ;; 60 cases or so (slightly below 64)
 345   (define (switch ast)
 346     (let* ((var      (subast1 ast))
 347            (entry-bb bb)
 348            (exit-bb  (new-bb)))
 349       (push-break exit-bb)
 350       (let loop ((asts    (cdr (ast-subasts ast))) ; car is the tested variable
 351                  (bbs     '())  ; first bb of each case
 352                  (end-bbs '())  ; last bb of each case
 353                  (cases   '())) ; case labels
 354         (if (not (null? asts))
 355             (let ((x       (car asts))
 356                   (case-bb (new-bb)))
 357               (in case-bb)
 358               (block x)
 359               (if (or (null? (bb-succs case-bb))
 360                       (not (bb-label-name (car (bb-succs case-bb)))))
 361                   ;; the first block inside the body of a switch might not
 362                   ;; have a label, in which case it ill be skipped
 363                   ;; to have a valid CFG, it must still contain an instruction
 364                   (begin (gen-goto exit-bb)
 365                          (loop (cdr asts) bbs end-bbs cases))
 366                   (loop (cdr asts)
 367                         (cons case-bb bbs)
 368                         (cons bb      end-bbs)
 369                         ;; blocks create their own bb, which contains the case label
 370                         (cons (bb-label-name (car (bb-succs case-bb)))
 371                               cases))))
 372             (let ((bbs     (reverse bbs))
 373                   (end-bbs (reverse end-bbs))
 374                   (cases   (reverse cases))
 375                   (l       (length  bbs)))
 376               ;; add the case names to the bb names
 377               (for-each ;; TODO do it for all named bbs, not just switch (but, since the name is on the successor, might be lost)
 378                (lambda (bb case)
 379                  (vector-set!
 380                   (bb-label (car (bb-succs bb))) 2
 381                   (string->symbol
 382                    (string-append (symbol->string (bb-name bb))
 383                                   "$"
 384                                   (if (symbol? case)
 385                                       ;; default
 386                                       (symbol->string case)
 387                                       ;; (case n)
 388                                       (string-append
 389                                        (symbol->string (car case))
 390                                        (number->string (cadr case))))))))
 391                bbs
 392                cases)
 393               ;; handle fall-throughs
 394               (for-each
 395                (lambda (i)
 396                  (let ((case-bb (list-ref end-bbs i)))
 397                    (if (null? (bb-succs case-bb))
 398                        ;; fall through
 399                        (begin (in case-bb)
 400                               (gen-goto (if (= i (- l 1)) ; last bb
 401                                             exit-bb
 402                                             (list-ref bbs (+ i 1))))))))
 403                (iota l))
 404               (let* ((default   (memq 'default cases)) ;; TODO if default, since we can't know the domain of possible values (at least, not with enough precision for it to be interesting), revert to naive switch
 405                      ;; cases are lists (case n) and we want the numbers
 406                      (cases     (map cadr (keep list? cases)))
 407                      (case-max  (foldl max 0        cases))
 408                      (case-min  (foldl min case-max cases))
 409                      (n-entries (+ (- case-max case-min) 1)))
 410                 (if default (error "default is not supported with switch"))
 411                 (in entry-bb)
 412                 (bb-succs-set! bb
 413                                (map (lambda (i)
 414                                       (cond ((pos-in-list (+ i case-min) cases)
 415                                              => (lambda (j) (list-ref bbs j)))
 416                                             ;; no label, jump to the exit TODO would jump to default, eventually
 417                                             (else exit-bb)))
 418                                     (iota n-entries)))
 419                 ;; the branch-table virtual instruction takes the byte to check
 420                 ;; to choose the branch
 421                 (emit
 422                  (new-instr
 423                   'branch-table
 424                   ;; the cases now start from 0, so we might have to
 425                   ;; adjust the checked variable
 426                   (car (value-bytes
 427                         (expression
 428                          (if (= case-min 0)
 429                              var
 430                              (let* ((op  (operation? '(six.x-y)))
 431                                     (ast (new-oper
 432                                           (list var (new-literal 'int8
 433                                                                  case-min))
 434                                           #f
 435                                           op)))
 436                                (expr-type-set! ast ((op-type-rule op) ast))
 437                                ast)))))
 438                   ;; working space to calculate addresses
 439                   (new-byte-cell #f (bb-name bb))
 440                   #f))))))
 441       (in exit-bb)
 442       (pop-break)))
 443
 444 ;;   ;; naive switch with if cascade ;; TODO revert to that if there's a case we can't handle with branch tables
 445 ;;   (define (switch ast)
 446 ;;     (let* ((var (subast1 ast))
 447 ;;         (case-list #f)
 448 ;;         (default #f)
 449 ;;         (decision-bb bb)
 450 ;;         (exit-bb (new-bb))
 451 ;;         (prev-bb decision-bb))
 452 ;;       (push-break exit-bb)
 453 ;;       (for-each (lambda (x) ; generate each case
 454 ;;                (in (new-bb)) ; this bb will be given the name of the case
 455 ;;                (add-succ decision-bb bb)
 456 ;;                ;; if the previous case didn't end in a break, fall through
 457 ;;                (if (null? (bb-succs prev-bb))
 458 ;;                    (let ((curr bb))
 459 ;;                      (in prev-bb)
 460 ;;                      (gen-goto curr)
 461 ;;                      (in curr)))
 462 ;;                (statement x)
 463 ;;                (set! prev-bb bb))
 464 ;;              (cdr (ast-subasts ast)))
 465 ;;       (if (null? (bb-succs prev-bb)) ; if the last case didn't end in a break, fall through to the exit
 466 ;;        (gen-goto exit-bb))
 467 ;;       (bb-succs-set! decision-bb (reverse (bb-succs decision-bb))) ; preserving the order is important in the absence of break
 468 ;;       (set! case-list (list-named-bbs decision-bb))
 469 ;;       (set! default (keep (lambda (x) (eq? (car x) 'default))
 470 ;;                        (list-named-bbs decision-bb)))
 471 ;;       (set! case-list (keep (lambda (x) (and (list? (car x))
 472 ;;                                           (eq? (caar x) 'case)))
 473 ;;                          case-list))
 474 ;;       (bb-succs-set! decision-bb '()) ; now that we have the list of cases we don't need the successors anymore
 475 ;;       (let loop ((case-list case-list)
 476 ;;               (decision-bb decision-bb))
 477 ;;      (in decision-bb)
 478 ;;      (if (not (null? case-list))
 479 ;;          (let* ((next-bb (new-bb))
 480 ;;                 (curr-case (car case-list))
 481 ;;                 (curr-case-id (cadar curr-case))
 482 ;;                 (curr-case-bb (cdr curr-case)))
 483 ;;            (emit (new-instr 'x==y
 484 ;;                             (car (value-bytes (expression var)))
 485 ;;                             (new-byte-lit curr-case-id) #f))
 486 ;;            (add-succ bb next-bb) ; if false, keep looking
 487 ;;            (add-succ bb curr-case-bb) ; if true, go to the case
 488 ;;            (loop (cdr case-list)
 489 ;;                  next-bb))
 490 ;;          (gen-goto (if (not (null? default))
 491 ;;                        (cdar default)
 492 ;;                        exit-bb))))
 493 ;;       (in exit-bb)
 494 ;;       (pop-break)))
 495
 496   (define (break ast)
 497     (gen-goto (car break-stack)))
 498
 499   (define (continue ast)
 500     (gen-goto (car continue-stack)))
 501
 502   ;; generates a goto with a target label. once the current function definition
 503   ;; is over, all these labels are resolved. therefore, we don't have any gotos
 504   ;; that jump from a function to another
 505   (define (goto ast)
 506     (emit (new-instr 'goto #f #f (subast1 ast))))
 507
 508   (define (gen-goto dest)
 509     (if (null? (bb-succs bb))
 510         ;; since this is an unconditional goto, we want only one
 511         (begin (add-succ bb dest)
 512                (emit (new-instr 'goto #f #f #f)))))
 513
 514   (define (test-expression ast bb-true bb-false)
 515
 516     (define (test-byte id byte1 byte2 bb-true bb-false)
 517       (define (test-lit id x y)
 518         ((case id
 519            ((x==y) =)
 520            ((x<y) <)
 521            ((x>y) >)
 522            (else (error "invalid test")))
 523          x
 524          y))
 525       (cond ((and (byte-lit? byte1) (byte-lit? byte2))
 526              (if (test-lit id (byte-lit-val byte1) (byte-lit-val byte2))
 527                  (gen-goto bb-true)
 528                  (gen-goto bb-false)))
 529             ((byte-lit? byte2)
 530              ;; since we cons each new successor at the front, true has to be
 531              ;; added last
 532              (add-succ bb bb-false)
 533              (add-succ bb bb-true)
 534              (emit (new-instr id byte1 byte2 #f)))
 535             ((byte-lit? byte1)
 536              (let ((id
 537                     (case id
 538                       ((x==y) 'x==y)
 539                       ((x<y) 'x>y)
 540                       ((x>y) 'x<y)
 541                       (else (error "invalid test")))))
 542                (add-succ bb bb-false)
 543                (add-succ bb bb-true)
 544                (emit (new-instr id byte2 byte1 #f))))
 545             (else
 546              (add-succ bb bb-false)
 547              (add-succ bb bb-true)
 548              (emit (new-instr id byte1 byte2 #f)))))
 549
 550     (define (test-value id value1 value2 bb-true bb-false)
 551          (let loop ((bytes1  (value-bytes value1)) ; lsb first
 552                     (bytes2  (value-bytes value2))
 553                     (padded1 '())
 554                     (padded2 '()))
 555            (if (not (and (null? bytes1) (null? bytes2)))
 556                ;; note: won't work with signed types, as the padding is done
 557                ;; with 0s only
 558                (loop (if (null? bytes1) bytes1 (cdr bytes1))
 559                      (if (null? bytes2) bytes2 (cdr bytes2))
 560                      (cons (if (null? bytes1) (new-byte-lit 0) (car bytes1))
 561                            padded1)
 562                      (cons (if (null? bytes2) (new-byte-lit 0) (car bytes2))
 563                            padded2))
 564                ;; now so the test itself, using the padded values
 565                ;; the comparisons are done msb-first, for < and >
 566                (let ((padded1 (reverse padded1))
 567                      (padded2 (reverse padded2)))
 568                  (case id
 569                    ((x==y) ; unlike < and >, must check all bytes, so is simpler
 570                     (let loop2 ((bytes1 padded1) ;; TODO ior the xors
 571                                 (bytes2 padded2))
 572                       (let ((byte1 (car bytes1))
 573                             (byte2 (car bytes2)))
 574                         (if (null? (cdr bytes1))
 575                             (test-byte 'x==y byte1 byte2 bb-true bb-false)
 576                             (let ((bb-true2 (new-bb)))
 577                               (test-byte 'x==y byte1 byte2 bb-true2 bb-false)
 578                               (in bb-true2)
 579                               (loop2 (cdr bytes1) (cdr bytes2)))))))
 580
 581                    (else ; < and >
 582                     (if (= (length padded1) 1)
 583                         (test-byte id (car padded1) (car padded2)
 584                                    bb-true bb-false)
 585                         ;; more than one byte, we subtract, then see if we had
 586                         ;; to borrow
 587                         (let ((scratch (new-byte-cell #f (bb-name bb))))
 588
 589                           ;; our values might contain literal bytes and sub and
 590                           ;; subb can't have literals in their first argument,
 591                           ;; allocate it somewhere if needed
 592                           (if (and (foldl (lambda (acc new)
 593                                             (or acc (byte-lit? new)))
 594                                           #f padded2)
 595                                    (eq? id 'x>y))
 596                               (let ((tmp (alloc-value
 597                                           (bytes->type (length padded2))
 598                                           #f (bb-name bb))))
 599                                 (move-value (new-value padded2) tmp)
 600                                 (set! padded2 (value-bytes tmp))))
 601                           (if (and (foldl (lambda (acc new) ;; TODO abstract both cases
 602                                             (or acc (byte-lit? new)))
 603                                           #f padded1)
 604                                    (eq? id 'x<y))
 605                               (let ((tmp (alloc-value
 606                                           (bytes->type (length padded1))
 607                                           #f (bb-name bb))))
 608                                 (move-value (new-value padded1) tmp)
 609                                 (set! padded1 (value-bytes tmp))))
 610
 611                           (let loop ((bytes1  padded1)
 612                                      (bytes2  padded2)
 613                                      (borrow? #f))
 614                             (if (not (null? bytes1))
 615                                 (begin ; subtract y from x
 616                                   (emit
 617                                    (case id
 618                                      ((x<y) (new-instr (if borrow? 'subb 'sub)
 619                                                        (car bytes1) (car bytes2)
 620                                                        scratch))
 621                                      ((x>y) (new-instr (if borrow? 'subb 'sub)
 622                                                        (car bytes2) (car bytes1)
 623                                                        scratch))))
 624                                   (loop (cdr bytes1) (cdr bytes2) #t))))
 625
 626                           (add-succ bb bb-false)
 627                           (add-succ bb bb-true)
 628                           (emit (new-instr 'branch-if-carry scratch #f #f))))))))))
 629
 630     (define (test-relation id x y bb-true bb-false)
 631       (cond ((and (literal? x) (not (literal? y)))
 632              ;; literals must be in the last argument for code generation
 633              ;; flip the relation if needed
 634              (test-relation (case id
 635                               ((x==y x!=y) id) ; commutative, no change
 636                               ((x<y)       'x>y)
 637                               ((x>y)       'x<y)
 638                               ((x<=y)      'x>=y)
 639                               ((x>=y)      'x<=y)
 640                               (else (error "relation error")))
 641                             y
 642                             x
 643                             bb-true
 644                             bb-false))
 645             ((assq id '((x!=y . x==y) (x<=y . x>y) (x>=y . x<y)))
 646              ;; flip the destination blocks to have a simpler comparison
 647              =>
 648              (lambda (z) (test-relation (cdr z) x y bb-false bb-true)))
 649             (else
 650              ;; normal case
 651 ;;           ' ;; TODO use these special cases, but fall back on the current implementation for default
 652 ;;           (case id
 653 ;;             ((x==y)
 654 ;;              (cond ((and (literal? y) (= (literal-val y) 0))
 655 ;;                     (test-zero x bb-true bb-false))
 656 ;;                    ((literal? y)
 657 ;;                     (test-eq-lit x (literal-val y) bb-true bb-false))
 658 ;;                    (else
 659 ;;                     (error "unhandled case"))))
 660 ;;             ((x<y)
 661 ;;              (cond ((and (literal? y) (= (literal-val y) 0))
 662 ;;                     (test-negative x bb-true bb-false))
 663 ;;                    (else
 664 ;;                     (error "unhandled case"))))
 665 ;;             ((x>y)
 666 ;;              (cond ((and (literal? y) (= (literal-val y) 0))
 667 ;;                     (test-positive x bb-true bb-false))
 668 ;;                    (else
 669 ;;                     (error "unhandled case"))))
 670 ;;             (else
 671 ;;              (error "unexpected operator")))
 672
 673              (let* ((value1 (expression x))
 674                     (value2 (expression y)))
 675                (test-value id value1 value2 bb-true bb-false))
 676              )))
 677
 678     (define (test-zero ast bb-true bb-false)
 679
 680       (define (default)
 681         (let ((type (expr-type ast))
 682               (value (expression ast)))
 683           ;; since nonzero is true, we must swap the destinations to use ==
 684           (test-value 'x==y value (int->value 0 type) bb-false bb-true)))
 685
 686       (cond ((oper? ast)
 687              (let* ((op (oper-op ast))
 688                     (id (op-id op)))
 689                (case id
 690                  ((!x)
 691                   (test-zero (subast1 ast) bb-false bb-true))
 692                  ((x&&y)
 693                   (let ((bb-true2 (new-bb)))
 694                     (test-zero (subast1 ast) bb-true2 bb-false)
 695                     (in bb-true2)
 696                     (test-zero (subast2 ast) bb-true bb-false)))
 697                  ((|x\|\|y|)
 698                   (let ((bb-false2 (new-bb)))
 699                     (test-zero (subast1 ast) bb-true bb-false2)
 700                     (in bb-false2)
 701                     (test-zero (subast2 ast) bb-true bb-false)))
 702                  ((x==y x!=y x<y x>y x<=y x>=y)
 703                   (test-relation id
 704                                  (subast1 ast)
 705                                  (subast2 ast)
 706                                  bb-true
 707                                  bb-false))
 708                  (else (default)))))
 709             (else (default))))
 710
 711     (test-zero ast bb-true bb-false))
 712
 713   (define (expression ast)
 714     (let ((result
 715            (cond ((literal? ast) (literal ast))
 716                  ((ref? ast)     (ref ast))
 717                  ((oper? ast)    (oper ast))
 718                  ((call? ast)    (call ast))
 719                  (else           (error "unexpected ast" ast)))))
 720       (do-delayed-post-incdec)
 721       result))
 722
 723   (define (literal ast)
 724     (let ((val (literal-val ast)))
 725       (int->value val (expr-type ast))))
 726
 727   (define (ref ast)
 728     (let* ((def-var (ref-def-var ast))
 729            (value (def-variable-value def-var)))
 730       value))
 731
 732   (define (add-sub id value1 value2 result)
 733     (let loop ((bytes1 (value-bytes value1)) ; car is lsb
 734                (bytes2 (value-bytes value2))
 735                (bytes3 (value-bytes result))
 736                (ignore-carry-borrow? #t))
 737       (if (not (null? bytes3))
 738           ;; if we would add or subtract 0 and not use the carry, just move
 739           ;; the value
 740           (let ((b1 (car bytes1)) (b2 (car bytes2)) (b3 (car bytes3)))
 741             (if (and (byte-lit? b2)
 742                      (= (byte-lit-val b2) 0)
 743                      (or (eq? id 'add) (eq? id 'sub)))
 744                 (move b1 b3)
 745                 (emit (new-instr (if ignore-carry-borrow?
 746                                      (case id ((x+y) 'add)  ((x-y) 'sub))
 747                                      (case id ((x+y) 'addc) ((x-y) 'subb)))
 748                                  b1 b2 b3)))
 749             (loop (cdr bytes1) (cdr bytes2) (cdr bytes3) #f))
 750           result)))
 751
 752   (define (mul x y type result)
 753     (let* ((value-x (expression x))
 754            (value-y (expression y))
 755            (bytes-x (value-bytes value-x))
 756            (bytes-y (value-bytes value-y))
 757            (lx (length bytes-x))
 758            (ly (length bytes-y)))
 759       ;; if this a multiplication by 2 or 4, we use additions instead
 760       ;; at this point, only y (or both x and y) can contain a literal
 761       (if (and (= ly 1)
 762                (byte-lit? (car bytes-y))
 763                (let ((v (byte-lit-val (car bytes-y))))
 764                  (or (= v 2) (= v 4))))
 765           (case (byte-lit-val (car bytes-y))
 766             ((2) (add-sub 'x+y value-x value-x result)) ; simple addition
 767             ((4) (let ((tmp (alloc-value (bytes->type
 768                                           (length (value-bytes result)))
 769                                          #f (bb-name bb))))
 770                    (add-sub 'x+y value-x value-x tmp)
 771                    (add-sub 'x+y tmp tmp result))))
 772           ;; if not, we have to do it the long way
 773           (begin
 774             ;; finds the appropriate multiplication routine (depending on the
 775             ;; length of each argument) and turns the multiplication into a
 776             ;; call to the routine
 777             ;; the arguments must be the asts of the 2 arguments (x and y) and
 778             ;; the type of the returned value, since these are what are
 779             ;; expected by the call function
 780
 781             ;; to avoid code duplication (i.e. habing a routine for 8 by 16
 782             ;; multplication and one for 16 by 8), the longest operand goes first
 783             (if (> ly lx)
 784                 (let ((tmp1 y)
 785                       (tmp2 ly))
 786                   (set! y x)
 787                   (set! x tmp1)
 788                   (set! ly lx)
 789                   (set! lx tmp2)))
 790             (routine-call
 791              (string->symbol ; mul8_8, mul8_16, etc
 792               ;; for now, only unsigned multiplications are supported
 793               (string-append "__mul"
 794                              (number->string (* lx 8)) "_"
 795                              (number->string (* ly 8))))
 796              (list x y)
 797              type)))))
 798
 799   (define (mod x y result)
 800     (let* ((bytes1 (value-bytes x))
 801            (bytes2 (value-bytes y))
 802            (bytes3 (value-bytes result))
 803            (y0     (car bytes2)))
 804       ;; if y is a literal and a power of 2, we can do a bitwise and
 805       (if (and (byte-lit? y0)
 806                (let ((x (/ (log (value->int y)) (log 2))))
 807                  (= (floor x) x)))
 808           ;; bitwise and with y - 1
 809           (begin (let* ((l   (bytes->type (length bytes2)))
 810                         (tmp (alloc-value l #f (bb-name bb))))
 811                    (move-value (int->value (- (value->int y) 1)
 812                                            (bytes->type (length bytes2)))
 813                                tmp)
 814                    (bitwise 'x&y x tmp result)))
 815           ;; TODO for the general case, try to optimise the case where division and modulo are used together, since they are calculated together
 816           (error "modulo is only supported for powers of 2"))
 817       result))
 818
 819   (define (shift id x y type result)
 820     (let ((bytes1 (value-bytes (extend (expression x) type)))
 821           (bytes2 (value-bytes (extend (expression y) type)))
 822           (bytes3 (value-bytes result)))
 823       ;; if the second argument is a literal and a multiple of 8, we can simply
 824       ;; move the bytes around
 825       (let ((y0 (car bytes2)))
 826         (if (and (byte-lit? y0) (= (modulo (byte-lit-val y0) 8) 0))
 827             ;; uses only the first byte, but shifting by 255 should be enough
 828             (let ((n (/ (byte-lit-val y0) 8))
 829                   (l (length bytes1))) ; same length for x and result
 830               (let loop ((i 0)
 831                          (x bytes1))
 832                 (if (< i l)
 833                     (case id
 834                       ((x<<y)
 835                        (move (if (< i n)
 836                                  (new-byte-lit 0) ; padding
 837                                  (car x))
 838                              (list-ref bytes3 i))
 839                        (loop (+ i 1) (if (< i n) x (cdr x))))
 840                       ((x>>y)
 841                        (move (if (<= l (+ i n))
 842                                  (new-byte-lit 0)
 843                                  (list-ref x (+ i n)))
 844                              (list-ref bytes3 i))
 845                        (loop (+ i 1) x)))
 846                     result)))
 847             (routine-call
 848              (string->symbol
 849               (string-append "__sh"
 850                              (case id ((x<<y) "l") ((x>>y) "r"))
 851                              (number->string (* 8 (length bytes1)))))
 852              (list x y)
 853              type)))))
 854
 855   ;; bitwise and, or, xor
 856   ;; TODO similar to add-sub and probably others, abstract multi-byte ops
 857   ;; TODO use bit set, clear and toggle for some shortcuts
 858   (define (bitwise id value1 value2 result)
 859     (let loop ((bytes1 (value-bytes value1))
 860                (bytes2 (value-bytes value2))
 861                (bytes3 (value-bytes result)))
 862       (if (not (null? bytes3)) ;; TODO check for cases like or 0, or ff, and 0, and ff, ...
 863           (begin
 864             (emit (new-instr (case id ((x&y) 'and) ((|x\|y|) 'ior) ((x^y) 'xor))
 865                              (car bytes1) (car bytes2) (car bytes3)))
 866             (loop (cdr bytes1) (cdr bytes2) (cdr bytes3)))
 867           result)))
 868
 869   (define (bitwise-negation x result)
 870     (let loop ((bytes1 (value-bytes x))
 871                (bytes2 (value-bytes result)))
 872       (if (not (null? bytes2))
 873           (begin (emit (new-instr 'not (car bytes1) #f (car bytes2)))
 874                  (loop (cdr bytes1) (cdr bytes2))))))
 875
 876   (define (do-delayed-post-incdec)
 877     (if (not (null? delayed-post-incdec))
 878         (let* ((ast (car delayed-post-incdec))
 879                (type (expr-type ast))
 880                (op (oper-op ast))
 881                (id (op-id op)))
 882           (set! delayed-post-incdec (cdr delayed-post-incdec))
 883           (let ((x (subast1 ast)))
 884             (if (not (ref? x))
 885                 (error "assignment target must be a variable"))
 886             (let ((result (def-variable-value (ref-def-var x))))
 887               ;; clobbers the original value, which is fine, since it
 888               ;; was moved somewhere else for the expression
 889               (add-sub (if (eq? id 'x++) 'x+y 'x-y)
 890                        result
 891                        (int->value 1 type)
 892                        result)))
 893           (do-delayed-post-incdec))))
 894
 895   ;; calculates an address in an array by adding the base pointer and the offset
 896   ;; and puts the answer in FSR0 so that changes to INDF0 change the array
 897   ;; location
 898   (define (calculate-address ast)
 899     ;; if we have a special FSR variable, no need to calculate the address as
 900     ;; it is already in the register
 901     (let ((base-name (array-base-name ast))
 902           (index? (eq? (op-id (oper-op ast)) 'index)))
 903       (if (not (and base-name
 904                     (memq base-name fsr-variables)))
 905           (let ((base    (expression (subast1 ast)))
 906                 ;; NB: actual addresses are 12 bits, not 16
 907                 (address (new-value (list (get-register FSR0L)
 908                                           (get-register FSR0H)))))
 909             (if index?
 910                 ;; we pad up to int16, since it is the size of the addresses
 911                 (let ((value1 (extend base 'int16))
 912                       (value2 (extend (expression (subast2 ast)) 'int16)))
 913                   (add-sub 'x+y value1 value2 address))
 914                 ;; no offset with simple dereference
 915                 (move-value base address)))
 916           (error "You used the array index syntax with a FSR variable, didn't you? I told you not to."))))
 917
 918   (define (array-base-name ast)
 919     ;; returns #f if the lhs is not a direct variable reference
 920     ;; eg : *x++ ; (x+y)* ; ...
 921     (let ((lhs (subast1 ast)))
 922       (and (ref? lhs)
 923            (def-id (ref-def-var lhs)))))
 924
 925   (define (get-indf base-name)
 926     ;; INDF0 is not here, since it's already used for regular array accesses
 927     (if (eq? base-name 'SIXPIC_FSR1)
 928         (new-value (list (get-register INDF1)))
 929         (new-value (list (get-register INDF2)))))
 930
 931   (define (oper ast)
 932     (let* ((type (expr-type ast))
 933            (op (oper-op ast))
 934            (id (op-id op)))
 935
 936       (define (arith-op id x y value-x value-y)
 937         ;; since code generation does not accept literals as first
 938         ;; arguments unless both arguments are, if this is the
 939         ;; case, we either have to swap the arguments (if
 940         ;; possible) or allocate the argument somewhere
 941         (if (and (literal? x) (not (literal? y)))
 942             (if (memq id '(x+y x*y x&y |x\|y| x^y))
 943                 ;; the operator is commutative, we can swap the args
 944                 (let ((tmp value-x))
 945                   (set! value-x value-y)
 946                   (set! value-y tmp))
 947                 ;; the operator is not commutative, we have to
 948                 ;; allocate the first argument somewhere
 949                 (let ((dest (alloc-value (expr-type x) #f (bb-name bb))))
 950                   (move-value value-x dest)
 951                   (set! value-x dest))))
 952         (let ((result (alloc-value type #f (bb-name bb))))
 953           (case id
 954             ((x+y x-y)        (add-sub id value-x value-y result))
 955             ((x*y)            (mul x y type result))
 956             ((x/y)            (error "division not implemented yet")) ;; TODO optimize for powers of 2
 957             ((x%y)            (mod value-x value-y result))
 958             ((x&y |x\|y| x^y) (bitwise id value-x value-y result))
 959             ((x>>y x<<y)      (shift id x y type result)))))
 960
 961       (cond
 962        ((op1? op)
 963         (case id
 964           ((-x ~x)
 965            (let ((x (extend (expression (subast1 ast))
 966                             type))
 967                  (result (alloc-value type #f (bb-name bb))))
 968              (case id
 969                ((-x) (add-sub 'x-y
 970                               (int->value 0 type)
 971                               x
 972                               result))
 973                ((~x) (bitwise-negation x result)))
 974              result))
 975           ((++x --x)
 976            (let ((x (subast1 ast)))
 977              (if (not (ref? x))
 978                  (error "assignment target must be a variable"))
 979              (let ((result (def-variable-value (ref-def-var x))))
 980                (add-sub (if (eq? id '++x) 'x+y 'x-y)
 981                         result
 982                         (int->value 1 type)
 983                         result)
 984                result)))
 985           ((x++ x--)
 986            (let ((x (subast1 ast)))
 987              (if (not (ref? x))
 988                  (error "assignment target must be a variable"))
 989              ;; push-delayed-post-incdec moves the original value
 990              ;; somewhere else, and returns that location
 991              (push-delayed-post-incdec ast)))
 992           ((*x)
 993            ;; if it's a FSR variable, no adress to set
 994            (let ((base-name (array-base-name ast)))
 995              (if (and (ref? (subast1 ast)) ; do we have a FSR variable ?
 996                       base-name
 997                       (memq base-name fsr-variables))
 998                  (get-indf base-name)
 999                  (begin (calculate-address ast)
1000                         (new-value (list (get-register INDF0)))))))
1001           (else
1002            (error "unary operation error" id))))
1003
1004        ((op2? op)
1005         (case id
1006           ((x+y x-y x*y x/y x%y x&y |x\|y| x^y x>>y x<<y)
1007            (let* ((x (subast1 ast))
1008                   (y (subast2 ast)))
1009              (let* ((value-x (extend (expression x) type))
1010                     (value-y (extend (expression y) type)))
1011                (arith-op id x y value-x value-y))))
1012           ((x=y)
1013            (let* ((x       (subast1 ast))
1014                   (y       (subast2 ast))
1015                   (value-y (expression y)))
1016              (cond
1017               ;; lhs is a variable
1018               ((ref? x)
1019                (let ((ext-value-y (extend value-y type)))
1020                  (let ((result (def-variable-value (ref-def-var x))))
1021                    (move-value value-y result)
1022                    result)))
1023               ;; lhs is a pointer dereference
1024               ((and (oper? x) (eq? (op-id (oper-op x)) '*x))
1025                (let ((base-name (array-base-name x))
1026                      (val       (car (value-bytes value-y))))
1027                  (if (and (ref? (subast1 x))
1028                           base-name
1029                           (memq base-name fsr-variables))
1030                      (move val (car (value-bytes (get-indf base-name))))
1031                      (begin (calculate-address x)
1032                             (move val (get-register INDF0))))))
1033               ;; lhs is an indexed array access
1034               ((and (oper? x) (eq? (op-id (oper-op x)) 'index))
1035                ;; note: this will throw an error if SIXPIC_FSR{1,2} is
1036                ;; used. this is by design, as it would clobber the value
1037                ;; in the FSR registers, which goes against their purpose
1038                ;; of storing a user-chosen value
1039                (calculate-address x)
1040                ;; this section of memory is a byte array, only the lsb
1041                ;; of y is used
1042                (move (car (value-bytes value-y)) (get-register INDF0)))
1043               (else (error "assignment target must be a variable or an array slot")))))
1044           ((index)
1045            ;; note: throws an error if given SIXPIC_FSR{1,2}, see above
1046            (calculate-address ast)
1047            (new-value (list (get-register INDF0))))
1048           ((x+=y x-=y x*=y x/=y x%=y x&=y |x\|=y| x^=y x>>=y x<<=y)
1049            (let* ((x (subast1 ast))
1050                   (y (subast2 ast))
1051                   (value-x (extend (expression x) type))
1052                   (value-y (extend (expression y) type)))
1053              (move-value (arith-op (case id
1054                                      ((x+=y)    'x+y)
1055                                      ((x-=y)    'x-y)
1056                                      ((x*=y)    'x*y)
1057                                      ((x/=y)    'x/y)
1058                                      ((x%=y)    'x%y)
1059                                      ((x&=y)    'x&y)
1060                                      ((|x\|=y|) '|x\|y|)
1061                                      ((x^=y)    'x^=y)
1062                                      ((x>>=y)   'x>>y)
1063                                      ((x<<=y)   'x<<y))
1064                                    x y value-x value-y)
1065                          value-x)
1066              value-x))
1067           ((x==y x!=y x>y x>=y x<y x<=y x&&y |x\|\|y|)
1068            (let ((bb-start bb)
1069                  (bb-true  (new-bb))
1070                  (bb-false (new-bb))
1071                  (bb-join  (new-bb))
1072                  (result   (alloc-value type #f (bb-name bb))))
1073              (in bb-true)
1074              (move-value (int->value 1 type) result)
1075              (gen-goto bb-join)
1076              (in bb-false)
1077              (move-value (int->value 0 type) result)
1078              (gen-goto bb-join)
1079              (in bb-start)
1080              (test-expression ast bb-true bb-false)
1081              (in bb-join)
1082              result))
1083           (else
1084            (error "binary operation error" id))))
1085
1086        ((op3? op)
1087         (let ((bb-start bb)
1088               (bb-true  (new-bb))
1089               (bb-false (new-bb))
1090               (bb-join  (new-bb))
1091               (result   (alloc-value type #f (bb-name bb))))
1092           (in bb-true)
1093           (move-value (expression (subast2 ast)) result)
1094           (gen-goto bb-join)
1095           (in bb-false)
1096           (move-value (expression (subast3 ast)) result)
1097           (gen-goto bb-join)
1098           (in bb-start)
1099           (test-expression (subast1 ast) bb-true bb-false)
1100           (in bb-join)
1101           result)))))
1102
1103   ;; generates the cfg for a predefined routine and adds it to the current cfg
1104   (define (include-predefined-routine proc)
1105     (define (get-bytes var)
1106       (value-bytes (def-variable-value var)))
1107     (let ((old-proc current-def-proc) ; if we were already defining a procedure, save it
1108           (old-bb-no current-def-proc-bb-id)
1109           (id (def-id proc))
1110           (params (def-procedure-params proc))
1111           (value (def-procedure-value proc))
1112           (old-bb bb)
1113           (entry (begin (set! current-def-proc proc)
1114                         (set! current-def-proc-bb-id 0)
1115                         (new-bb)))) ;; TODO insipired from def-procedure, abstract
1116       (def-procedure-entry-set! proc entry)
1117       (in entry)
1118       (case id
1119
1120         ((rom_get)
1121          (let* ((x  (get-bytes (car params)))
1122                 (x0 (car  x))
1123                 (x1 (cadr x))
1124                 (z0 (car (value-bytes value))))
1125            ;; TODO use postinc/dec and co
1126            (emit (new-instr 'tblrd x0 x1 #f))
1127            (move (get-register TABLAT) z0)))
1128
1129         ((__mul8_8)
1130          (let ((x (car params))
1131                (y (cadr params))
1132                (z (value-bytes value)))
1133            ;; TODO implement literal multiplication in the simulator
1134            (emit (new-instr 'mul (car (get-bytes x)) (car (get-bytes y)) #f))
1135            (move (get-register PRODL) (car z)))) ; lsb
1136
1137         ((__mul16_8)
1138          (let* ((x  (get-bytes (car params)))
1139                 (x0 (car  x)) ; lsb
1140                 (x1 (cadr x))
1141                 (y  (get-bytes (cadr params)))
1142                 (y0 (car y))
1143                 (z  (value-bytes value))
1144                 (z0 (car  z)) ; lsb
1145                 (z1 (cadr z)))
1146            (emit (new-instr 'mul y0 x1 #f))
1147            (move (get-register PRODL) z1)
1148
1149            (emit (new-instr 'mul y0 x0 #f))
1150            (move (get-register PRODL) z0)
1151            (emit (new-instr 'add  (get-register PRODH) z1 z1))))
1152
1153         ((__mul16_16)
1154          (let* ((x  (get-bytes (car params)))
1155                 (x0 (car  x))
1156                 (x1 (cadr x))
1157                 (y  (get-bytes (cadr params)))
1158                 (y0 (car  y))
1159                 (y1 (cadr y))
1160                 (z  (value-bytes value))
1161                 (z0 (car  z))
1162                 (z1 (cadr z)))
1163
1164            (emit (new-instr 'mul x0 y0 #f))
1165            (move (get-register PRODH) z1)
1166            (move (get-register PRODL) z0)
1167
1168            (emit (new-instr 'mul x0 y1 #f))
1169            (emit (new-instr 'add  (get-register PRODL) z1 z1))
1170
1171            (emit (new-instr 'mul x1 y0 #f))
1172            (emit (new-instr 'add  (get-register PRODL) z1 z1))))
1173
1174         ((__mul32_16)
1175          (let* ((x  (get-bytes (car params)))
1176                 (x0 (car    x))
1177                 (x1 (cadr   x))
1178                 (x2 (caddr  x))
1179                 (x3 (cadddr x))
1180                 (y  (get-bytes (cadr params)))
1181                 (y0 (car  y))
1182                 (y1 (cadr y))
1183                 (z  (value-bytes value))
1184                 (z0 (car    z))
1185                 (z1 (cadr   z))
1186                 (z2 (caddr  z))
1187                 (z3 (cadddr z)))
1188
1189            (emit (new-instr 'mul x0 y0 #f))
1190            (move (get-register PRODH) z1)
1191            (move (get-register PRODL) z0)
1192
1193            (emit (new-instr 'mul x1 y1 #f))
1194            (move (get-register PRODH) z3)
1195            (move (get-register PRODL) z2)
1196
1197            (emit (new-instr 'mul x1 y0 #f))
1198            (emit (new-instr 'add  (get-register PRODL) z1 z1))
1199            (emit (new-instr 'addc (get-register PRODH) z2 z2))
1200            (emit (new-instr 'addc z3     (new-byte-lit 0) z3))
1201
1202            (emit (new-instr 'mul x0 y1 #f))
1203            (emit (new-instr 'add  (get-register PRODL) z1 z1))
1204            (emit (new-instr 'addc (get-register PRODH) z2 z2))
1205            (emit (new-instr 'addc z3     (new-byte-lit 0) z3))
1206
1207            (emit (new-instr 'mul x2 y0 #f))
1208            (emit (new-instr 'add  (get-register PRODL) z2 z2))
1209            (emit (new-instr 'addc (get-register PRODH) z3 z3))
1210
1211            (emit (new-instr 'mul x2 y1 #f))
1212            (emit (new-instr 'add  (get-register PRODL) z3 z3))
1213
1214            (emit (new-instr 'mul x3 y0 #f))
1215            (emit (new-instr 'add  (get-register PRODL) z3 z3))))
1216
1217         ((__shl8 __shr8 __shl16 __shr16 __shl32 __shr32)
1218          (let* ((id (symbol->string id))
1219                 (left-shift? (eq? (string-ref id 4) #\l))
1220                 (x (def-variable-value (car params)))
1221                 (y (def-variable-value (cadr params)))
1222                 (y0 (car (value-bytes y))) ; shift by 255 is enough
1223                 (bytes-z (value-bytes value))
1224                 (start-bb (new-bb))
1225                 (loop-bb  (new-bb))
1226                 (after-bb (new-bb)))
1227            (move-value x value)
1228            (gen-goto start-bb) ; fall through to the loop
1229            (in start-bb)
1230            ;; if we'd shift of 0, we're done
1231            (add-succ bb loop-bb) ; false
1232            (add-succ bb after-bb) ; true
1233            (emit (new-instr 'x==y y0 (new-byte-lit 0) #f))
1234            (in loop-bb)
1235            ;; clear the carry, to avoid reinserting it in the register
1236            (emit (new-instr 'clear
1237                             (get-register STATUS)
1238                             (new-byte-lit C)
1239                             #f))
1240            ;; shift for each byte, since it's a rotation using the carry,
1241            ;; what goes out from the low bytes gets into the high bytes
1242            (for-each (lambda (b)
1243                        (emit (new-instr (if left-shift? 'shl 'shr)
1244                                         b #f b)))
1245                      (if left-shift? bytes-z (reverse bytes-z)))
1246            (emit (new-instr 'sub y0 (new-byte-lit 1) y0))
1247            (gen-goto start-bb)
1248            (in after-bb))))
1249       (return-with-no-new-bb proc)
1250       (set! current-def-proc old-proc)
1251       (set! current-def-proc-bb-id old-bb-no)
1252       (resolve-all-gotos entry (list-named-bbs entry))
1253       (in old-bb)))
1254
1255   (define (call ast)
1256     (let* ((def-proc   (call-def-proc ast))
1257            (arguments  (ast-subasts ast))
1258            (parameters (def-procedure-params def-proc)))
1259       (if (and (memq (def-id def-proc) predefined-routines)
1260                (not (def-procedure-entry def-proc)))
1261           ;; it's the first time we encounter this predefined routine, generate
1262           ;; the corresponding cfg
1263           (include-predefined-routine def-proc))
1264       ;; argument number check
1265       (if (not (= (length arguments) (length parameters))) ;; TODO check at parse time ?
1266           (error (string-append "wrong number of arguments given to function "
1267                                 (symbol->string (def-id def-proc)) ": "
1268                                 (number->string (length arguments)) " given, "
1269                                 (number->string (length parameters))
1270                                 " expected")))
1271       (for-each (lambda (ast def-var)
1272                   (let ((value (expression ast)))
1273                     (let ((ext-value (extend value (def-variable-type def-var))))
1274                       (move-value value (def-variable-value def-var)))))
1275                 arguments
1276                 parameters)
1277       (emit (new-call-instr def-proc))
1278       (let ((value (def-procedure-value def-proc)))
1279         (let ((result
1280                (alloc-value (def-procedure-type def-proc) #f (bb-name bb))))
1281           (move-value value result)
1282           result))))
1283
1284   ;; call to a predefined routine, a simple wrapper to an ordinary call
1285   ;; name is a symbol, args is a list of the arguments
1286   (define (routine-call name args type)
1287     (cond ((memp (lambda (x) (eq? (def-id x) name))
1288                  initial-cte)
1289            => (lambda (x) (call (new-call args type (car x)))))
1290           (else (error "unknown routine: " name))))
1291
1292   (in (new-bb))
1293   (program ast)
1294   cfg)
1295
1296 (define (print-cfg-bbs cfg)
1297   (for-each (lambda (bb)
1298               (pp (list "BB:" (bb-name bb)
1299                         "SUCCS" (map bb-name (bb-succs bb))
1300                         "PREDS" (map bb-name (bb-preds bb))
1301                         (cond ((null? (bb-rev-instrs bb)) "EMPTY")
1302                               ((and (null? (cdr (bb-rev-instrs bb)))
1303                                      (eq? (instr-id (car (bb-rev-instrs bb))) 'goto)) "SINGLE GOTO")
1304                               (else #f)))))
1305             (cfg-bbs cfg)))