configure.ac

   1 #
   2 # The build process allows for using a cross-compiler.  But the default
   3 # action is to target the same platform that we are running on.  The
   4 # configure script needs to discover the following properties of the
   5 # build and target systems:
   6 #
   7 #    srcdir
   8 #
   9 #        The is the name of the directory that contains the
  10 #        "configure" shell script.  All source files are
  11 #        located relative to this directory.
  12 #
  13 #    bindir
  14 #
  15 #        The name of the directory where executables should be
  16 #        written by the "install" target of the makefile.
  17 #
  18 #    program_prefix
  19 #
  20 #        Add this prefix to the names of all executables that run
  21 #        on the target machine.  Default: ""
  22 #
  23 #    ENABLE_SHARED
  24 #
  25 #        True if shared libraries should be generated.
  26 #
  27 #    BUILD_CC
  28 #
  29 #        The name of a command that is used to convert C
  30 #        source files into executables that run on the build
  31 #        platform.
  32 #
  33 #    BUILD_CFLAGS
  34 #
  35 #        Switches that the build compiler needs in order to construct
  36 #        command-line programs.
  37 #
  38 #    BUILD_LIBS
  39 #
  40 #        Libraries that the build compiler needs in order to construct
  41 #        command-line programs.
  42 #
  43 #    BUILD_EXEEXT
  44 #
  45 #        The filename extension for executables on the build
  46 #        platform.  "" for Unix and ".exe" for Windows.
  47 #
  48 #    TCL_*
  49 #
  50 #        Lots of values are read in from the tclConfig.sh script,
  51 #        if that script is available.  This values are used for
  52 #        constructing and installing the TCL extension.
  53 #
  54 #    TARGET_READLINE_LIBS
  55 #
  56 #        This is the library directives passed to the target linker
  57 #        that cause the executable to link against the readline library.
  58 #        This might be a switch like "-lreadline" or pathnames of library
  59 #        file like "../../src/libreadline.a".
  60 #
  61 #    TARGET_READLINE_INC
  62 #
  63 #        This variables define the directory that contain header
  64 #        files for the readline library.  If the compiler is able
  65 #        to find <readline.h> on its own, then this can be blank.
  66 #
  67 #    TARGET_EXEEXT
  68 #
  69 #        The filename extension for executables on the
  70 #        target platform.  "" for Unix and ".exe" for windows.
  71 #
  72 # This configure.in file is easy to reuse on other projects.  Just
  73 # change the argument to AC_INIT().  And disable any features that
  74 # you don't need (for example BLT) by erasing or commenting out
  75 # the corresponding code.
  76 #
  77 AC_INIT(sqlcipher, m4_esyscmd([cat VERSION | tr -d '\n']))
  78
  79 dnl Make sure the local VERSION file matches this configure script
  80 sqlite_version_sanity_check=`cat $srcdir/VERSION | tr -d '\n'`
  81 if test "$PACKAGE_VERSION" != "$sqlite_version_sanity_check" ; then
  82 AC_MSG_ERROR([configure script is out of date:
  83  configure \$PACKAGE_VERSION = $PACKAGE_VERSION
  84  top level VERSION file     = $sqlite_version_sanity_check
  85 please regen with autoconf])
  86 fi
  87
  88 #########
  89 # Programs needed
  90 #
  91 AC_PROG_LIBTOOL
  92 AC_PROG_INSTALL
  93
  94 #########
  95 # Enable large file support (if special flags are necessary)
  96 #
  97 AC_SYS_LARGEFILE
  98
  99 #########
 100 # Check for needed/wanted data types
 101 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, intptr_t, uint8_t,
 102                 uint16_t, uint32_t, uint64_t, uintptr_t])
 103
 104 #########
 105 # Check for needed/wanted headers
 106 AC_CHECK_HEADERS([sys/types.h stdlib.h stdint.h inttypes.h malloc.h])
 107
 108 #########
 109 # Figure out whether or not we have these functions
 110 #
 111 AC_CHECK_FUNCS([fdatasync gmtime_r isnan localtime_r localtime_s malloc_usable_size strchrnul usleep utime pread pread64 pwrite pwrite64])
 112
 113 #########
 114 # By default, we use the amalgamation (this may be changed below...)
 115 #
 116 USE_AMALGAMATION=1
 117
 118 #########
 119 # See whether we can run specific tclsh versions known to work well;
 120 # if not, then we fall back to plain tclsh.
 121 # TODO: try other versions before falling back?
 122 #
 123 AC_CHECK_PROGS(TCLSH_CMD, [tclsh8.7 tclsh8.6 tclsh8.5 tclsh], none)
 124 if test "$TCLSH_CMD" = "none"; then
 125   # If we can't find a local tclsh, then building the amalgamation will fail.
 126   # We act as though --disable-amalgamation has been used.
 127   echo "Warning: can't find tclsh - defaulting to non-amalgamation build."
 128   USE_AMALGAMATION=0
 129   TCLSH_CMD="tclsh"
 130 fi
 131 AC_SUBST(TCLSH_CMD)
 132
 133 AC_ARG_VAR([TCLLIBDIR], [Where to install tcl plugin])
 134 if test "x${TCLLIBDIR+set}" != "xset" ; then
 135   TCLLIBDIR='$(libdir)'
 136   for i in `echo 'puts stdout $auto_path' | ${TCLSH_CMD}` ; do
 137     if test -d $i ; then
 138       TCLLIBDIR=$i
 139       break
 140     fi
 141   done
 142   TCLLIBDIR="${TCLLIBDIR}/sqlite3"
 143 fi
 144
 145 #########
 146 # Set up an appropriate program prefix
 147 #
 148 if test "$program_prefix" = "NONE"; then
 149   program_prefix=""
 150 fi
 151 AC_SUBST(program_prefix)
 152
 153 VERSION=[`cat $srcdir/VERSION | sed 's/^\([0-9]*\.*[0-9]*\).*/\1/'`]
 154 AC_MSG_NOTICE(Version set to $VERSION)
 155 AC_SUBST(VERSION)
 156 RELEASE=`cat $srcdir/VERSION`
 157 AC_MSG_NOTICE(Release set to $RELEASE)
 158 AC_SUBST(RELEASE)
 159
 160 #########
 161 # Locate a compiler for the build machine.  This compiler should
 162 # generate command-line programs that run on the build machine.
 163 #
 164 if test x"$cross_compiling" = xno; then
 165         BUILD_CC=$CC
 166         BUILD_CFLAGS=$CFLAGS
 167 else
 168         if test "${BUILD_CC+set}" != set; then
 169                 AC_CHECK_PROGS(BUILD_CC, gcc cc cl)
 170         fi
 171         if test "${BUILD_CFLAGS+set}" != set; then
 172                 BUILD_CFLAGS="-g"
 173         fi
 174 fi
 175 AC_SUBST(BUILD_CC)
 176
 177 ##########
 178 # Do we want to support multithreaded use of sqlite
 179 #
 180 AC_ARG_ENABLE(threadsafe,
 181 AC_HELP_STRING([--disable-threadsafe],[Disable mutexing]))
 182 AC_MSG_CHECKING([whether to support threadsafe operation])
 183 if test "$enable_threadsafe" = "no"; then
 184   SQLITE_THREADSAFE=0
 185   AC_MSG_RESULT([no])
 186 else
 187   SQLITE_THREADSAFE=1
 188   AC_MSG_RESULT([yes])
 189 fi
 190 AC_SUBST(SQLITE_THREADSAFE)
 191
 192 if test "$SQLITE_THREADSAFE" = "1"; then
 193   AC_SEARCH_LIBS(pthread_create, pthread)
 194   AC_SEARCH_LIBS(pthread_mutexattr_init, pthread)
 195 fi
 196
 197 ##########
 198 # Which crypto library do we use
 199 #
 200 AC_ARG_WITH([crypto-lib],
 201 AC_HELP_STRING([--with-crypto-lib],[Specify which crypto library to use]),
 202 crypto_lib=$withval)
 203 AC_MSG_CHECKING([for crypto library to use])
 204 if test "$crypto_lib" = "none"; then
 205   AC_MSG_RESULT([none])
 206 else
 207   if test "$crypto_lib" = "commoncrypto"; then
 208     CFLAGS="$CFLAGS -DSQLCIPHER_CRYPTO_CC"
 209     BUILD_CFLAGS="$BUILD_CFLAGS -DSQLCIPHER_CRYPTO_CC"
 210           AC_MSG_RESULT([commoncrypto])
 211   else
 212     if test "$crypto_lib" = "libtomcrypt"; then
 213       CFLAGS="$CFLAGS -DSQLCIPHER_CRYPTO_LIBTOMCRYPT"
 214       BUILD_CFLAGS="$BUILD_CFLAGS -DSQLCIPHER_CRYPTO_LIBTOMCRYPT"
 215       AC_MSG_RESULT([libtomcrypt])
 216       AC_CHECK_LIB([tomcrypt], [register_cipher], ,
 217                    AC_MSG_ERROR([Library crypto not found. Install libtomcrypt!"]))
 218     else
 219       if test "$crypto_lib" = "nss"; then
 220         CFLAGS="$CFLAGS -DSQLCIPHER_CRYPTO_NSS"
 221         BUILD_CFLAGS="$BUILD_CFLAGS -DSQLCIPHER_CRYPTO_NSS"
 222         AC_MSG_RESULT([nss3])
 223         AC_CHECK_LIB([nss3], [PK11_Decrypt], ,
 224                      AC_MSG_ERROR([Library crypto not found. Install nss!"]))
 225       else
 226         CFLAGS="$CFLAGS -DSQLCIPHER_CRYPTO_OPENSSL"
 227         BUILD_CFLAGS="$BUILD_CFLAGS -DSQLCIPHER_CRYPTO_OPENSSL"
 228               AC_MSG_RESULT([openssl])
 229         AC_CHECK_LIB([crypto], [HMAC_Init_ex], ,
 230                      AC_MSG_ERROR([Library crypto not found. Install openssl!"]))
 231       fi
 232     fi
 233   fi
 234 fi
 235
 236 ##########
 237 # Do we want to allow a connection created in one thread to be used
 238 # in another thread.  This does not work on many Linux systems (ex: RedHat 9)
 239 # due to bugs in the threading implementations.  This is thus off by default.
 240 #
 241 AC_ARG_ENABLE(cross-thread-connections,
 242 AC_HELP_STRING([--enable-cross-thread-connections],[Allow connection sharing across threads]),,enable_xthreadconnect=no)
 243 AC_MSG_CHECKING([whether to allow connections to be shared across threads])
 244 if test "$enable_xthreadconnect" = "no"; then
 245   XTHREADCONNECT=''
 246   AC_MSG_RESULT([no])
 247 else
 248   XTHREADCONNECT='-DSQLITE_ALLOW_XTHREAD_CONNECT=1'
 249   AC_MSG_RESULT([yes])
 250 fi
 251 AC_SUBST(XTHREADCONNECT)
 252
 253 ##########
 254 # Do we want to support release
 255 #
 256 AC_ARG_ENABLE(releasemode,
 257 AC_HELP_STRING([--enable-releasemode],[Support libtool link to release mode]),,enable_releasemode=no)
 258 AC_MSG_CHECKING([whether to support shared library linked as release mode or not])
 259 if test "$enable_releasemode" = "no"; then
 260   ALLOWRELEASE=""
 261   AC_MSG_RESULT([no])
 262 else
 263   ALLOWRELEASE="-release `cat $srcdir/VERSION`"
 264   AC_MSG_RESULT([yes])
 265 fi
 266 AC_SUBST(ALLOWRELEASE)
 267
 268 ##########
 269 # Do we want temporary databases in memory
 270 #
 271 AC_ARG_ENABLE(tempstore,
 272 AC_HELP_STRING([--enable-tempstore],[Use an in-ram database for temporary tables (never,no,yes,always)]),,enable_tempstore=no)
 273 AC_MSG_CHECKING([whether to use an in-ram database for temporary tables])
 274 case "$enable_tempstore" in
 275   never )
 276     TEMP_STORE=0
 277     AC_MSG_RESULT([never])
 278   ;;
 279   no )
 280     TEMP_STORE=1
 281     AC_MSG_RESULT([no])
 282   ;;
 283   yes )
 284      TEMP_STORE=2
 285     AC_MSG_RESULT([yes])
 286   ;;
 287   always )
 288      TEMP_STORE=3
 289     AC_MSG_RESULT([always])
 290   ;;
 291   * )
 292     TEMP_STORE=1
 293     AC_MSG_RESULT([no])
 294   ;;
 295 esac
 296
 297 AC_SUBST(TEMP_STORE)
 298
 299 ###########
 300 # Lots of things are different if we are compiling for Windows using
 301 # the CYGWIN environment.  So check for that special case and handle
 302 # things accordingly.
 303 #
 304 AC_MSG_CHECKING([if executables have the .exe suffix])
 305 if test "$config_BUILD_EXEEXT" = ".exe"; then
 306   CYGWIN=yes
 307   AC_MSG_RESULT(yes)
 308 else
 309   AC_MSG_RESULT(unknown)
 310 fi
 311 if test "$CYGWIN" != "yes"; then
 312   AC_CYGWIN
 313 fi
 314 if test "$CYGWIN" = "yes"; then
 315   BUILD_EXEEXT=.exe
 316 else
 317   BUILD_EXEEXT=$EXEEXT
 318 fi
 319 if test x"$cross_compiling" = xno; then
 320   TARGET_EXEEXT=$BUILD_EXEEXT
 321 else
 322   TARGET_EXEEXT=$config_TARGET_EXEEXT
 323 fi
 324 if test "$TARGET_EXEEXT" = ".exe"; then
 325   SQLITE_OS_UNIX=0
 326   SQLITE_OS_WIN=1
 327   CFLAGS="$CFLAGS -DSQLITE_OS_WIN=1"
 328 else
 329   SQLITE_OS_UNIX=1
 330   SQLITE_OS_WIN=0
 331   CFLAGS="$CFLAGS -DSQLITE_OS_UNIX=1"
 332 fi
 333
 334 AC_SUBST(BUILD_EXEEXT)
 335 AC_SUBST(SQLITE_OS_UNIX)
 336 AC_SUBST(SQLITE_OS_WIN)
 337 AC_SUBST(TARGET_EXEEXT)
 338
 339 ##########
 340 # Figure out all the parameters needed to compile against Tcl.
 341 #
 342 # This code is derived from the SC_PATH_TCLCONFIG and SC_LOAD_TCLCONFIG
 343 # macros in the in the tcl.m4 file of the standard TCL distribution.
 344 # Those macros could not be used directly since we have to make some
 345 # minor changes to accomodate systems that do not have TCL installed.
 346 #
 347 AC_ARG_ENABLE(tcl, AC_HELP_STRING([--disable-tcl],[do not build TCL extension]),
 348       [use_tcl=$enableval],[use_tcl=yes])
 349 if test "${use_tcl}" = "yes" ; then
 350   AC_ARG_WITH(tcl, AC_HELP_STRING([--with-tcl=DIR],[directory containing tcl configuration (tclConfig.sh)]), with_tclconfig=${withval})
 351   AC_MSG_CHECKING([for Tcl configuration])
 352   AC_CACHE_VAL(ac_cv_c_tclconfig,[
 353     # First check to see if --with-tcl was specified.
 354     if test x"${with_tclconfig}" != x ; then
 355       if test -f "${with_tclconfig}/tclConfig.sh" ; then
 356         ac_cv_c_tclconfig=`(cd ${with_tclconfig}; pwd)`
 357       else
 358         AC_MSG_ERROR([${with_tclconfig} directory doesn't contain tclConfig.sh])
 359       fi
 360     fi
 361
 362     # Start autosearch by asking tclsh
 363     if test x"${ac_cv_c_tclconfig}" = x ; then
 364       if test x"$cross_compiling" = xno; then
 365         for i in `echo 'puts stdout $auto_path' | ${TCLSH_CMD}`
 366         do
 367           if test -f "$i/tclConfig.sh" ; then
 368             ac_cv_c_tclconfig="$i"
 369             break
 370           fi
 371         done
 372       fi
 373     fi
 374
 375     # On ubuntu 14.10, $auto_path on tclsh is not quite correct.
 376     # So try again after applying corrections.
 377     if test x"${ac_cv_c_tclconfig}" = x ; then
 378       if test x"$cross_compiling" = xno; then
 379         for i in `echo 'puts stdout $auto_path' | ${TCLSH_CMD} | sed 's,/tcltk/tcl,/tcl,g'`
 380         do
 381           if test -f "$i/tclConfig.sh" ; then
 382             ac_cv_c_tclconfig="$i"
 383             break
 384           fi
 385         done
 386       fi
 387     fi
 388
 389     # Recent versions of Xcode on Macs hid the tclConfig.sh file
 390     # in a strange place.
 391     if test x"${ac_cv_c_tclconfig}" = x ; then
 392       if test x"$cross_compiling" = xno; then
 393         for i in /Applications/Xcode.app/Contents/Developer/Platforms/MacOSX.platform/Developer/SDKs/MacOSX*.sdk/usr/lib
 394         do
 395           if test -f "$i/tclConfig.sh" ; then
 396             ac_cv_c_tclconfig="$i"
 397             break
 398           fi
 399         done
 400       fi
 401     fi
 402
 403     # then check for a private Tcl installation
 404     if test x"${ac_cv_c_tclconfig}" = x ; then
 405       for i in \
 406             ../tcl \
 407             `ls -dr ../tcl[[8-9]].[[0-9]].[[0-9]]* 2>/dev/null` \
 408             `ls -dr ../tcl[[8-9]].[[0-9]] 2>/dev/null` \
 409             `ls -dr ../tcl[[8-9]].[[0-9]]* 2>/dev/null` \
 410             ../../tcl \
 411             `ls -dr ../../tcl[[8-9]].[[0-9]].[[0-9]]* 2>/dev/null` \
 412             `ls -dr ../../tcl[[8-9]].[[0-9]] 2>/dev/null` \
 413             `ls -dr ../../tcl[[8-9]].[[0-9]]* 2>/dev/null` \
 414             ../../../tcl \
 415             `ls -dr ../../../tcl[[8-9]].[[0-9]].[[0-9]]* 2>/dev/null` \
 416             `ls -dr ../../../tcl[[8-9]].[[0-9]] 2>/dev/null` \
 417             `ls -dr ../../../tcl[[8-9]].[[0-9]]* 2>/dev/null`
 418       do
 419         if test -f "$i/unix/tclConfig.sh" ; then
 420           ac_cv_c_tclconfig=`(cd $i/unix; pwd)`
 421           break
 422         fi
 423       done
 424     fi
 425
 426     # check in a few common install locations
 427     if test x"${ac_cv_c_tclconfig}" = x ; then
 428       for i in \
 429             `ls -d ${libdir} 2>/dev/null` \
 430             `ls -d /usr/local/lib 2>/dev/null` \
 431             `ls -d /usr/contrib/lib 2>/dev/null` \
 432             `ls -d /usr/lib 2>/dev/null`
 433       do
 434         if test -f "$i/tclConfig.sh" ; then
 435            ac_cv_c_tclconfig=`(cd $i; pwd)`
 436            break
 437         fi
 438       done
 439     fi
 440
 441     # check in a few other private locations
 442     if test x"${ac_cv_c_tclconfig}" = x ; then
 443       for i in \
 444          ${srcdir}/../tcl \
 445          `ls -dr ${srcdir}/../tcl[[8-9]].[[0-9]].[[0-9]]* 2>/dev/null` \
 446          `ls -dr ${srcdir}/../tcl[[8-9]].[[0-9]] 2>/dev/null` \
 447          `ls -dr ${srcdir}/../tcl[[8-9]].[[0-9]]* 2>/dev/null`
 448       do
 449         if test -f "$i/unix/tclConfig.sh" ; then
 450           ac_cv_c_tclconfig=`(cd $i/unix; pwd)`
 451           break
 452         fi
 453       done
 454     fi
 455   ])
 456
 457   if test x"${ac_cv_c_tclconfig}" = x ; then
 458     use_tcl=no
 459     AC_MSG_WARN(Can't find Tcl configuration definitions)
 460     AC_MSG_WARN(*** Without Tcl the regression tests cannot be executed ***)
 461     AC_MSG_WARN(*** Consider using --with-tcl=... to define location of Tcl ***)
 462   else
 463     TCL_BIN_DIR=${ac_cv_c_tclconfig}
 464     AC_MSG_RESULT(found $TCL_BIN_DIR/tclConfig.sh)
 465
 466     AC_MSG_CHECKING([for existence of $TCL_BIN_DIR/tclConfig.sh])
 467     if test -f "$TCL_BIN_DIR/tclConfig.sh" ; then
 468       AC_MSG_RESULT([loading])
 469       . $TCL_BIN_DIR/tclConfig.sh
 470     else
 471       AC_MSG_RESULT([file not found])
 472     fi
 473
 474     #
 475     # If the TCL_BIN_DIR is the build directory (not the install directory),
 476     # then set the common variable name to the value of the build variables.
 477     # For example, the variable TCL_LIB_SPEC will be set to the value
 478     # of TCL_BUILD_LIB_SPEC. An extension should make use of TCL_LIB_SPEC
 479     # instead of TCL_BUILD_LIB_SPEC since it will work with both an
 480     # installed and uninstalled version of Tcl.
 481     #
 482
 483     if test -f $TCL_BIN_DIR/Makefile ; then
 484       TCL_LIB_SPEC=${TCL_BUILD_LIB_SPEC}
 485       TCL_STUB_LIB_SPEC=${TCL_BUILD_STUB_LIB_SPEC}
 486       TCL_STUB_LIB_PATH=${TCL_BUILD_STUB_LIB_PATH}
 487     fi
 488
 489     #
 490     # eval is required to do the TCL_DBGX substitution
 491     #
 492
 493     eval "TCL_LIB_FILE=\"${TCL_LIB_FILE}\""
 494     eval "TCL_LIB_FLAG=\"${TCL_LIB_FLAG}\""
 495     eval "TCL_LIB_SPEC=\"${TCL_LIB_SPEC}\""
 496
 497     eval "TCL_STUB_LIB_FILE=\"${TCL_STUB_LIB_FILE}\""
 498     eval "TCL_STUB_LIB_FLAG=\"${TCL_STUB_LIB_FLAG}\""
 499     eval "TCL_STUB_LIB_SPEC=\"${TCL_STUB_LIB_SPEC}\""
 500
 501     AC_SUBST(TCL_VERSION)
 502     AC_SUBST(TCL_BIN_DIR)
 503     AC_SUBST(TCL_SRC_DIR)
 504     AC_SUBST(TCL_INCLUDE_SPEC)
 505
 506     AC_SUBST(TCL_LIB_FILE)
 507     AC_SUBST(TCL_LIB_FLAG)
 508     AC_SUBST(TCL_LIB_SPEC)
 509
 510     AC_SUBST(TCL_STUB_LIB_FILE)
 511     AC_SUBST(TCL_STUB_LIB_FLAG)
 512     AC_SUBST(TCL_STUB_LIB_SPEC)
 513     AC_SUBST(TCL_SHLIB_SUFFIX)
 514   fi
 515 fi
 516 if test "${use_tcl}" = "no" ; then
 517   HAVE_TCL=""
 518 else
 519   HAVE_TCL=1
 520 fi
 521 AC_SUBST(HAVE_TCL)
 522
 523 ##########
 524 # Figure out what C libraries are required to compile programs
 525 # that use "readline()" library.
 526 #
 527 TARGET_READLINE_LIBS=""
 528 TARGET_READLINE_INC=""
 529 TARGET_HAVE_READLINE=0
 530 TARGET_HAVE_EDITLINE=0
 531 AC_ARG_ENABLE([editline],
 532         [AC_HELP_STRING([--enable-editline],[enable BSD editline support])],
 533         [with_editline=$enableval],
 534         [with_editline=auto])
 535 AC_ARG_ENABLE([readline],
 536         [AC_HELP_STRING([--disable-readline],[disable readline support])],
 537         [with_readline=$enableval],
 538         [with_readline=auto])
 539
 540 if test x"$with_editline" != xno; then
 541         sLIBS=$LIBS
 542         LIBS=""
 543         TARGET_HAVE_EDITLINE=1
 544         AC_SEARCH_LIBS(readline,edit,[with_readline=no],[TARGET_HAVE_EDITLINE=0])
 545         TARGET_READLINE_LIBS=$LIBS
 546         LIBS=$sLIBS
 547 fi
 548 if test x"$with_readline" != xno; then
 549         found="yes"
 550
 551         AC_ARG_WITH([readline-lib],
 552                 [AC_HELP_STRING([--with-readline-lib],[specify readline library])],
 553                 [with_readline_lib=$withval],
 554                 [with_readline_lib="auto"])
 555         if test "x$with_readline_lib" = xauto; then
 556                 save_LIBS="$LIBS"
 557                 LIBS=""
 558                 AC_SEARCH_LIBS(tgetent, [readline ncurses curses termcap], [term_LIBS="$LIBS"], [term_LIBS=""])
 559                 AC_CHECK_LIB([readline], [readline], [TARGET_READLINE_LIBS="-lreadline"], [found="no"])
 560                 TARGET_READLINE_LIBS="$TARGET_READLINE_LIBS $term_LIBS"
 561                 LIBS="$save_LIBS"
 562         else
 563                 TARGET_READLINE_LIBS="$with_readline_lib"
 564         fi
 565
 566         AC_ARG_WITH([readline-inc],
 567                 [AC_HELP_STRING([--with-readline-inc],[specify readline include paths])],
 568                 [with_readline_inc=$withval],
 569                 [with_readline_inc="auto"])
 570         if test "x$with_readline_inc" = xauto; then
 571                 AC_CHECK_HEADER(readline.h, [found="yes"], [
 572                         found="no"
 573                         if test "$cross_compiling" != yes; then
 574                                 for dir in /usr /usr/local /usr/local/readline /usr/contrib /mingw; do
 575                                         for subdir in include include/readline; do
 576                                                 AC_CHECK_FILE($dir/$subdir/readline.h, found=yes)
 577                                                 if test "$found" = "yes"; then
 578                                                         TARGET_READLINE_INC="-I$dir/$subdir"
 579                                                         break
 580                                                 fi
 581                                         done
 582                                         test "$found" = "yes" && break
 583                                 done
 584                         fi
 585                 ])
 586         else
 587                 TARGET_READLINE_INC="$with_readline_inc"
 588         fi
 589
 590         if test x"$found" = xno; then
 591                 TARGET_READLINE_LIBS=""
 592                 TARGET_READLINE_INC=""
 593                 TARGET_HAVE_READLINE=0
 594         else
 595                 TARGET_HAVE_READLINE=1
 596         fi
 597 fi
 598
 599 AC_SUBST(TARGET_READLINE_LIBS)
 600 AC_SUBST(TARGET_READLINE_INC)
 601 AC_SUBST(TARGET_HAVE_READLINE)
 602 AC_SUBST(TARGET_HAVE_EDITLINE)
 603
 604 ##########
 605 # Figure out what C libraries are required to compile programs
 606 # that use "fdatasync()" function.
 607 #
 608 AC_SEARCH_LIBS(fdatasync, [rt])
 609
 610 #########
 611 # check for debug enabled
 612 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug],[enable debugging & verbose explain]))
 613 AC_MSG_CHECKING([build type])
 614 if test "${enable_debug}" = "yes" ; then
 615   TARGET_DEBUG="-DSQLITE_DEBUG=1 -DSQLITE_ENABLE_SELECTTRACE -DSQLITE_ENABLE_WHERETRACE -O0"
 616   AC_MSG_RESULT([debug])
 617 else
 618   TARGET_DEBUG="-DNDEBUG"
 619   AC_MSG_RESULT([release])
 620 fi
 621 AC_SUBST(TARGET_DEBUG)
 622
 623 #########
 624 # See whether we should use the amalgamation to build
 625 AC_ARG_ENABLE(amalgamation, AC_HELP_STRING([--disable-amalgamation],
 626       [Disable the amalgamation and instead build all files separately]))
 627 if test "${enable_amalgamation}" = "no" ; then
 628   USE_AMALGAMATION=0
 629 fi
 630 AC_SUBST(USE_AMALGAMATION)
 631
 632 #########
 633 # By default, amalgamation sqlite3.c will have #line directives.
 634 # This is a build option not shown by ./configure --help
 635 # To control it, use configure option: amalgamation_line_macros=?
 636 # where ? is no to suppress #line directives or yes to create them.
 637 AMALGAMATION_LINE_MACROS=--linemacros=1
 638 AC_ARG_VAR(amalgamation_line_macros,)
 639 AC_SUBST(AMALGAMATION_LINE_MACROS)
 640 if test "${amalgamation_line_macros+set}" = set; then :
 641   enableval=$amalgamation_line_macros;
 642 fi
 643 if test "${amalgamation_line_macros}" = "yes" ; then
 644   AMALGAMATION_LINE_MACROS=--linemacros=1
 645 fi
 646 if test "${amalgamation_line_macros}" = "no" ; then
 647   AMALGAMATION_LINE_MACROS=--linemacros=0
 648 fi
 649
 650 #########
 651 # Look for zlib.  Only needed by extensions and by the sqlite3.exe shell
 652 AC_CHECK_HEADERS(zlib.h)
 653 AC_SEARCH_LIBS(deflate, z, [HAVE_ZLIB="-DSQLITE_HAVE_ZLIB=1"], [HAVE_ZLIB=""])
 654 AC_SUBST(HAVE_ZLIB)
 655
 656 #########
 657 # See whether we should allow loadable extensions
 658 AC_ARG_ENABLE(load-extension, AC_HELP_STRING([--disable-load-extension],
 659       [Disable loading of external extensions]),,[enable_load_extension=yes])
 660 if test "${enable_load_extension}" = "yes" ; then
 661   OPT_FEATURE_FLAGS=""
 662   AC_SEARCH_LIBS(dlopen, dl)
 663 else
 664   OPT_FEATURE_FLAGS="-DSQLITE_OMIT_LOAD_EXTENSION=1"
 665 fi
 666
 667 ##########
 668 # Do we want to support math functions
 669 #
 670 AC_ARG_ENABLE(math,
 671 AC_HELP_STRING([--disable-math],[Disable math functions]))
 672 AC_MSG_CHECKING([whether to support math functions])
 673 if test "$enable_math" = "no"; then
 674   AC_MSG_RESULT([no])
 675 else
 676   AC_MSG_RESULT([yes])
 677   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_MATH_FUNCTIONS"
 678   AC_SEARCH_LIBS(ceil, m)
 679 fi
 680
 681
 682 ########
 683 # The --enable-all argument is short-hand to enable
 684 # multiple extensions.
 685 AC_ARG_ENABLE(all, AC_HELP_STRING([--enable-all],
 686       [Enable FTS4, FTS5, Geopoly, JSON, RTree, Sessions]))
 687
 688 ##########
 689 # Do we want to support memsys3 and/or memsys5
 690 #
 691 AC_ARG_ENABLE(memsys5,
 692   AC_HELP_STRING([--enable-memsys5],[Enable MEMSYS5]))
 693 AC_MSG_CHECKING([whether to support MEMSYS5])
 694 if test "${enable_memsys5}" = "yes"; then
 695   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_MEMSYS5"
 696   AC_MSG_RESULT([yes])
 697 else
 698   AC_MSG_RESULT([no])
 699 fi
 700 AC_ARG_ENABLE(memsys3,
 701   AC_HELP_STRING([--enable-memsys3],[Enable MEMSYS3]))
 702 AC_MSG_CHECKING([whether to support MEMSYS3])
 703 if test "${enable_memsys3}" = "yes" -a "${enable_memsys5}" = "no"; then
 704   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_MEMSYS3"
 705   AC_MSG_RESULT([yes])
 706 else
 707   AC_MSG_RESULT([no])
 708 fi
 709
 710 #########
 711 # See whether we should enable Full Text Search extensions
 712 AC_ARG_ENABLE(fts3, AC_HELP_STRING([--enable-fts3],
 713       [Enable the FTS3 extension]))
 714 AC_MSG_CHECKING([whether to support FTS3])
 715 if test "${enable_fts3}" = "yes" ; then
 716   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_FTS3"
 717   AC_MSG_RESULT([yes])
 718 else
 719   AC_MSG_RESULT([no])
 720 fi
 721 AC_ARG_ENABLE(fts4, AC_HELP_STRING([--enable-fts4],
 722       [Enable the FTS4 extension]))
 723 AC_MSG_CHECKING([whether to support FTS4])
 724 if test "${enable_fts4}" = "yes" -o "${enable_all}" = "yes" ; then
 725   AC_MSG_RESULT([yes])
 726   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_FTS4"
 727   AC_SEARCH_LIBS([log],[m])
 728 else
 729   AC_MSG_RESULT([no])
 730 fi
 731 AC_ARG_ENABLE(fts5, AC_HELP_STRING([--enable-fts5],
 732       [Enable the FTS5 extension]))
 733 AC_MSG_CHECKING([whether to support FTS5])
 734 if test "${enable_fts5}" = "yes" -o "${enable_all}" = "yes" ; then
 735   AC_MSG_RESULT([yes])
 736   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_FTS5"
 737   AC_SEARCH_LIBS([log],[m])
 738 else
 739   AC_MSG_RESULT([no])
 740 fi
 741
 742 #########
 743 # See whether we should enable JSON1
 744 AC_ARG_ENABLE(json1, AC_HELP_STRING([--enable-json1],[Enable the JSON1 extension]))
 745 AC_MSG_CHECKING([whether to support JSON])
 746 if test "${enable_json1}" = "yes" -o "${enable_all}" = "yes" ; then
 747   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_JSON1"
 748   AC_MSG_RESULT([yes])
 749 else
 750   AC_MSG_RESULT([no])
 751 fi
 752
 753 #########
 754 # See whether we should enable the LIMIT clause on UPDATE and DELETE
 755 # statements.
 756 AC_ARG_ENABLE(update-limit, AC_HELP_STRING([--enable-update-limit],
 757       [Enable the UPDATE/DELETE LIMIT clause]))
 758 AC_MSG_CHECKING([whether to support LIMIT on UPDATE and DELETE statements])
 759 if test "${enable_update_limit}" = "yes" ; then
 760   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_UPDATE_DELETE_LIMIT"
 761   AC_MSG_RESULT([yes])
 762 else
 763   AC_MSG_RESULT([no])
 764 fi
 765
 766 #########
 767 # See whether we should enable GEOPOLY
 768 AC_ARG_ENABLE(geopoly, AC_HELP_STRING([--enable-geopoly],
 769       [Enable the GEOPOLY extension]),
 770       [enable_geopoly=yes],[enable_geopoly=no])
 771 AC_MSG_CHECKING([whether to support GEOPOLY])
 772 if test "${enable_geopoly}" = "yes" -o "${enable_all}" = "yes" ; then
 773   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_GEOPOLY"
 774   enable_rtree=yes
 775   AC_MSG_RESULT([yes])
 776 else
 777   AC_MSG_RESULT([no])
 778 fi
 779
 780 #########
 781 # See whether we should enable RTREE
 782 AC_ARG_ENABLE(rtree, AC_HELP_STRING([--enable-rtree],
 783       [Enable the RTREE extension]))
 784 AC_MSG_CHECKING([whether to support RTREE])
 785 if test "${enable_rtree}" = "yes" ; then
 786   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_RTREE"
 787   AC_MSG_RESULT([yes])
 788 else
 789   AC_MSG_RESULT([no])
 790 fi
 791
 792 #########
 793 # See whether we should enable the SESSION extension
 794 AC_ARG_ENABLE(session, AC_HELP_STRING([--enable-session],
 795       [Enable the SESSION extension]))
 796 AC_MSG_CHECKING([whether to support SESSION])
 797 if test "${enable_session}" = "yes" -o "${enable_all}" = "yes" ; then
 798   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_SESSION"
 799   OPT_FEATURE_FLAGS="${OPT_FEATURE_FLAGS} -DSQLITE_ENABLE_PREUPDATE_HOOK"
 800   AC_MSG_RESULT([yes])
 801 else
 802   AC_MSG_RESULT([no])
 803 fi
 804
 805 #########
 806 # attempt to duplicate any OMITS and ENABLES into the ${OPT_FEATURE_FLAGS} parameter
 807 for option in $CFLAGS $CPPFLAGS
 808 do
 809   case $option in
 810     -DSQLITE_OMIT*) OPT_FEATURE_FLAGS="$OPT_FEATURE_FLAGS $option";;
 811     -DSQLITE_ENABLE*) OPT_FEATURE_FLAGS="$OPT_FEATURE_FLAGS $option";;
 812   esac
 813 done
 814 AC_SUBST(OPT_FEATURE_FLAGS)
 815
 816
 817 # attempt to remove any OMITS and ENABLES from the $(CFLAGS) parameter
 818 ac_temp_CFLAGS=""
 819 for option in $CFLAGS
 820 do
 821   case $option in
 822     -DSQLITE_OMIT*) ;;
 823     -DSQLITE_ENABLE*) ;;
 824     *) ac_temp_CFLAGS="$ac_temp_CFLAGS $option";;
 825   esac
 826 done
 827 CFLAGS=$ac_temp_CFLAGS
 828
 829
 830 # attempt to remove any OMITS and ENABLES from the $(CPPFLAGS) parameter
 831 ac_temp_CPPFLAGS=""
 832 for option in $CPPFLAGS
 833 do
 834   case $option in
 835     -DSQLITE_OMIT*) ;;
 836     -DSQLITE_ENABLE*) ;;
 837     *) ac_temp_CPPFLAGS="$ac_temp_CPPFLAGS $option";;
 838   esac
 839 done
 840 CPPFLAGS=$ac_temp_CPPFLAGS
 841
 842
 843 # attempt to remove any OMITS and ENABLES from the $(BUILD_CFLAGS) parameter
 844 ac_temp_BUILD_CFLAGS=""
 845 for option in $BUILD_CFLAGS
 846 do
 847   case $option in
 848     -DSQLITE_OMIT*) ;;
 849     -DSQLITE_ENABLE*) ;;
 850     *) ac_temp_BUILD_CFLAGS="$ac_temp_BUILD_CFLAGS $option";;
 851   esac
 852 done
 853 BUILD_CFLAGS=$ac_temp_BUILD_CFLAGS
 854
 855
 856 #########
 857 # See whether we should use GCOV
 858 AC_ARG_ENABLE(gcov, AC_HELP_STRING([--enable-gcov],
 859       [Enable coverage testing using gcov]))
 860 if test "${use_gcov}" = "yes" ; then
 861   USE_GCOV=1
 862 else
 863   USE_GCOV=0
 864 fi
 865 AC_SUBST(USE_GCOV)
 866
 867 #########
 868 # Enable/disabled amalagamation line macros
 869 ########
 870 AMALGAMATION_LINE_MACROS=--linemacros=0
 871 if test "${amalgamation_line_macros}" = "yes" ; then
 872   AMALGAMATION_LINE_MACROS=--linemacros=1
 873 fi
 874 if test "${amalgamation_line_macros}" = "no" ; then
 875   AMALGAMATION_LINE_MACROS=--linemacros=0
 876 fi
 877 AC_SUBST(AMALGAMATION_LINE_MACROS)
 878
 879 #########
 880 # Output the config header
 881 AC_CONFIG_HEADERS(config.h)
 882
 883 #########
 884 # Generate the output files.
 885 #
 886 AC_SUBST(BUILD_CFLAGS)
 887 AC_OUTPUT([
 888 Makefile
 889 sqlcipher.pc
 890 ])