configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.62)
   4 LT_PREREQ(2.4)
   5
   6 AC_INIT(SoX, 14.4.3git, sox-devel@lists.sourceforge.net)
   7
   8 dnl Increase version when binary compatibility with previous version is broken
   9 SHLIB_VERSION=3:0:0
  10 AC_SUBST(SHLIB_VERSION)
  11
  12 AC_CONFIG_MACRO_DIR([m4])
  13 AC_CONFIG_SRCDIR(sox.1)
  14 AC_CONFIG_HEADERS([src/soxconfig.h])
  15
  16 AM_INIT_AUTOMAKE([subdir-objects])
  17 AM_SILENT_RULES([yes])
  18
  19 LT_INIT([win32-dll])
  20
  21 AC_ARG_WITH(distro,
  22     AS_HELP_STRING([--with-distro=name], [Provide distribution name]),
  23     AC_DEFINE_UNQUOTED(DISTRO, ["$with_distro"], [Distribution name]))
  24
  25 dnl Checks for programs.
  26 AC_PROG_CC
  27 AM_PROG_CC_C_O
  28 AC_PROG_INSTALL
  29 AC_PROG_LN_S
  30
  31 PKG_PROG_PKG_CONFIG
  32 PKG_INSTALLDIR
  33
  34 AX_APPEND_COMPILE_FLAGS([-fstack-protector-strong])
  35 AX_APPEND_COMPILE_FLAGS([-Wall -Wmissing-prototypes -Wstrict-prototypes])
  36 AX_APPEND_LINK_FLAGS([-Wl,--as-needed])
  37
  38 dnl Check for system dependent features.
  39 AC_C_BIGENDIAN
  40 AC_C_INLINE
  41
  42 dnl Checks for header files.
  43 AC_HEADER_STDC
  44 AC_CHECK_HEADERS(fcntl.h unistd.h byteswap.h sys/ioctl.h sys/stat.h sys/time.h sys/timeb.h sys/types.h sys/utsname.h termios.h glob.h fenv.h)
  45
  46 dnl Checks for library functions.
  47 AC_CHECK_FUNCS(strcasecmp strdup popen vsnprintf gettimeofday mkstemp fmemopen sigaction)
  48
  49 dnl Check if math library is needed.
  50 AC_SEARCH_LIBS([pow], [m])
  51 AC_SEARCH_LIBS([lrint], [m])
  52 AC_CHECK_FUNCS([lrint])
  53
  54 dnl Large File Support
  55 AC_SYS_LARGEFILE
  56 AC_FUNC_FSEEKO
  57
  58 dnl Check for OpenMP
  59 AC_OPENMP
  60 CFLAGS="$CFLAGS $OPENMP_CFLAGS"
  61
  62 if test "$ac_cv_header_glob_h" != yes; then
  63     AC_CHECK_FUNC([FindFirstFileA], [
  64         AC_DEFINE([HAVE_GLOB_H], [1], [Define if glob.h exists])
  65         HAVE_WIN32_GLOB=yes])
  66 fi
  67 AM_CONDITIONAL(HAVE_WIN32_GLOB, test "$HAVE_WIN32_GLOB" = yes)
  68
  69 AC_ARG_WITH(dyn-default,AS_HELP_STRING([--with-dyn-default],[Default to loading optional formats dynamically]),opt_default=dyn,opt_default=yes)
  70
  71 AC_ARG_WITH(libltdl,
  72     AS_HELP_STRING([--without-libltdl],
  73         [Don't try to use libltdl for external dynamic library support]),
  74     with_libltdl=$withval, with_libltdl=default)
  75
  76 if test "$with_libltdl" = "default"; then
  77     dnl Default to no libltdl support when building only static libraries
  78     if test "$enable_shared" != "no"; then
  79         using_libltdl=yes
  80     else
  81         using_libltdl=no
  82     fi
  83     with_libltdl="yes"
  84 else
  85     using_libltdl=$with_libltdl
  86 fi
  87
  88 dnl Check if ltdl should be enabled.
  89 if test "$using_libltdl" != "no"; then
  90     AC_CHECK_HEADERS(ltdl.h,
  91                      AC_CHECK_LIB(ltdl, lt_dlinit, LIBLTDL="$LIBLTDL -lltdl",
  92                                   using_libltdl=no), using_libltdl=no)
  93 fi
  94 if test "$using_libltdl" = yes; then
  95   AC_DEFINE([HAVE_LIBLTDL], 1, [Define to 1 if you have libltdl])
  96 fi
  97 AM_CONDITIONAL(HAVE_LIBLTDL, test x$using_libltdl = xyes)
  98 AC_SUBST(LIBLTDL)
  99
 100
 101 dnl Check for magic library
 102 AC_ARG_WITH(magic,
 103     AS_HELP_STRING([--without-magic],
 104         [Don't try to use magic]))
 105 using_magic=no
 106 if test "$with_magic" != "no"; then
 107     using_magic=yes
 108     AC_CHECK_HEADER(magic.h,
 109         [AC_CHECK_LIB(magic, magic_open, MAGIC_LIBS="-lmagic",using_magic=no)],
 110         using_magic=no)
 111     if test "$with_magic" = "yes" -a "$using_magic" = "no"; then
 112         AC_MSG_FAILURE([cannot find magic])
 113     fi
 114 fi
 115 if test "$using_magic" = yes; then
 116    AC_DEFINE(HAVE_MAGIC, 1, [Define to 1 if you have magic.])
 117 fi
 118 AM_CONDITIONAL(HAVE_MAGIC, test x$using_magic = xyes)
 119 AC_SUBST(MAGIC_LIBS)
 120
 121
 122
 123 dnl Check for png libraries
 124 AC_ARG_WITH(png,
 125     AS_HELP_STRING([--without-png],
 126         [Don't try to use png]))
 127 using_png=no
 128 if test "$with_png" != "no"; then
 129     AC_CHECK_HEADERS(png.h libpng/png.h,using_png=yes)
 130     if test "$using_png" = "yes"; then
 131         AC_CHECK_LIB(png, png_set_rows, PNG_LIBS="$PNG_LIBS -lpng -lz",
 132                      [AC_CHECK_LIB(png12, png_set_rows,
 133                       PNG_LIBS="$PNG_LIBS -lpng12 -lz",
 134                       using_png=no, -lz)], -lz)
 135     fi
 136     if test "$with_png" = "yes" -a "$using_png" = "no"; then
 137         AC_MSG_FAILURE([cannot find png])
 138     fi
 139 fi
 140 if test "$using_png" = yes; then
 141    AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have PNG.])
 142 fi
 143 AM_CONDITIONAL(HAVE_PNG, test x$using_png = xyes)
 144 AC_SUBST(PNG_LIBS)
 145
 146
 147
 148 dnl Test for LADSPA
 149 AC_ARG_WITH(ladspa,
 150     AS_HELP_STRING([--without-ladspa], [Don't try to use LADSPA]))
 151 using_ladspa=no
 152 if test "$with_ladspa" != "no" -a "$using_libltdl" = "yes"; then
 153     using_ladspa=yes
 154     AC_DEFINE(HAVE_LADSPA_H, 1, [1 if should enable LADSPA])
 155 fi
 156 LADSPA_PATH=${libdir}/ladspa
 157 AC_ARG_WITH(ladspa-path,
 158     AS_HELP_STRING([--with-ladspa-path], [Default search path for LADSPA plugins]))
 159 AC_SUBST(LADSPA_PATH)
 160
 161
 162
 163 dnl Check for MAD libraries
 164 AC_ARG_WITH(mad,
 165     AS_HELP_STRING([--without-mad],
 166         [Don't try to use MAD (MP3 Audio Decoder)]))
 167 using_mad=no
 168 if test "$with_mad" != "no"; then
 169     using_mad=yes
 170     AC_CHECK_HEADERS(mad.h,, using_mad=no)
 171     AC_MSG_CHECKING([whether to dlopen mad])
 172     AC_ARG_ENABLE(dl_mad,
 173       AS_HELP_STRING([--enable-dl-mad], [Dlopen mad instead of linking in.]),
 174       enable_dl_mad=$enableval, enable_dl_mad=no)
 175     AC_MSG_RESULT($enable_dl_mad)
 176     if test "x$using_libltdl" = "xyes" -a "x$enable_dl_mad" = "xyes"; then
 177       AC_DEFINE(DL_MAD, 1, [Define to dlopen() mad.])
 178     else
 179       enable_dl_mad="no"
 180       AC_CHECK_LIB(mad, mad_stream_buffer, MP3_LIBS="$MP3_LIBS -lmad",using_mad=no)
 181       if test "$with_mad" = "yes" -a "$using_mad" = "no"; then
 182         AC_MSG_FAILURE([cannot find libmad])
 183       fi
 184     fi
 185 fi
 186
 187
 188
 189 dnl Check for id3tag libraries
 190 AC_ARG_WITH(id3tag,
 191     AS_HELP_STRING([--without-id3tag],
 192         [Don't try to use id3tag]))
 193 using_id3tag=no
 194 if test "$with_id3tag" != "no"; then
 195     using_id3tag=yes
 196     AC_CHECK_HEADER(id3tag.h,
 197         [AC_CHECK_LIB(id3tag, id3_file_open, MP3_LIBS="$MP3_LIBS -lid3tag -lz",using_id3tag=no, -lz)],
 198         using_id3tag=no)
 199     if test "$with_id3tag" = "yes" -a "$using_id3tag" = "no"; then
 200         AC_MSG_FAILURE([cannot find id3tag])
 201     fi
 202 fi
 203 if test "$using_id3tag" = yes; then
 204    AC_DEFINE(HAVE_ID3TAG, 1, [Define to 1 if you have id3tag.])
 205 fi
 206 AM_CONDITIONAL(HAVE_ID3TAG, test x$using_id3tag = xyes)
 207
 208
 209
 210 dnl Check for LAME library.
 211 AC_ARG_WITH(lame,
 212     AS_HELP_STRING([--without-lame],
 213         [Don't try to use LAME (LAME Ain't an MP3 Encoder)]))
 214 using_lame=no
 215 if test "$with_lame" != "no"; then
 216     using_lame=yes
 217     AC_MSG_CHECKING([whether to dlopen lame])
 218     AC_ARG_ENABLE(dl_lame,
 219       AS_HELP_STRING([--enable-dl-lame], [Dlopen lame instead of linking in.]),
 220       enable_dl_lame=$enableval, enable_dl_lame=no)
 221     AC_MSG_RESULT($enable_dl_lame)
 222     if test "x$using_libltdl" = "xyes" -a "x$enable_dl_lame" = "xyes"; then
 223       AC_DEFINE(DL_LAME, 1, [Define to dlopen() lame.])
 224     else
 225       enable_dl_lame="no"
 226       AC_CHECK_HEADERS(lame/lame.h,,
 227         [AC_CHECK_HEADERS(lame.h, [], using_lame=no)])
 228       AC_CHECK_LIB(mp3lame, lame_get_lametag_frame, MP3_LIBS="$MP3_LIBS -lmp3lame", using_lame=no)
 229       if test "$with_lame" = "yes" -a "$using_lame" = "no"; then
 230         AC_MSG_FAILURE([cannot find LAME])
 231       fi
 232     fi
 233 fi
 234
 235
 236
 237 dnl Check for Twolame library
 238 AC_ARG_WITH(twolame,
 239     AS_HELP_STRING([--without-twolame],
 240         [Don't try to use Twolame (MP2 Audio Encoder)]))
 241 using_twolame=no
 242 if test "$with_twolame" != "no"; then
 243     using_twolame=yes
 244     AC_CHECK_HEADERS(twolame.h,, using_twolame=no)
 245     AC_MSG_CHECKING([whether to dlopen twolame])
 246     AC_ARG_ENABLE(dl_twolame,
 247       AS_HELP_STRING([--enable-dl-twolame], [Dlopen twolame instead of linking in.]),
 248       enable_dl_twolame=$enableval, enable_dl_twolame=no)
 249     AC_MSG_RESULT($enable_dl_twolame)
 250     if test "x$using_libltdl" = "xyes" -a "x$enable_dl_twolame" = "xyes"; then
 251       AC_DEFINE(DL_TWOLAME, 1, [Define to dlopen() libtwolame.])
 252     else
 253       enable_dl_twolame="no"
 254       AC_CHECK_LIB(twolame, twolame_init, MP3_LIBS="$MP3_LIBS -ltwolame",using_twolame=no)
 255       if test "$with_twolame" = "yes" -a "$using_twolame" = "no"; then
 256         AC_MSG_FAILURE([cannot find libtwolame])
 257       fi
 258     fi
 259 fi
 260
 261 # Check for libgsm
 262 HAVE_LIBGSM=yes
 263 AC_CHECK_HEADERS(gsm/gsm.h, ,
 264     [AC_CHECK_HEADERS(gsm.h, , HAVE_LIBGSM=no)])
 265     AC_CHECK_LIB(gsm, gsm_create, [
 266         AC_DEFINE(HAVE_LIBGSM, 1, [Define if libgsm is available])
 267         LIBGSM_LIBS="$LIBGSM_LIBS -lgsm"], HAVE_LIBGSM=no)
 268 AC_SUBST(LIBGSM_LIBS)
 269
 270
 271
 272 # Check for liblpc10
 273 found_liblpc10=yes
 274 AC_CHECK_HEADERS(lpc10.h, ,
 275     [AC_CHECK_HEADERS(lpc10.h, ,found_liblpc10=no)])
 276     AC_CHECK_LIB(lpc10, create_lpc10_encoder_state, LPC10_LIBS="$LPC10_LIBS -llpc10", found_liblpc10=no)
 277 if test "$found_liblpc10" = yes; then
 278     AC_DEFINE(HAVE_LIBLPC10, 1, [Define if you are using an external liblpc10])
 279 else
 280     LPC10_CFLAGS='-I${top_srcdir}/lpc10'
 281     LPC10_LIBS=../lpc10/liblpc10.la
 282 fi
 283 AM_CONDITIONAL(HAVE_LIBLPC10, test x$found_liblpc10 = xyes)
 284
 285
 286
 287 # Check for Ogg Vorbis
 288 AC_OPTIONAL_FORMAT(oggvorbis, OGGVORBIS, [AC_CHECK_HEADER(vorbis/codec.h,
 289   [AC_CHECK_LIB(ogg, ogg_packet_clear, OGGVORBIS_LIBS="$OGGVORBIS_LIBS -logg", using_oggvorbis=no)
 290   AC_CHECK_LIB(vorbis, vorbis_analysis_headerout, OGGVORBIS_LIBS="-lvorbis $OGGVORBIS_LIBS", using_oggvorbis=no, $OGGVORBIS_LIBS)
 291   AC_CHECK_LIB(vorbisfile, ov_clear, OGGVORBIS_LIBS="-lvorbisfile $OGGVORBIS_LIBS", using_oggvorbis=no, $OGGVORBIS_LIBS)
 292   AC_CHECK_LIB(vorbisenc, vorbis_encode_init_vbr, OGGVORBIS_LIBS="-lvorbisenc $OGGVORBIS_LIBS", using_oggvorbis=no, $OGGVORBIS_LIBS)],
 293   using_oggvorbis=no)])
 294
 295 # Check for Opus
 296 AC_OPTIONAL_FORMAT(opus, OPUS,
 297   [PKG_CHECK_MODULES(OPUS, [opusfile], [], using_opus=no)],
 298   using_opus=no)
 299
 300
 301 dnl Check for FLAC library
 302 AC_OPTIONAL_FORMAT(flac, FLAC,
 303     [PKG_CHECK_MODULES([FLAC], [flac], [], [using_flac=no])])
 304
 305
 306 tmp_using_amrwb=no
 307 AC_CHECK_HEADERS(opencore-amrwb/dec_if.h,
 308     [AC_CHECK_LIB(opencore-amrwb, D_IF_init,
 309         [OPENCORE_AMRWB_LIBS="$OPENCORE_AMRWB_LIBS -lopencore-amrwb"; tmp_using_amrwb=$opt_default])])
 310 AC_CHECK_HEADERS(vo-amrwbenc/enc_if.h,
 311     [AC_CHECK_LIB(vo-amrwbenc, E_IF_init,
 312         [VO_AMRWBENC_LIBS="$VO_AMRWBENC_LIBS -lvo-amrwbenc"; tmp_using_amrwb=$opt_default])])
 313 AC_ARG_ENABLE(dl_opencore_amrwb,
 314               AS_HELP_STRING([--enable-dl-opencore-amrwb],
 315                              [Dlopen opencore-amrbw instead of linking in.]))
 316 AC_ARG_ENABLE(dl_vo_amrwbenc,
 317               AS_HELP_STRING([--enable-dl-vo-amrwbenc],
 318                              [Dlopen vo-amrbwenc instead of linking in.]))
 319 if test "$using_libltdl" != "yes"; then
 320   enable_dl_opencore_amrwb=no
 321   enable_dl_vo_amrwbenc=no
 322 fi
 323 if test "$enable_dl_opencore_amrwb" = "yes"; then
 324   AC_DEFINE(DL_OPENCORE_AMRWB, 1, [Define to dlopen() opencore-amrwb.])
 325 else
 326   AMRWB_LIBS="$AMRWB_LIBS $OPENCORE_AMRWB_LIBS"
 327 fi
 328 if test "$enable_dl_vo_amrwbenc" = "yes"; then
 329   AC_DEFINE(DL_VO_AMRWBENC, 1, [Define to dlopen() vo-amrwbenc.])
 330 else
 331   AMRWB_LIBS="$AMRWB_LIBS $VO_AMRWBENC_LIBS"
 332 fi
 333 AC_OPTIONAL_FORMAT(amrwb, AMRWB, [using_amrwb=$tmp_using_amrwb])
 334
 335 dnl When enable_dl_amrnb, do not let add libraries to be linked in
 336 dnl since they will be dlopen()'ed instead.
 337 ac_sox_save_AMRNB_LIBS="$AMRNB_LIBS"
 338 tmp_using_amrnb=$opt_default
 339 AC_CHECK_HEADERS(opencore-amrnb/interf_dec.h,
 340                  [AC_CHECK_LIB(opencore-amrnb, Decoder_Interface_init,
 341                   AMRNB_LIBS="$AMRNB_LIBS -lopencore-amrnb", tmp_using_amrnb=no)],
 342                   [tmp_using_amrnb=no])
 343 AC_ARG_ENABLE(dl_opencore_amrnb,
 344               AS_HELP_STRING([--enable-dl-opencore-amrnb],
 345                              [Dlopen opencore-amrnb instead of linking in.]))
 346 if test "$using_libltdl" = "yes" -a "$enable_dl_opencore_amrnb" = "yes"; then
 347   AC_DEFINE(DL_OPENCORE_AMRNB, 1, [Define to dlopen() opencore-amrnb.])
 348   dnl When enable_dl_amrnb, do not let SOX_PATH_AMRNB add libraries
 349   dnl to be linked in (since they will be dlopen()'ed instead).
 350   AMRNB_LIBS="$ac_sox_save_AMRNB_LIBS"
 351   dnl Force to using regardless if headers or libraries were found.
 352   tmp_using_amrnb=yes
 353 else
 354   enable_dl_opencore_amrnb="no"
 355 fi
 356 AC_OPTIONAL_FORMAT(amrnb, AMRNB, [using_amrnb=$tmp_using_amrnb])
 357
 358
 359 AC_OPTIONAL_FORMAT(wavpack, WAVPACK, [AC_CHECK_HEADER(wavpack/wavpack.h, [AC_CHECK_LIB(wavpack, WavpackGetSampleRate, WAVPACK_LIBS="$WAVPACK_LIBS -lwavpack",using_wavpack=no)], using_wavpack=no)])
 360
 361
 362
 363 AC_OPTIONAL_FORMAT(sndio, SNDIO, [AC_CHECK_HEADER(sndio.h, [AC_CHECK_LIB(sndio, sio_open, SNDIO_LIBS="$SNDIO_LIBS -lsndio",using_sndio=no)], using_sndio=no)])
 364
 365
 366
 367 AC_OPTIONAL_FORMAT(coreaudio, COREAUDIO, [AC_CHECK_HEADER(CoreAudio/CoreAudio.h, [COREAUDIO_LIBS="$COREAUDIO_LIBS -Wl,-framework,CoreAudio"], using_coreaudio=no)])
 368
 369
 370
 371 AC_OPTIONAL_FORMAT(alsa, ALSA, [AC_CHECK_HEADER(alsa/asoundlib.h, [AC_CHECK_LIB(asound, snd_pcm_open, ALSA_LIBS="$ALSA_LIBS -lasound",using_alsa=no)], using_alsa=no)])
 372
 373
 374
 375 AC_OPTIONAL_FORMAT(ao, AO, [AC_CHECK_HEADER(ao/ao.h, [AC_CHECK_LIB(ao, ao_play, AO_LIBS="$AO_LIBS -lao",using_ao=no)], using_ao=no)])
 376
 377
 378
 379 AC_OPTIONAL_FORMAT(pulseaudio, PULSEAUDIO, [AC_CHECK_HEADER(pulse/simple.h, [AC_CHECK_LIB(pulse, pa_simple_new, PULSEAUDIO_LIBS="$PULSEAUDIO_LIBS -lpulse -lpulse-simple",using_pulseaudio=no,"-lpulse-simple")], using_pulseaudio=no)])
 380
 381
 382 AC_OPTIONAL_FORMAT(waveaudio, WAVEAUDIO, [AC_CHECK_HEADER(mmsystem.h, [WAVEAUDIO_LIBS="$WAVEAUDIO_LIBS -lwinmm"], using_waveaudio=no, [[#include <windows.h>]])])
 383
 384 dnl When enable_dl_sndfile, do not let SOX_PATH_SNDFILE add libraries
 385 dnl to be linked in (since they will be dlopen()'ed instead).
 386 ac_sox_save_SNDFILE_LIBS="$LIBSNDFILE_LIBS"
 387 SOX_PATH_SNDFILE(tmp_using_sndfile=$opt_default, tmp_using_sndfile=no)
 388 AC_ARG_ENABLE(dl_sndfile,
 389               AS_HELP_STRING([--enable-dl-sndfile],
 390                              [Dlopen sndfile instead of linking in.]),
 391                              enable_dl_sndfile=$enableval, enable_dl_sndfile=no)
 392 if test "x$tmp_using_sndfile" = "xyes"; then
 393   if test "x$using_libltdl" = "xyes" -a "x$enable_dl_sndfile" = "xyes"; then
 394     AC_DEFINE(DL_LIBSNDFILE, 1, [Define to dlopen() sndfile.])
 395     dnl When enable_dl_sndfile, do not let SOX_PATH_SNDFILE add libraries
 396     dnl to be linked in (since they will be dlopen()'ed instead).
 397     LIBSNDFILE_LIBS="$ac_sox_save_SNDFILE_LIBS"
 398   else
 399     enable_dl_sndfile="no"
 400   fi
 401 fi
 402 AC_OPTIONAL_FORMAT(sndfile, SNDFILE, [using_sndfile=$tmp_using_sndfile])
 403
 404
 405
 406 AC_OPTIONAL_FORMAT(oss, OSS, [AC_CHECK_HEADERS(sys/soundcard.h,, using_oss=no)])
 407
 408
 409
 410 AC_OPTIONAL_FORMAT(sunaudio, SUNAUDIO, [AC_CHECK_HEADERS(sys/audioio.h,,
 411       [AC_CHECK_HEADERS(sun/audioio.h,, using_sunaudio=no)])])
 412
 413
 414
 415 # MP2/MP3 format depends on libmad || LAME || twolame
 416 AC_OPTIONAL_FORMAT(mp3, MP3, [
 417   if test "$using_mad" != yes -a "$using_lame" != yes -a "$using_twolame" != yes; then
 418     using_mp3=no
 419   fi])
 420
 421
 422
 423 # GSM format depends on libgsm
 424 AC_OPTIONAL_FORMAT(gsm, GSM, [using_gsm=$HAVE_LIBGSM])
 425
 426
 427
 428 # LPC10 format depends on liblpc10
 429 # No need to check; LPC10 is always found
 430 AC_OPTIONAL_FORMAT(lpc10, LPC10)
 431
 432
 433
 434 dnl Check if we want to disable all symlinks
 435 AC_MSG_CHECKING([whether to enable symlinks])
 436 AC_ARG_ENABLE(symlinks,
 437     AS_HELP_STRING([--disable-symlinks], [Don't make any symlinks to sox.]),,enable_symlinks=yes)
 438 AC_MSG_RESULT($enable_symlinks)
 439
 440 if test "$enable_symlinks" = "yes"; then
 441   SYMLINKS=soxi
 442   if test "" \
 443       -o "$using_alsa" = yes \
 444       -o "$using_ao" = yes \
 445       -o "$using_coreaudio" = yes \
 446       -o "$using_oss" = yes \
 447       -o "$using_pulseaudio" = yes \
 448       -o "$using_sndio" = yes \
 449       -o "$using_sunaudio" = yes \
 450       -o "$using_waveaudio" = yes \
 451     ; then
 452     SYMLINKS="$SYMLINKS play rec"
 453   fi
 454 fi
 455 AC_SUBST(SYMLINKS)
 456
 457 AM_CONDITIONAL(STATIC_LIBSOX_ONLY, test "$enable_shared" = "no" -a "$enable_static" = "yes")
 458
 459 dnl Generate output files.
 460 AC_CONFIG_FILES(Makefile src/Makefile lpc10/Makefile sox.pc)
 461 AC_OUTPUT
 462
 463 if test "$using_lpc10" != "no"; then
 464   if test "$found_liblpc10" = "yes"; then
 465     lpc10_option="(external)"
 466   else
 467     lpc10_option="(in-tree)"
 468   fi
 469 fi
 470
 471 # Report configuration.
 472 echo
 473 echo "BUILD OPTIONS"
 474 echo "Distro name ...............${with_distro:-unspecified}"
 475 echo "Dynamic loading support....$using_libltdl"
 476 echo "Pkg-config location........$pkgconfigdir"
 477 echo "Symlinks enabled...........${SYMLINKS:-no}"
 478 echo
 479 echo "OPTIONAL DEVICE DRIVERS"
 480 echo "ao (Xiph)..................$using_ao"
 481 echo "alsa (Linux)...............$using_alsa"
 482 echo "coreaudio (Mac OS X).......$using_coreaudio"
 483 echo "sndio (OpenBSD)............$using_sndio"
 484 echo "oss........................$using_oss"
 485 echo "pulseaudio.................$using_pulseaudio"
 486 echo "sunaudio...................$using_sunaudio"
 487 echo "waveaudio (MS-Windows).....$using_waveaudio"
 488 echo
 489 echo "OPTIONAL FILE FORMATS"
 490 echo "amrnb......................$using_amrnb"
 491 if test "x$using_amrnb" = "xyes"; then
 492 echo " dlopen amrnb..............${enable_dl_opencore_amrnb:-no}"
 493 fi
 494 echo "amrwb......................$using_amrwb"
 495 if test "x$using_amrwb" = "xyes"; then
 496 echo " dlopen opencore-amrwb.....${enable_dl_opencore_amrwb:-no}"
 497 echo " dlopen vo-amrwbenc........${enable_dl_vo_amrwbenc:-no}"
 498 fi
 499 echo "flac.......................$using_flac"
 500 echo "gsm........................$using_gsm"
 501 echo "lpc10......................$using_lpc10 $lpc10_option"
 502 echo "mp2/mp3....................$using_mp3"
 503 echo " id3tag....................$using_id3tag"
 504 echo " lame......................$using_lame"
 505 if test "x$using_lame" = "xyes"; then
 506 echo " dlopen lame...............$enable_dl_lame"
 507 fi
 508 echo " mad.......................$using_mad"
 509 if test "x$using_mad" = "xyes"; then
 510 echo " dlopen mad................$enable_dl_mad"
 511 fi
 512 echo " twolame...................$using_twolame"
 513 if test "x$using_twolame" = "xyes"; then
 514 echo " dlopen twolame............$enable_dl_twolame"
 515 fi
 516 echo "oggvorbis..................$using_oggvorbis"
 517 echo "opus.......................$using_opus"
 518 echo "sndfile....................$using_sndfile"
 519 if test "x$using_sndfile" = "xyes"; then
 520 echo " dlopen sndfile............$enable_dl_sndfile"
 521 fi
 522 echo "wavpack....................$using_wavpack"
 523 echo
 524 echo "OTHER OPTIONS"
 525 echo "ladspa effects.............$using_ladspa"
 526 echo "magic support..............$using_magic"
 527 echo "png support................$using_png"
 528 if test "x$OPENMP_CFLAGS" = "x"; then
 529 echo "OpenMP support.............no"
 530 else
 531 echo "OpenMP support.............yes, $OPENMP_CFLAGS"
 532 fi
 533 echo
 534 echo "Configure finished.  Do 'make -s && make install' to compile and install SoX."
 535 echo