configure.ac

   1 dnl Process with autoconf to create a configure script  -*- Autoconf -*-
   2 AC_PREREQ(2.69)
   3
   4 AC_INIT([Splint], [3.1.2a], [splint-bug@splint.org], [splint], [http://www.splint.org])
   5
   6 AC_COPYRIGHT([
   7 Copyright (C) 2001-2007 University of Virginia,
   8         Massachusetts Institute of Technology
   9
  10 Copyright (C) 2016-2017 Mihail Groza
  11 ])
  12
  13 dnl This MUST precede any other macro
  14 AC_CONFIG_AUX_DIR([config])
  15
  16 AM_INIT_AUTOMAKE([-Wall -Werror foreign])
  17 AM_SILENT_RULES([yes])
  18
  19 dnl Set up the source directory
  20 AC_CONFIG_SRCDIR([src/lclinit.c])
  21 dnl Set up the configuration header
  22 AC_CONFIG_HEADERS([config.h:config.h.in])
  23
  24 dnl Prepare for Splint processing of config.h
  25 AH_TOP([/*@ -macroconstdecl@*/])
  26 AH_BOTTOM([/*@ =macroconstdecl@*/])
  27
  28 dnl Checks for programs.
  29 AC_PROG_CC
  30 AC_PROG_CPP
  31 AM_PROG_LEX
  32 AC_PROG_YACC
  33
  34 AC_PROG_INSTALL
  35 AC_PROG_GREP
  36 AC_PROG_SED
  37 AC_CHECK_PROG(RM, rm, rm, rm-is-missing)
  38 AC_CHECK_PROG(CAT, cat, cat, cat-is-missing)
  39 AC_CHECK_PROG(DIFF, diff, diff, diff-is-missing)
  40
  41
  42 # C preprocessor options
  43 AC_ARG_WITH([systemdirs],
  44             [AS_HELP_STRING([--with-systemdirs],
  45                             [list of default system directories @<:@default=/usr/include@:>@.])],
  46             [with_systemdirs=$withval], [with_systemdirs=/usr/include])
  47 AC_DEFINE_UNQUOTED(DEFAULT_SYSTEMDIRS, "$with_systemdirs",
  48             [The list of preprocessor's default system include directories])
  49
  50 AC_ARG_WITH([predefines],
  51             [AS_HELP_STRING([--with-predefines],
  52                             [list of implicit preprocessor defines; set them as
  53                              if on the command line, e.g. "-DFOO=bar -DBAZ"
  54                               @<:@default=""@:>@.])],
  55             [with_predefines=$withval], [with_predefines=""])
  56 AC_DEFINE_UNQUOTED(CPP_PREDEFINES, "$with_predefines",
  57             [The list of implicit preprocessor defines])
  58
  59
  60 AC_DEFINE(DEFAULT_LARCHDIR, "lib",
  61           [The directory where Splint's LARCH support files live])
  62 AC_DEFINE(DEFAULT_LCLDIR, "imports",
  63           [The directory where Splint's LCL support files live])
  64
  65
  66 AC_DEFINE_UNQUOTED(COMPILE_INFO,
  67                    "Compiled using \"$CC $CFLAGS\" on `uname -a` by `whoami`",
  68                    [String describing who compiled this binary and how])
  69
  70 AC_CONFIG_FILES([
  71                  Makefile
  72                  src/Makefile
  73                  lib/Makefile
  74                  imports/Makefile
  75                  doc/Makefile
  76                  ])
  77 AC_OUTPUT
  78