configure.ac

   1 #
   2 # The build process allows for using a cross-compiler.  But the default
   3 # action is to target the same platform that we are running on.  The
   4 # configure script needs to discover the following properties of the
   5 # build and target systems:
   6 #
   7 #    srcdir
   8 #
   9 #        The is the name of the directory that contains the
  10 #        "configure" shell script.  All source files are
  11 #        located relative to this directory.
  12 #
  13 #    bindir
  14 #
  15 #        The name of the directory where executables should be
  16 #        written by the "install" target of the makefile.
  17 #
  18 #    program_prefix
  19 #
  20 #        Add this prefix to the names of all executables that run
  21 #        on the target machine.  Default: ""
  22 #
  23 #    ENABLE_SHARED
  24 #
  25 #        True if shared libraries should be generated.
  26 #
  27 #    BUILD_CC
  28 #
  29 #        The name of a command that is used to convert C
  30 #        source files into executables that run on the build
  31 #        platform.
  32 #
  33 #    BUILD_CFLAGS
  34 #
  35 #        Switches that the build compiler needs in order to construct
  36 #        command-line programs.
  37 #
  38 #    BUILD_LIBS
  39 #
  40 #        Libraries that the build compiler needs in order to construct
  41 #        command-line programs.
  42 #
  43 #    BUILD_EXEEXT
  44 #
  45 #        The filename extension for executables on the build
  46 #        platform.  "" for Unix and ".exe" for Windows.
  47 #
  48 #    TCL_*
  49 #
  50 #        Lots of values are read in from the tclConfig.sh script,
  51 #        if that script is available.  This values are used for
  52 #        constructing and installing the TCL extension.
  53 #
  54 #    TARGET_READLINE_LIBS
  55 #
  56 #        This is the library directives passed to the target linker
  57 #        that cause the executable to link against the readline library.
  58 #        This might be a switch like "-lreadline" or pathnames of library
  59 #        file like "../../src/libreadline.a".
  60 #
  61 #    TARGET_READLINE_INC
  62 #
  63 #        This variables define the directory that contain header
  64 #        files for the readline library.  If the compiler is able
  65 #        to find <readline.h> on its own, then this can be blank.
  66 #
  67 #    TARGET_EXEEXT
  68 #
  69 #        The filename extension for executables on the
  70 #        target platform.  "" for Unix and ".exe" for windows.
  71 #
  72 # This configure.in file is easy to reuse on other projects.  Just
  73 # change the argument to AC_INIT.  And disable any features that
  74 # you don't need (for example BLT) by erasing or commenting out
  75 # the corresponding code.
  76 #
  77 AC_INIT(sqlcipher, m4_esyscmd([cat VERSION | tr -d '\n']))
  78
  79 dnl Make sure the local VERSION file matches this configure script
  80 sqlite_version_sanity_check=`cat $srcdir/VERSION | tr -d '\n'`
  81 if test "$PACKAGE_VERSION" != "$sqlite_version_sanity_check" ; then
  82 AC_MSG_ERROR([configure script is out of date:
  83  configure \$PACKAGE_VERSION = $PACKAGE_VERSION
  84  top level VERSION file     = $sqlite_version_sanity_check
  85 please regen with autoconf])
  86 fi
  87
  88 #########
  89 # Programs needed
  90 #
  91 LT_INIT
  92 AC_PROG_INSTALL
  93
  94 #########
  95 # Enable large file support (if special flags are necessary)
  96 #
  97 AC_SYS_LARGEFILE
  98
  99 #########
 100 # Check for needed/wanted data types
 101 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, intptr_t, uint8_t,
 102                 uint16_t, uint32_t, uint64_t, uintptr_t])
 103
 104 #########
 105 # Check for needed/wanted headers
 106 AC_CHECK_HEADERS([sys/types.h stdlib.h stdint.h inttypes.h malloc.h])
 107
 108 #########
 109 # Figure out whether or not we have these functions
 110 #
 111 AC_CHECK_FUNCS([fdatasync gmtime_r isnan localtime_r localtime_s malloc_usable_size strchrnul usleep utime pread pread64 pwrite pwrite64])
 112
 113 #########
 114 # By default, we use the amalgamation (this may be changed below...)
 115 #
 116 USE_AMALGAMATION=1
 117
 118 #########
 119 # See whether we can run specific tclsh versions known to work well;
 120 # if not, then we fall back to plain tclsh.
 121 # TODO: try other versions before falling back?
 122 #
 123 AC_CHECK_PROGS(TCLSH_CMD, [tclsh8.7 tclsh8.6 tclsh8.5 tclsh], none)
 124 if test "$TCLSH_CMD" = "none"; then
 125   # If we can't find a local tclsh, then building the amalgamation will fail.
 126   # We act as though --disable-amalgamation has been used.
 127   echo "Warning: can't find tclsh - defaulting to non-amalgamation build."
 128   USE_AMALGAMATION=0
 129   TCLSH_CMD="tclsh"
 130 fi
 131 AC_SUBST(TCLSH_CMD)
 132
 133 AC_ARG_VAR([TCLLIBDIR], [Where to install tcl plugin])
 134 if test "x${TCLLIBDIR+set}" != "xset" ; then
 135   TCLLIBDIR='$(libdir)'
 136   for i in `echo 'puts stdout $auto_path' | ${TCLSH_CMD}` ; do
 137     if test -d $i ; then
 138       TCLLIBDIR=$i
 139       break
 140     fi
 141   done
 142   TCLLIBDIR="${TCLLIBDIR}/sqlite3"
 143 fi
 144
 145 #########
 146 # Set up an appropriate program prefix
 147 #
 148 if test "$program_prefix" = "NONE"; then
 149   program_prefix=""
 150 fi
 151 AC_SUBST(program_prefix)
 152
 153 VERSION=[`cat $srcdir/VERSION | sed 's/^\([0-9]*\.*[0-9]*\).*/\1/'`]
 154 AC_MSG_NOTICE(Version set to $VERSION)
 155 AC_SUBST(VERSION)
 156 RELEASE=`cat $srcdir/VERSION`
 157 AC_MSG_NOTICE(Release set to $RELEASE)
 158 AC_SUBST(RELEASE)
 159
 160 ##########
 161 # Handle --with-wasi-sdk=DIR
 162 #
 163 # This must be early because it changes the toolchain.
 164 #
 165 AC_ARG_WITH(wasi-sdk,
 166 AS_HELP_STRING([--with-wasi-sdk=DIR],
 167        [directory containing the WASI SDK. Triggers cross-compile to WASM.]), with_wasisdk=${withval})
 168 AC_MSG_CHECKING([for WASI SDK directory])
 169 AC_CACHE_VAL(ac_cv_c_wasi_sdk,[
 170   # First check to see if --with-tcl was specified.
 171   if test x"${with_wasi_sdk}" != x ; then
 172     if ! test -d "${with_wasi_sdk}" ; then
 173       AC_MSG_ERROR([${with_wasi_sdk} directory doesn't exist])
 174     fi
 175     AC_MSG_RESULT([${with_wasi_sdk}: using wasi-sdk clang, disabling: tcl, CLI shell, DLL])
 176     use_wasi_sdk=yes
 177   else
 178     use_wasi_sdk=no
 179   fi
 180 ])
 181 if test "${use_wasi_sdk}" = "no" ; then
 182   HAVE_WASI_SDK=""
 183   AC_MSG_RESULT([no])
 184 else
 185   HAVE_WASI_SDK=1
 186 # Changing --host and --target have no effect here except to possibly
 187 # cause confusion. autoconf has finished processing them by this
 188 # point.
 189 #
 190 #  host_alias=wasm32-wasi
 191 #  target=wasm32-wasi
 192 #
 193 # Merely changing CC and LD to the wasi-sdk's is enough to get
 194 # sqlite3.o building in WASM format.
 195   CC="${with_wasi_sdk}/bin/clang"
 196   LD="${with_wasi_sdk}/bin/wasm-ld"
 197   RANLIB="${with_wasi_sdk}/bin/llvm-ranlib"
 198   cross_compiling=yes
 199   enable_threadsafe=no
 200   use_tcl=no
 201   enable_tcl=no
 202   # libtool is apparently hard-coded to use gcc for linking DLLs, so
 203   # we disable the DLL build...
 204   enable_shared=no
 205   AC_MSG_RESULT([yes])
 206 fi
 207 AC_SUBST(HAVE_WASI_SDK)
 208
 209
 210 #########
 211 # Locate a compiler for the build machine.  This compiler should
 212 # generate command-line programs that run on the build machine.
 213 #
 214 if test x"$cross_compiling" = xno; then
 215         BUILD_CC=$CC
 216         BUILD_CFLAGS=$CFLAGS
 217 else
 218         if test "${BUILD_CC+set}" != set; then
 219                 AC_CHECK_PROGS(BUILD_CC, gcc cc cl)
 220         fi
 221         if test "${BUILD_CFLAGS+set}" != set; then
 222                 BUILD_CFLAGS="-g"
 223         fi
 224 fi
 225 AC_SUBST(BUILD_CC)
 226
 227 ##########
 228 # Do we want to support multithreaded use of sqlite
 229 #
 230 AC_ARG_ENABLE(threadsafe,
 231 AS_HELP_STRING([--disable-threadsafe],[Disable mutexing]))
 232 AC_MSG_CHECKING([whether to support threadsafe operation])
 233 if test "$enable_threadsafe" = "no"; then
 234   SQLITE_THREADSAFE=0
 235   AC_MSG_RESULT([no])
 236 else
 237   SQLITE_THREADSAFE=1
 238   AC_MSG_RESULT([yes])
 239 fi
 240 AC_SUBST(SQLITE_THREADSAFE)
 241
 242 if test "$SQLITE_THREADSAFE" = "1"; then
 243   AC_SEARCH_LIBS(pthread_create, pthread)
 244   AC_SEARCH_LIBS(pthread_mutexattr_init, pthread)
 245 fi
 246
 247 ##########
 248 # Which crypto library do we use
 249 #
 250 AC_ARG_WITH([crypto-lib],
 251 AC_HELP_STRING([--with-crypto-lib],[Specify which crypto library to use]),
 252 crypto_lib=$withval)
 253 AC_MSG_CHECKING([for crypto library to use])
 254 if test "$crypto_lib" = "none"; then
 255   AC_MSG_RESULT([none])
 256 else
 257   if test "$crypto_lib" = "commoncrypto"; then
 258     CFLAGS="$CFLAGS -DSQLCIPHER_CRYPTO_CC"
 259     BUILD_CFLAGS="$BUILD_CFLAGS -DSQLCIPHER_CRYPTO_CC"
 260           AC_MSG_RESULT([commoncrypto])
 261   else
 262     if test "$crypto_lib" = "libtomcrypt"; then
 263       CFLAGS="$CFLAGS -DSQLCIPHER_CRYPTO_LIBTOMCRYPT"
 264       BUILD_CFLAGS="$BUILD_CFLAGS -DSQLCIPHER_CRYPTO_LIBTOMCRYPT"
 265       AC_MSG_RESULT([libtomcrypt])
 266       AC_CHECK_LIB([tomcrypt], [register_cipher], ,
 267                    AC_MSG_ERROR([Library crypto not found. Install libtomcrypt!"]))
 268     else
 269       if test "$crypto_lib" = "nss"; then
 270         CFLAGS="$CFLAGS -DSQLCIPHER_CRYPTO_NSS"
 271         BUILD_CFLAGS="$BUILD_CFLAGS -DSQLCIPHER_CRYPTO_NSS"
 272         AC_MSG_RESULT([nss3])
 273         AC_CHECK_LIB([nss3], [PK11_Decrypt], ,
 274                      AC_MSG_ERROR([Library crypto not found. Install nss!"]))
 275       else
 276         CFLAGS="$CFLAGS -DSQLCIPHER_CRYPTO_OPENSSL"
 277         BUILD_CFLAGS="$BUILD_CFLAGS -DSQLCIPHER_CRYPTO_OPENSSL"
 278               AC_MSG_RESULT([openssl])
 279         AC_CHECK_LIB([crypto], [HMAC_Init_ex], ,
 280                      AC_MSG_ERROR([Library crypto not found. Install openssl!"]))
 281       fi
 282     fi
 283   fi
 284 fi
 285
 286 ##########
 287 # Do we want to allow a connection created in one thread to be used
 288 # in another thread.  This does not work on many Linux systems (ex: RedHat 9)
 289 # due to bugs in the threading implementations.  This is thus off by default.
 290 #
 291 AC_ARG_ENABLE(cross-thread-connections,
 292 AC_HELP_STRING([--enable-cross-thread-connections],[Allow connection sharing across threads]),,enable_xthreadconnect=no)
 293 AC_MSG_CHECKING([whether to allow connections to be shared across threads])
 294 if test "$enable_xthreadconnect" = "no"; then
 295   XTHREADCONNECT=''
 296   AC_MSG_RESULT([no])
 297 else
 298   XTHREADCONNECT='-DSQLITE_ALLOW_XTHREAD_CONNECT=1'
 299   AC_MSG_RESULT([yes])
 300 fi
 301 AC_SUBST(XTHREADCONNECT)
 302
 303 ##########
 304 # Do we want to support release
 305 #
 306 AC_ARG_ENABLE(releasemode,
 307 AS_HELP_STRING([--enable-releasemode],[Support libtool link to release mode]),,enable_releasemode=no)
 308 AC_MSG_CHECKING([whether to support shared library linked as release mode or not])
 309 if test "$enable_releasemode" = "no"; then
 310   ALLOWRELEASE=""
 311   AC_MSG_RESULT([no])
 312 else
 313   ALLOWRELEASE="-release `cat $srcdir/VERSION`"
 314   AC_MSG_RESULT([yes])
 315 fi
 316 AC_SUBST(ALLOWRELEASE)
 317
 318 ##########
 319 # Do we want temporary databases in memory
 320 #
 321 AC_ARG_ENABLE(tempstore,
 322 AS_HELP_STRING([--enable-tempstore],[Use an in-ram database for temporary tables (never,no,yes,always)]),,enable_tempstore=no)
 323 AC_MSG_CHECKING([whether to use an in-ram database for temporary tables])
 324 case "$enable_tempstore" in
 325   never )
 326     TEMP_STORE=0
 327     AC_MSG_RESULT([never])
 328   ;;
 329   no )
 330     TEMP_STORE=1
 331     AC_MSG_RESULT([no])
 332   ;;
 333   yes )
 334      TEMP_STORE=2
 335     AC_MSG_RESULT([yes])
 336   ;;
 337   always )
 338      TEMP_STORE=3
 339     AC_MSG_RESULT([always])
 340   ;;
 341   * )
 342     TEMP_STORE=1
 343     AC_MSG_RESULT([no])
 344   ;;
 345 esac
 346
 347 AC_SUBST(TEMP_STORE)
 348
 349 ###########
 350 # Lots of things are different if we are compiling for Windows using
 351 # the CYGWIN environment.  So check for that special case and handle
 352 # things accordingly.
 353 #
 354 AC_MSG_CHECKING([if executables have the .exe suffix])
 355 if test "$config_BUILD_EXEEXT" = ".exe"; then
 356   CYGWIN=yes
 357   AC_MSG_RESULT(yes)
 358 else
 359   AC_MSG_RESULT(unknown)
 360 fi
 361 if test "$CYGWIN" != "yes"; then
 362   m4_warn([obsolete],
 363 [AC_CYGWIN is obsolete: use AC_CANONICAL_HOST and check if $host_os
 364 matches *cygwin*])dnl
 365 AC_CANONICAL_HOST
 366 case $host_os in
 367   *cygwin* ) CYGWIN=yes;;
 368          * ) CYGWIN=no;;
 369 esac
 370
 371 fi
 372 if test "$CYGWIN" = "yes"; then
 373   BUILD_EXEEXT=.exe
 374 else
 375   BUILD_EXEEXT=$EXEEXT
 376 fi
 377 if test x"$cross_compiling" = xno; then
 378   TARGET_EXEEXT=$BUILD_EXEEXT
 379 else
 380   TARGET_EXEEXT=$config_TARGET_EXEEXT
 381 fi
 382 if test "$TARGET_EXEEXT" = ".exe"; then
 383   SQLITE_OS_UNIX=0
 384   SQLITE_OS_WIN=1
 385   CFLAGS="$CFLAGS -DSQLITE_OS_WIN=1"
 386 else
 387   SQLITE_OS_UNIX=1
 388   SQLITE_OS_WIN=0
 389   CFLAGS="$CFLAGS -DSQLITE_OS_UNIX=1"
 390 fi
 391
 392 AC_SUBST(BUILD_EXEEXT)
 393 AC_SUBST(SQLITE_OS_UNIX)
 394 AC_SUBST(SQLITE_OS_WIN)
 395 AC_SUBST(TARGET_EXEEXT)
 396
 397 ##########
 398 # Figure out all the parameters needed to compile against Tcl.
 399 #
 400 # This code is derived from the SC_PATH_TCLCONFIG and SC_LOAD_TCLCONFIG
 401 # macros in the in the tcl.m4 file of the standard TCL distribution.
 402 # Those macros could not be used directly since we have to make some
 403 # minor changes to accomodate systems that do not have TCL installed.
 404 #
 405 AC_ARG_ENABLE(tcl, AS_HELP_STRING([--disable-tcl],[do not build TCL extension]),
 406       [use_tcl=$enableval],[use_tcl=yes])
 407 if test "${use_tcl}" = "yes" ; then
 408   AC_ARG_WITH(tcl, AS_HELP_STRING([--with-tcl=DIR],[directory containing tcl configuration (tclConfig.sh)]), with_tclconfig=${withval})
 409   AC_MSG_CHECKING([for Tcl configuration])
 410   AC_CACHE_VAL(ac_cv_c_tclconfig,[
 411     # First check to see if --with-tcl was specified.
 412     if test x"${with_tclconfig}" != x ; then
 413       if test -f "${with_tclconfig}/tclConfig.sh" ; then
 414         ac_cv_c_tclconfig=`(cd ${with_tclconfig}; pwd)`
 415       else
 416         AC_MSG_ERROR([${with_tclconfig} directory doesn't contain tclConfig.sh])
 417       fi
 418     fi
 419
 420     # Start autosearch by asking tclsh
 421     if test x"${ac_cv_c_tclconfig}" = x ; then
 422       if test x"$cross_compiling" = xno; then
 423         for i in `echo 'puts stdout $auto_path' | ${TCLSH_CMD}`
 424         do
 425           if test -f "$i/tclConfig.sh" ; then
 426             ac_cv_c_tclconfig="$i"
 427             break
 428           fi
 429         done
 430       fi
 431     fi
 432
 433     # On ubuntu 14.10, $auto_path on tclsh is not quite correct.
 434     # So try again after applying corrections.
 435     if test x"${ac_cv_c_tclconfig}" = x ; then
 436       if test x"$cross_compiling" = xno; then
 437         for i in `echo 'puts stdout $auto_path' | ${TCLSH_CMD} | sed 's,/tcltk/tcl,/tcl,g'`
 438         do
 439           if test -f "$i/tclConfig.sh" ; then
 440             ac_cv_c_tclconfig="$i"
 441             break
 442           fi
 443         done
 444       fi
 445     fi
 446
 447     # Recent versions of Xcode on Macs hid the tclConfig.sh file
 448     # in a strange place.
 449     if test x"${ac_cv_c_tclconfig}" = x ; then
 450       if test x"$cross_compiling" = xno; then
 451         for i in /Applications/Xcode.app/Contents/Developer/Platforms/MacOSX.platform/Developer/SDKs/MacOSX*.sdk/usr/lib
 452         do
 453           if test -f "$i/tclConfig.sh" ; then
 454             ac_cv_c_tclconfig="$i"
 455             break
 456           fi
 457         done
 458       fi
 459     fi
 460
 461     # then check for a private Tcl installation
 462     if test x"${ac_cv_c_tclconfig}" = x ; then
 463       for i in \
 464             ../tcl \
 465             `ls -dr ../tcl[[8-9]].[[0-9]].[[0-9]]* 2>/dev/null` \
 466             `ls -dr ../tcl[[8-9]].[[0-9]] 2>/dev/null` \
 467             `ls -dr ../tcl[[8-9]].[[0-9]]* 2>/dev/null` \
 468             ../../tcl \
 469             `ls -dr ../../tcl[[8-9]].[[0-9]].[[0-9]]* 2>/dev/null` \
 470             `ls -dr ../../tcl[[8-9]].[[0-9]] 2>/dev/null` \
 471             `ls -dr ../../tcl[[8-9]].[[0-9]]* 2>/dev/null` \
 472             ../../../tcl \
 473             `ls -dr ../../../tcl[[8-9]].[[0-9]].[[0-9]]* 2>/dev/null` \
 474             `ls -dr ../../../tcl[[8-9]].[[0-9]] 2>/dev/null` \
 475             `ls -dr ../../../tcl[[8-9]].[[0-9]]* 2>/dev/null`
 476       do
 477         if test -f "$i/unix/tclConfig.sh" ; then
 478           ac_cv_c_tclconfig=`(cd $i/unix; pwd)`
 479           break
 480         fi
 481       done
 482     fi
 483
 484     # check in a few common install locations
 485     if test x"${ac_cv_c_tclconfig}" = x ; then
 486       for i in \
 487             `ls -d ${libdir} 2>/dev/null` \
 488             `ls -d /usr/local/lib 2>/dev/null` \
 489             `ls -d /usr/contrib/lib 2>/dev/null` \
 490             `ls -d /usr/lib 2>/dev/null`
 491       do
 492         if test -f "$i/tclConfig.sh" ; then
 493            ac_cv_c_tclconfig=`(cd $i; pwd)`
 494            break
 495         fi
 496       done
 497     fi
 498
 499     # check in a few other private locations
 500     if test x"${ac_cv_c_tclconfig}" = x ; then
 501       for i in \
 502          ${srcdir}/../tcl \
 503          `ls -dr ${srcdir}/../tcl[[8-9]].[[0-9]].[[0-9]]* 2>/dev/null` \
 504          `ls -dr ${srcdir}/../tcl[[8-9]].[[0-9]] 2>/dev/null` \
 505          `ls -dr ${srcdir}/../tcl[[8-9]].[[0-9]]* 2>/dev/null`
 506       do
 507         if test -f "$i/unix/tclConfig.sh" ; then
 508           ac_cv_c_tclconfig=`(cd $i/unix; pwd)`
 509           break
 510         fi
 511       done
 512     fi
 513   ])
 514
 515   if test x"${ac_cv_c_tclconfig}" = x ; then
 516     use_tcl=no
 517     AC_MSG_WARN(Can't find Tcl configuration definitions)
 518     AC_MSG_WARN(*** Without Tcl the regression tests cannot be executed ***)
 519     AC_MSG_WARN(*** Consider using --with-tcl=... to define location of Tcl ***)
 520   else
 521     TCL_BIN_DIR=${ac_cv_c_tclconfig}
 522     AC_MSG_RESULT(found $TCL_BIN_DIR/tclConfig.sh)
 523
 524     AC_MSG_CHECKING([for existence of $TCL_BIN_DIR/tclConfig.sh])
 525     if test -f "$TCL_BIN_DIR/tclConfig.sh" ; then
 526       AC_MSG_RESULT([loading])
 527       . $TCL_BIN_DIR/tclConfig.sh
 528     else
 529       AC_MSG_RESULT([file not found])
 530     fi
 531
 532     #
 533     # If the TCL_BIN_DIR is the build directory (not the install directory),
 534     # then set the common variable name to the value of the build variables.
 535     # For example, the variable TCL_LIB_SPEC will be set to the value
 536     # of TCL_BUILD_LIB_SPEC. An extension should make use of TCL_LIB_SPEC
 537     # instead of TCL_BUILD_LIB_SPEC since it will work with both an
 538     # installed and uninstalled version of Tcl.
 539     #
 540
 541     if test -f $TCL_BIN_DIR/Makefile ; then
 542       TCL_LIB_SPEC=${TCL_BUILD_LIB_SPEC}
 543       TCL_STUB_LIB_SPEC=${TCL_BUILD_STUB_LIB_SPEC}
 544       TCL_STUB_LIB_PATH=${TCL_BUILD_STUB_LIB_PATH}
 545     fi
 546
 547     #
 548     # eval is required to do the TCL_DBGX substitution
 549     #
 550
 551     eval "TCL_LIB_FILE=\"${TCL_LIB_FILE}\""
 552     eval "TCL_LIB_FLAG=\"${TCL_LIB_FLAG}\""
 553     eval "TCL_LIB_SPEC=\"${TCL_LIB_SPEC}\""
 554
 555     eval "TCL_STUB_LIB_FILE=\"${TCL_STUB_LIB_FILE}\""
 556     eval "TCL_STUB_LIB_FLAG=\"${TCL_STUB_LIB_FLAG}\""
 557     eval "TCL_STUB_LIB_SPEC=\"${TCL_STUB_LIB_SPEC}\""
 558
 559     AC_SUBST(TCL_VERSION)
 560     AC_SUBST(TCL_BIN_DIR)
 561     AC_SUBST(TCL_SRC_DIR)
 562     AC_SUBST(TCL_INCLUDE_SPEC)
 563
 564     AC_SUBST(TCL_LIB_FILE)
 565     AC_SUBST(TCL_LIB_FLAG)
 566     AC_SUBST(TCL_LIB_SPEC)
 567
 568     AC_SUBST(TCL_STUB_LIB_FILE)
 569     AC_SUBST(TCL_STUB_LIB_FLAG)
 570     AC_SUBST(TCL_STUB_LIB_SPEC)
 571     AC_SUBST(TCL_SHLIB_SUFFIX)
 572   fi
 573 fi
 574 if test "${use_tcl}" = "no" ; then
 575   HAVE_TCL=""
 576 else
 577   HAVE_TCL=1
 578 fi
 579 AC_SUBST(HAVE_TCL)
 580
 581 ##########
 582 # Figure out what C libraries are required to compile programs
 583 # that use "readline()" library.
 584 #
 585 TARGET_READLINE_LIBS=""
 586 TARGET_READLINE_INC=""
 587 TARGET_HAVE_READLINE=0
 588 TARGET_HAVE_EDITLINE=0
 589 AC_ARG_ENABLE([editline],
 590         [AS_HELP_STRING([--enable-editline],[enable BSD editline support])],
 591         [with_editline=$enableval],
 592         [with_editline=auto])
 593 AC_ARG_ENABLE([readline],
 594         [AS_HELP_STRING([--disable-readline],[disable readline support])],
 595         [with_readline=$enableval],
 596         [with_readline=auto])
 597
 598 if test x"$with_editline" != xno; then
 599         sLIBS=$LIBS
 600         LIBS=""
 601         TARGET_HAVE_EDITLINE=1
 602         AC_SEARCH_LIBS(readline,edit,[with_readline=no],[TARGET_HAVE_EDITLINE=0])
 603         TARGET_READLINE_LIBS=$LIBS
 604         LIBS=$sLIBS
 605 fi
 606 if test x"$with_readline" != xno; then
 607         found="yes"
 608
 609         AC_ARG_WITH([readline-lib],
 610                 [AS_HELP_STRING([--with-readline-lib],[specify readline library])],
 611                 [with_readline_lib=$withval],
 612                 [with_readline_lib="auto"])
 613         if test "x$with_readline_lib" = xauto; then
 614                 save_LIBS="$LIBS"
 615                 LIBS=""
 616                 AC_SEARCH_LIBS(tgetent, [readline ncurses curses termcap], [term_LIBS="$LIBS"], [term_LIBS=""])
 617                 AC_CHECK_LIB([readline], [readline], [TARGET_READLINE_LIBS="-lreadline"], [found="no"])
 618                 TARGET_READLINE_LIBS="$TARGET_READLINE_LIBS $term_LIBS"
 619                 LIBS="$save_LIBS"
 620         else
 621                 TARGET_READLINE_LIBS="$with_readline_lib"
 622         fi
 623
 624         AC_ARG_WITH([readline-inc],
 625                 [AS_HELP_STRING([--with-readline-inc],[specify readline include paths])],
 626                 [with_readline_inc=$withval],
 627                 [with_readline_inc="auto"])
 628         if test "x$with_readline_inc" = xauto; then
 629                 AC_CHECK_HEADER(readline.h, [found="yes"], [
 630                         found="no"
 631                         if test "$cross_compiling" != yes; then
 632                                 for dir in /usr /usr/local /usr/local/readline /usr/contrib /mingw; do
 633                                         for subdir in include include/readline; do
 634                                                 AC_CHECK_FILE($dir/$subdir/readline.h, found=yes)
 635                                                 if test "$found" = "yes"; then
 636                                                         TARGET_READLINE_INC="-I$dir/$subdir"
 637                                                         break
 638                                                 fi
 639                                         done
 640                                         test "$found" = "yes" && break
 641                                 done
 642                         fi
 643                 ])
 644         else
 645                 TARGET_READLINE_INC="$with_readline_inc"
 646         fi
 647
 648         if test x"$found" = xno; then
 649                 TARGET_READLINE_LIBS=""
 650                 TARGET_READLINE_INC=""
 651                 TARGET_HAVE_READLINE=0
 652         else
 653                 TARGET_HAVE_READLINE=1
 654         fi
 655 fi
 656
 657 AC_SUBST(TARGET_READLINE_LIBS)
 658 AC_SUBST(TARGET_READLINE_INC)
 659 AC_SUBST(TARGET_HAVE_READLINE)
 660 AC_SUBST(TARGET_HAVE_EDITLINE)
 661
 662 ##########
 663 # Figure out what C libraries are required to compile programs
 664 # that use "fdatasync()" function.
 665 #
 666 AC_SEARCH_LIBS(fdatasync, [rt])
 667
 668 #########
 669 # check for debug enabled
 670 AC_ARG_ENABLE(debug, AS_HELP_STRING([--enable-debug],[enable debugging & verbose explain]))
 671 AC_MSG_CHECKING([build type])
 672 if test "${enable_debug}" = "yes" ; then
 673   TARGET_DEBUG="-DSQLITE_DEBUG=1 -DSQLITE_ENABLE_SELECTTRACE -DSQLITE_ENABLE_WHERETRACE -O0"
 674   AC_MSG_RESULT([debug])
 675 else
 676   TARGET_DEBUG="-DNDEBUG"
 677   AC_MSG_RESULT([release])
 678 fi
 679 AC_SUBST(TARGET_DEBUG)
 680
 681 #########
 682 # See whether we should use the amalgamation to build
 683
 684 AC_ARG_ENABLE(amalgamation, AS_HELP_STRING([--disable-amalgamation],
 685       [Disable the amalgamation and instead build all files separately]))
 686 if test "${enable_amalgamation}" = "no" ; then
 687   USE_AMALGAMATION=0
 688 fi
 689 AC_SUBST(USE_AMALGAMATION)
 690
 691 #########
 692 # By default, amalgamation sqlite3.c will have #line directives.
 693 # This is a build option not shown by ./configure --help
 694 # To control it, use configure option: amalgamation_line_macros=?
 695 # where ? is no to suppress #line directives or yes to create them.
 696 AMALGAMATION_LINE_MACROS=--linemacros=1
 697 AC_ARG_VAR(amalgamation_line_macros,)
 698 AC_SUBST(AMALGAMATION_LINE_MACROS)
 699 if test "${amalgamation_line_macros+set}" = set; then :
 700   enableval=$amalgamation_line_macros;
 701 fi
 702 if test "${amalgamation_line_macros}" = "yes" ; then
 703   AMALGAMATION_LINE_MACROS=--linemacros=1
 704 fi
 705 if test "${amalgamation_line_macros}" = "no" ; then
 706   AMALGAMATION_LINE_MACROS=--linemacros=0
 707 fi
 708
 709 #########
 710 # Look for zlib.  Only needed by extensions and by the sqlite3.exe shell
 711 AC_CHECK_HEADERS(zlib.h)
 712 AC_SEARCH_LIBS(deflate, z, [HAVE_ZLIB="-DSQLITE_HAVE_ZLIB=1"], [HAVE_ZLIB=""])
 713 AC_SUBST(HAVE_ZLIB)
 714
 715 #########
 716 # See whether we should allow loadable extensions
 717 AC_ARG_ENABLE(load-extension, AS_HELP_STRING([--disable-load-extension],
 718       [Disable loading of external extensions]),,[enable_load_extension=yes])
 719 if test "${enable_load_extension}" = "yes" ; then
 720   OPT_FEATURE_FLAGS=""
 721   AC_SEARCH_LIBS(dlopen, dl)
 722 else
 723   OPT_FEATURE_FLAGS="-DSQLITE_OMIT_LOAD_EXTENSION=1"
 724 fi
 725
 726 ##########
 727 # Do we want to support math functions
 728 #
 729 AC_ARG_ENABLE(math,
 730 AS_HELP_STRING([--disable-math],[Disable math functions]))
 731 AC_MSG_CHECKING([whether to support math functions])
 732 if test "$enable_math" = "no"; then
 733   AC_MSG_RESULT([no])
 734 else
 735   AC_MSG_RESULT([yes])
 736   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_MATH_FUNCTIONS"
 737   AC_SEARCH_LIBS(ceil, m)
 738 fi
 739
 740 ##########
 741 # Do we want to support JSON functions
 742 #
 743 AC_ARG_ENABLE(json,
 744 AS_HELP_STRING([--disable-json],[Disable JSON functions]))
 745 AC_MSG_CHECKING([whether to support JSON functions])
 746 if test "$enable_json" = "no"; then
 747   AC_MSG_RESULT([no])
 748   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_OMIT_JSON"
 749 else
 750   AC_MSG_RESULT([yes])
 751 fi
 752
 753 ########
 754 # The --enable-all argument is short-hand to enable
 755 # multiple extensions.
 756 AC_ARG_ENABLE(all, AS_HELP_STRING([--enable-all],
 757       [Enable FTS4, FTS5, Geopoly, RTree, Sessions]))
 758
 759 ##########
 760 # Do we want to support memsys3 and/or memsys5
 761 #
 762 AC_ARG_ENABLE(memsys5,
 763   AS_HELP_STRING([--enable-memsys5],[Enable MEMSYS5]))
 764 AC_MSG_CHECKING([whether to support MEMSYS5])
 765 if test "${enable_memsys5}" = "yes"; then
 766   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_MEMSYS5"
 767   AC_MSG_RESULT([yes])
 768 else
 769   AC_MSG_RESULT([no])
 770 fi
 771 AC_ARG_ENABLE(memsys3,
 772   AS_HELP_STRING([--enable-memsys3],[Enable MEMSYS3]))
 773 AC_MSG_CHECKING([whether to support MEMSYS3])
 774 if test "${enable_memsys3}" = "yes" -a "${enable_memsys5}" = "no"; then
 775   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_MEMSYS3"
 776   AC_MSG_RESULT([yes])
 777 else
 778   AC_MSG_RESULT([no])
 779 fi
 780
 781 #########
 782 # See whether we should enable Full Text Search extensions
 783 AC_ARG_ENABLE(fts3, AS_HELP_STRING([--enable-fts3],
 784       [Enable the FTS3 extension]))
 785 AC_MSG_CHECKING([whether to support FTS3])
 786 if test "${enable_fts3}" = "yes" ; then
 787   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_FTS3"
 788   AC_MSG_RESULT([yes])
 789 else
 790   AC_MSG_RESULT([no])
 791 fi
 792 AC_ARG_ENABLE(fts4, AS_HELP_STRING([--enable-fts4],
 793       [Enable the FTS4 extension]))
 794 AC_MSG_CHECKING([whether to support FTS4])
 795 if test "${enable_fts4}" = "yes" -o "${enable_all}" = "yes" ; then
 796   AC_MSG_RESULT([yes])
 797   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_FTS4"
 798   AC_SEARCH_LIBS([log],[m])
 799 else
 800   AC_MSG_RESULT([no])
 801 fi
 802 AC_ARG_ENABLE(fts5, AS_HELP_STRING([--enable-fts5],
 803       [Enable the FTS5 extension]))
 804 AC_MSG_CHECKING([whether to support FTS5])
 805 if test "${enable_fts5}" = "yes" -o "${enable_all}" = "yes" ; then
 806   AC_MSG_RESULT([yes])
 807   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_FTS5"
 808   AC_SEARCH_LIBS([log],[m])
 809 else
 810   AC_MSG_RESULT([no])
 811 fi
 812
 813 #########
 814 # See whether we should enable the LIMIT clause on UPDATE and DELETE
 815 # statements.
 816 AC_ARG_ENABLE(update-limit, AS_HELP_STRING([--enable-update-limit],
 817       [Enable the UPDATE/DELETE LIMIT clause]))
 818 AC_MSG_CHECKING([whether to support LIMIT on UPDATE and DELETE statements])
 819 if test "${enable_update_limit}" = "yes" ; then
 820   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_UPDATE_DELETE_LIMIT"
 821   AC_MSG_RESULT([yes])
 822 else
 823   AC_MSG_RESULT([no])
 824 fi
 825
 826 #########
 827 # See whether we should enable GEOPOLY
 828 AC_ARG_ENABLE(geopoly, AS_HELP_STRING([--enable-geopoly],
 829       [Enable the GEOPOLY extension]),
 830       [enable_geopoly=yes],[enable_geopoly=no])
 831 AC_MSG_CHECKING([whether to support GEOPOLY])
 832 if test "${enable_geopoly}" = "yes" -o "${enable_all}" = "yes" ; then
 833   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_GEOPOLY"
 834   enable_rtree=yes
 835   AC_MSG_RESULT([yes])
 836 else
 837   AC_MSG_RESULT([no])
 838 fi
 839
 840 #########
 841 # See whether we should enable RTREE
 842 AC_ARG_ENABLE(rtree, AS_HELP_STRING([--enable-rtree],
 843       [Enable the RTREE extension]))
 844 AC_MSG_CHECKING([whether to support RTREE])
 845 if test "${enable_rtree}" = "yes" ; then
 846   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_RTREE"
 847   AC_MSG_RESULT([yes])
 848 else
 849   AC_MSG_RESULT([no])
 850 fi
 851
 852 #########
 853 # See whether we should enable the SESSION extension
 854 AC_ARG_ENABLE(session, AS_HELP_STRING([--enable-session],
 855       [Enable the SESSION extension]))
 856 AC_MSG_CHECKING([whether to support SESSION])
 857 if test "${enable_session}" = "yes" -o "${enable_all}" = "yes" ; then
 858   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_SESSION"
 859   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_PREUPDATE_HOOK"
 860   AC_MSG_RESULT([yes])
 861 else
 862   AC_MSG_RESULT([no])
 863 fi
 864
 865 #########
 866 # attempt to duplicate any OMITS and ENABLES into the ${OPT_FEATURE_FLAGS} parameter
 867 for option in $CFLAGS $CPPFLAGS
 868 do
 869   case $option in
 870     -DSQLITE_OMIT*) OPT_FEATURE_FLAGS="$OPT_FEATURE_FLAGS $option";;
 871     -DSQLITE_ENABLE*) OPT_FEATURE_FLAGS="$OPT_FEATURE_FLAGS $option";;
 872   esac
 873 done
 874 AC_SUBST(OPT_FEATURE_FLAGS)
 875
 876
 877 # attempt to remove any OMITS and ENABLES from the $(CFLAGS) parameter
 878 ac_temp_CFLAGS=""
 879 for option in $CFLAGS
 880 do
 881   case $option in
 882     -DSQLITE_OMIT*) ;;
 883     -DSQLITE_ENABLE*) ;;
 884     *) ac_temp_CFLAGS="$ac_temp_CFLAGS $option";;
 885   esac
 886 done
 887 CFLAGS=$ac_temp_CFLAGS
 888
 889
 890 # attempt to remove any OMITS and ENABLES from the $(CPPFLAGS) parameter
 891 ac_temp_CPPFLAGS=""
 892 for option in $CPPFLAGS
 893 do
 894   case $option in
 895     -DSQLITE_OMIT*) ;;
 896     -DSQLITE_ENABLE*) ;;
 897     *) ac_temp_CPPFLAGS="$ac_temp_CPPFLAGS $option";;
 898   esac
 899 done
 900 CPPFLAGS=$ac_temp_CPPFLAGS
 901
 902
 903 # attempt to remove any OMITS and ENABLES from the $(BUILD_CFLAGS) parameter
 904 ac_temp_BUILD_CFLAGS=""
 905 for option in $BUILD_CFLAGS
 906 do
 907   case $option in
 908     -DSQLITE_OMIT*) ;;
 909     -DSQLITE_ENABLE*) ;;
 910     *) ac_temp_BUILD_CFLAGS="$ac_temp_BUILD_CFLAGS $option";;
 911   esac
 912 done
 913 BUILD_CFLAGS=$ac_temp_BUILD_CFLAGS
 914
 915
 916 #########
 917 # See whether we should use GCOV
 918 AC_ARG_ENABLE(gcov, AS_HELP_STRING([--enable-gcov],
 919       [Enable coverage testing using gcov]))
 920 if test "${use_gcov}" = "yes" ; then
 921   USE_GCOV=1
 922 else
 923   USE_GCOV=0
 924 fi
 925 AC_SUBST(USE_GCOV)
 926
 927 #########
 928 # Enable/disabled amalagamation line macros
 929 ########
 930 AMALGAMATION_LINE_MACROS=--linemacros=0
 931 if test "${amalgamation_line_macros}" = "yes" ; then
 932   AMALGAMATION_LINE_MACROS=--linemacros=1
 933 fi
 934 if test "${amalgamation_line_macros}" = "no" ; then
 935   AMALGAMATION_LINE_MACROS=--linemacros=0
 936 fi
 937 AC_SUBST(AMALGAMATION_LINE_MACROS)
 938
 939 #########
 940 # Output the config header
 941 AC_CONFIG_HEADERS(sqlite_cfg.h)
 942
 943 #########
 944 # Generate the output files.
 945 #
 946 AC_SUBST(BUILD_CFLAGS)
 947 AC_CONFIG_FILES([
 948 Makefile
 949 sqlcipher.pc
 950 ])
 951 AC_OUTPUT