ast.scm

   1 ;;; definition of ast types
   2
   3 (define-type ast
   4   extender: define-type-of-ast
   5   (parent unprintable:)
   6   subasts)
   7
   8 (define (link-parent! subast parent)
   9   (ast-parent-set! subast parent)
  10   parent)
  11
  12 (define (multi-link-parent! subasts parent)
  13   (for-each (lambda (subast) (link-parent! subast parent))
  14             subasts)
  15   parent)
  16
  17 (define (unlink-parent! subast)
  18   (let ((parent (ast-parent subast)))
  19     (if (and (def-variable? subast) (def-procedure? parent))
  20         (def-procedure-params-set!
  21           parent
  22           (remove subast (def-procedure-params parent)))
  23         (ast-subasts-set!
  24          parent
  25          (remove subast (ast-subasts parent))))
  26     (ast-parent-set! subast #f)
  27     subast))
  28
  29 (define (subast1 ast) (car (ast-subasts ast)))
  30 (define (subast2 ast) (cadr (ast-subasts ast)))
  31 (define (subast3 ast) (caddr (ast-subasts ast)))
  32 (define (subast4 ast) (cadddr (ast-subasts ast)))
  33
  34 (define-type-of-ast def
  35   extender: define-type-of-def
  36   id
  37   unprintable:
  38   refs)
  39
  40 (define-type value
  41   bytes)
  42 (define (new-value bytes)
  43   (make-value bytes))
  44
  45 (define byte-cell-counter 0)
  46 (define (byte-cell-next-id) (let ((id byte-cell-counter))
  47                               (set! byte-cell-counter (+ id 1))
  48                               id))
  49 (define-type byte-cell
  50   id
  51   adr
  52   name ; to display in the listing
  53   bb   ; label of the basic in which this byte-cell is used
  54   (interferes-with   unprintable:) ; these 3 are stored as sets
  55   (coalesceable-with unprintable:)
  56   (coalesced-with    unprintable:))
  57 (define (new-byte-cell #!optional (name #f) (bb #f))
  58   (let ((id (byte-cell-next-id)))
  59     (make-byte-cell
  60      id (if allocate-registers? #f id)
  61      (if name (string-append name "$" (number->string id)) "__tmp") bb
  62      (new-empty-set) (new-empty-set) (new-empty-set))))
  63 (define (get-register n)
  64   (make-byte-cell
  65    (byte-cell-next-id) n
  66    (symbol->string (cdr (assv n file-reg-names))) #f
  67    (new-empty-set) (new-empty-set) (new-empty-set)))
  68
  69 (define-type byte-lit
  70   val)
  71 (define (new-byte-lit x)
  72   (make-byte-lit x))
  73
  74 (define types-bytes
  75   '((void  . 0)
  76     (bool  . 1)
  77     (int   . 2)
  78     (byte  . 1)
  79     (int8  . 1)
  80     (int16 . 2)
  81     (int24 . 3)
  82     (int32 . 4)))
  83
  84 (define (val->type n)
  85   (cond ((and (>= n 0) (< n 256))   'int8)
  86         ((and (>= n 0) (< n 65536)) 'int16)
  87         (else                       'int32)))
  88 (define (type->bytes type)
  89   (cond ((assq type types-bytes)
  90          => (lambda (x) (cdr x)))
  91         (else (error "wrong type?"))))
  92 (define (bytes->type n)
  93   (let loop ((l types-bytes))
  94     (cond ((null? l)     (error (string-append "no type contains "
  95                                                (number->string n)
  96                                                " bytes")))
  97           ((= n (cdar l)) (caar l))
  98           (else (loop (cdr l))))))
  99
 100 (define (int->value n type)
 101   (let ((len (type->bytes type)))
 102     (let loop ((len len) (n n) (rev-bytes '()))
 103       (if (= len 0)
 104           (new-value (reverse rev-bytes))
 105           (loop (- len 1)
 106                 (arithmetic-shift n -8)
 107                 (cons (new-byte-lit (modulo n 256))
 108                       rev-bytes))))))
 109 (define (value->int val)
 110   (let loop ((bytes (reverse (value-bytes val)))
 111              (n     0))
 112     (if (null? bytes)
 113         n
 114         (loop (cdr bytes)
 115               (+ (* 256 n) (byte-lit-val (car bytes)))))))
 116
 117 (define (alloc-value type #!optional (name #f) (bb #f))
 118   (let ((len (type->bytes type)))
 119     (let loop ((len len) (rev-bytes '()))
 120       (if (= len 0)
 121           (new-value rev-bytes)
 122           (loop (- len 1)
 123                 (cons (new-byte-cell
 124                        (if name
 125                            ;; the lsb is 0, and so on
 126                            (string-append (symbol->string name)
 127                                           (number->string (- len 1)))
 128                            #f)
 129                        bb)
 130                       rev-bytes))))))
 131
 132 (define-type-of-def def-variable
 133   type
 134   value
 135   unprintable:
 136   sets)
 137 (define (new-def-variable subasts id refs type value sets)
 138   (multi-link-parent!
 139    subasts
 140    (make-def-variable #f subasts id refs type value sets)))
 141
 142 (define-type-of-def def-procedure
 143   type
 144   value
 145   params
 146   entry
 147   live-after-calls) ; stored as a set
 148 (define (new-def-procedure subasts id refs type value params)
 149   (multi-link-parent!
 150    subasts
 151    (make-def-procedure #f subasts id refs type value params #f (new-empty-set))))
 152
 153
 154 (define-type-of-ast expr
 155   extender: define-type-of-expr
 156   type)
 157
 158 (define-type-of-expr literal
 159   val)
 160 (define (new-literal type val)
 161   (make-literal #f '() type val))
 162
 163 (define-type-of-expr ref
 164   def-var)
 165 (define (new-ref type def)
 166   (make-ref #f '() type def))
 167
 168 (define-type-of-expr oper
 169   op)
 170 (define (new-oper subasts type op)
 171   (multi-link-parent!
 172    subasts
 173    (make-oper #f subasts type op)))
 174
 175 (define-type-of-expr call
 176   (def-proc unprintable:))
 177 (define (new-call subasts type proc-def)
 178   (multi-link-parent!
 179    subasts
 180    (make-call #f subasts type proc-def)))
 181
 182 (define-type-of-ast block
 183   name) ; blocks that begin with a label have a name, the other have #f
 184 (define (new-block subasts)
 185   (multi-link-parent!
 186    subasts
 187    (make-block #f subasts #f)))
 188 (define (new-named-block name subasts)
 189   (multi-link-parent!
 190    subasts
 191    (make-block #f subasts name)))
 192
 193 (define-type-of-ast if)
 194 (define (new-if subasts)
 195   (multi-link-parent!
 196    subasts
 197    (make-if #f subasts)))
 198
 199 (define-type-of-ast switch)
 200 (define (new-switch subasts)
 201   (multi-link-parent!
 202    subasts
 203    (make-switch #f subasts)))
 204
 205 (define-type-of-ast while)
 206 (define (new-while subasts)
 207   (multi-link-parent!
 208    subasts
 209    (make-while #f subasts)))
 210
 211 (define-type-of-ast do-while)
 212 (define (new-do-while subasts)
 213   (multi-link-parent!
 214    subasts
 215    (make-do-while #f subasts)))
 216
 217 (define-type-of-ast for)
 218 (define (new-for subasts)
 219   (multi-link-parent!
 220    subasts
 221    (make-for #f subasts)))
 222
 223 (define-type-of-ast return)
 224 (define (new-return subasts)
 225   (multi-link-parent!
 226    subasts
 227    (make-return #f subasts)))
 228
 229 (define-type-of-ast break)
 230 (define (new-break)
 231   (make-break #f '()))
 232
 233 (define-type-of-ast continue)
 234 (define (new-continue)
 235   (make-continue #f '()))
 236
 237 (define-type-of-ast goto)
 238 (define (new-goto label)
 239   (make-goto #f (list label)))
 240
 241 (define-type-of-ast program)
 242 (define (new-program subasts) ;; TODO add support for main
 243   (multi-link-parent!
 244    subasts
 245    (make-program #f subasts)))
 246
 247 (define-type op
 248   extender: define-type-of-op
 249   (six-id unprintable:)
 250   id
 251   unprintable:
 252   type-rule
 253   constant-fold
 254   code-gen)
 255
 256 (define-type-of-op op1)
 257 (define-type-of-op op2)
 258 (define-type-of-op op3)