test/rdonly.test

   1 # 2007 April 24
   2 #
   3 # The author disclaims copyright to this source code.  In place of
   4 # a legal notice, here is a blessing:
   5 #
   6 #    May you do good and not evil.
   7 #    May you find forgiveness for yourself and forgive others.
   8 #    May you share freely, never taking more than you give.
   9 #
  10 #***********************************************************************
  11 # This file implements regression tests for SQLite library.
  12 #
  13 # This file implements tests to make sure SQLite treats a database
  14 # as readonly if its write version is set to  high.
  15 #
  16 # $Id: rdonly.test,v 1.2 2008/07/08 10:19:58 danielk1977 Exp $
  17
  18 set testdir [file dirname $argv0]
  19 source $testdir/tester.tcl
  20
  21 # Do not use a codec for tests in this file, as the database file is
  22 # manipulated directly using tcl scripts (using the [hexio_write] command).
  23 #
  24 do_not_use_codec
  25
  26 # Create a database.
  27 #
  28 do_test rdonly-1.1 {
  29   execsql {
  30     CREATE TABLE t1(x);
  31     INSERT INTO t1 VALUES(1);
  32     SELECT * FROM t1;
  33   }
  34 } {1}
  35
  36 # EVIDENCE-OF: R-29639-16887 The sqlite3_db_readonly(D,N) interface
  37 # returns 1 if the database N of connection D is read-only, 0 if it is
  38 # read/write, or -1 if N is not the name of a database on connection D.
  39 #
  40 do_test rdonly-1.1.1 {
  41   sqlite3_db_readonly db main
  42 } {0}
  43
  44 # Changes the write version from 1 to 3.  Verify that the database
  45 # can be read but not written.
  46 #
  47 do_test rdonly-1.2 {
  48   db close
  49   hexio_get_int [hexio_read test.db 18 1]
  50 } 1
  51 do_test rdonly-1.3 {
  52   hexio_write test.db 18 03
  53   sqlite3 db test.db
  54   execsql {
  55     SELECT * FROM t1;
  56   }
  57 } {1}
  58 do_test rdonly-1.3.1 {
  59   sqlite3_db_readonly db main
  60 } {1}
  61 do_test rdonly-1.4 {
  62   catchsql {
  63     INSERT INTO t1 VALUES(2)
  64   }
  65 } {1 {attempt to write a readonly database}}
  66
  67 # Change the write version back to 1.  Verify that the database
  68 # is read-write again.
  69 #
  70 do_test rdonly-1.5 {
  71   db close
  72   hexio_write test.db 18 01
  73   sqlite3 db test.db
  74   catchsql {
  75     INSERT INTO t1 VALUES(2);
  76     SELECT * FROM t1;
  77   }
  78 } {0 {1 2}}
  79
  80 # Now, after connection [db] has loaded the database schema, modify the
  81 # write-version of the file (and the change-counter, so that the
  82 # write-version is reloaded). This way, SQLite does not discover that
  83 # the database is read-only until after it is locked.
  84 #
  85 set ro_version 02
  86 ifcapable wal { set ro_version 03 }
  87 do_test rdonly-1.6 {
  88   hexio_write test.db 18 $ro_version     ; # write-version
  89   hexio_write test.db 24 11223344        ; # change-counter
  90   catchsql {
  91     INSERT INTO t1 VALUES(2);
  92   }
  93 } {1 {attempt to write a readonly database}}
  94
  95 finish_test