tests/ga.t

   1 #!/usr/bin/env perl
   2
   3 #==============================================================================
   4 # ga.t
   5 # File ID: c4726d6a-bf17-11eb-9d68-4f45262dc9b5
   6 #
   7 # Test suite for ga(1).
   8 #
   9 # Character set: UTF-8
  10 # ©opyleft 2021– Øyvind A. Holm <sunny@sunbase.org>
  11 # License: GNU General Public License version 2 or later, see end of file for
  12 # legal stuff.
  13 #==============================================================================
  14
  15 use strict;
  16 use warnings;
  17
  18 BEGIN {
  19         use Test::More qw{no_plan};
  20         # use_ok() goes here
  21 }
  22
  23 use Getopt::Long;
  24
  25 local $| = 1;
  26
  27 our $CMDB = "ga";
  28
  29 our $CMD = "../$CMDB";
  30
  31 my $Lh = "[0-9a-fA-F]";
  32 my $v1_templ = "$Lh\{8}-$Lh\{4}-1$Lh\{3}-$Lh\{4}-$Lh\{12}";
  33
  34 our %Opt = (
  35
  36         'all' => 0,
  37         'git' => 'git',
  38         'git-annex' => 'git-annex',
  39         'help' => 0,
  40         'quiet' => 0,
  41         'todo' => 0,
  42         'verbose' => 0,
  43         'version' => 0,
  44
  45 );
  46
  47 our $progname = $0;
  48 $progname =~ s/^.*\/(.*?)$/$1/;
  49 our $VERSION = '0.0.0'; # Not used here, $CMD decides
  50
  51 my %descriptions = ();
  52
  53 Getopt::Long::Configure('bundling');
  54 GetOptions(
  55
  56         'all|a' => \$Opt{'all'},
  57         'git-annex=s' => \$Opt{'git-annex'},
  58         'git=s' => \$Opt{'git'},
  59         'help|h' => \$Opt{'help'},
  60         'quiet|q+' => \$Opt{'quiet'},
  61         'todo|t' => \$Opt{'todo'},
  62         'verbose|v+' => \$Opt{'verbose'},
  63         'version' => \$Opt{'version'},
  64
  65 ) || die("$progname: Option error. Use -h for help.\n");
  66
  67 $Opt{'verbose'} -= $Opt{'quiet'};
  68 $Opt{'help'} && usage(0);
  69 if ($Opt{'version'}) {
  70         print_version();
  71         exit(0);
  72 }
  73
  74 my $GIT = $Opt{'git'};
  75 my $GIT_ANNEX = $Opt{'git-annex'};
  76 my $exec_version = `$CMD --version`;
  77 my $is_root = $< ? 0 : 1;
  78
  79 exit(main());
  80
  81 sub main {
  82         my $Retval = 0;
  83
  84         diag('========== BEGIN version info ==========');
  85         diag($exec_version);
  86         diag('=========== END version info ===========');
  87
  88         if ($Opt{'todo'} && !$Opt{'all'}) {
  89                 goto todo_section;
  90         }
  91
  92         test_standard_options();
  93         if (`$GIT_ANNEX version 2>/dev/null` !~ /^git-annex version/) {
  94                 diag("git-annex is not installed here, skipping tests");
  95                 return 0;
  96         }
  97         test_executable();
  98
  99         diag('========== BEGIN version info ==========');
 100         diag($exec_version);
 101         diag('=========== END version info ===========');
 102
 103         todo_section:
 104         ;
 105
 106         if ($Opt{'all'} || $Opt{'todo'}) {
 107                 diag('Running TODO tests...');
 108                 TODO: {
 109                         local $TODO = '';
 110                         # Insert TODO tests here.
 111                 }
 112         }
 113
 114         diag('Testing finished.');
 115
 116         return $Retval;
 117 }
 118
 119 sub test_standard_options {
 120         diag('Testing -h (--help) option...');
 121         likecmd("$CMD -h",
 122                 '/  Show this help/i',
 123                 '/^$/',
 124                 0,
 125                 'Option -h prints help screen');
 126
 127         diag('Testing --version option...');
 128         likecmd("$CMD --version",
 129                 '/^\S+ \d+\.\d+\.\d+/',
 130                 '/^$/',
 131                 0,
 132                 'Option --version returns version number');
 133
 134         return;
 135 }
 136
 137 sub test_executable {
 138         my $Tmptop = "tmp-$CMDB-t-$$-" . substr(rand, 2, 8);
 139
 140         ok(mkdir($Tmptop), "mkdir [Tmptop]");
 141         safe_chdir($Tmptop, "chdir [Tmptop]");
 142
 143         chomp($ENV{'HOME'} = `pwd`);
 144         like($ENV{'HOME'}, "/$Tmptop\$/",
 145              "HOME environment variable contains [Tmptop]");
 146         testcmd("$GIT config --global user.name 'Suttleif Fisen'", "", "", 0,
 147                 "$GIT config --global user.name 'Suttleif Fisen'");
 148         testcmd("$GIT config --global user.email suttleif\@example.com",
 149                 "", "", 0,
 150                 "$GIT config --global user.email suttleif\@example.com");
 151         testcmd("$GIT config --global init.defaultbranch master", "", "", 0,
 152                 "$GIT config --global init.defaultbranch master");
 153         testcmd("$GIT config --global annex.backend SHA256", "", "", 0,
 154                 "$GIT config --global annex.backend SHA256");
 155         ok(-f ".gitconfig", ".gitconfig exists");
 156
 157         my $suuid_logdir = "$ENV{'HOME'}/suuid_logdir";
 158         $ENV{'SUUID_LOGDIR'} = $suuid_logdir;
 159         like($ENV{'SUUID_LOGDIR'}, "/suuid_logdir\$/",
 160              'SUUID_LOGDIR environment variable contains "suuid_logdir"');
 161         ok(mkdir($suuid_logdir), "mkdir suuid_logdir");
 162
 163         test_init_command();
 164         my $suuid_file = glob("$suuid_logdir/*.xml");
 165         like($suuid_file, '/.*\.xml$/', 'suuid file found by glob()');
 166         test_chk_command();
 167         test_copnum_command();
 168
 169         diag("Clean up");
 170         ok(unlink($suuid_file), 'Delete suuid file');
 171         ok(rmdir($suuid_logdir), 'Delete suuid_logdir');
 172         delete_dir(".cache");
 173         delete_dir(".ssh");
 174         ok(unlink(".gitconfig"), "Delete .gitconfig");
 175         safe_chdir("..");
 176         ok(rmdir($Tmptop), "rmdir [Tmptop]");
 177
 178         return;
 179 }
 180
 181 sub test_init_command {
 182         diag("init");
 183         init_annex("t_init");
 184         safe_chdir("t_init");
 185         ok(-d ".git/annex", ".git/annex directory exists");
 186         like(`$GIT config --get annex.uuid`, "/^$v1_templ\\n/",
 187              "UUID is version 1");
 188         safe_chdir("..");
 189         delete_dir("t_init");
 190
 191         return;
 192 }
 193
 194 sub test_chk_command {
 195         init_annex('t_chk');
 196         safe_chdir('t_chk');
 197
 198         create_file('okfile', "This is file 1.\n");
 199         ga_add('okfile', 'Add okfile in t_chk/');
 200         git_commit('Add okfile', 'Commit okfile in t_chk/');
 201         testcmd("$CMD chk okfile",
 202                 "okfile ok\n",
 203                 "",
 204                 0,
 205                 "Check okfile");
 206
 207         create_file('with space.txt', "File with space in filname.\n");
 208         ga_add('"with space.txt"', 'Add "with space.txt" in t_chk/');
 209         git_commit('Add file with space in filename',
 210                    'Commit "with space.txt" in t_chk/');
 211         testcmd("$CMD chk 'with space.txt'",
 212                 "with space.txt ok\n",
 213                 "",
 214                 0,
 215                 'Check "with space.txt"');
 216
 217         create_file('errfile', "File with frrors.\n");
 218         ga_add('errfile', 'Add errfile in t_chk/');
 219         git_commit('Add errfile', 'Commit errfile in t_chk/');
 220         my $errkey = 'SHA256-s18--db1f5def94d1ace370d322ebb5bb8ee84b3f2ea7eb7445c8b8143fe1c9455c96';
 221         my $errobjdir = ".git/annex/objects/pJ/gJ/$errkey";
 222         my $errobjfile = "$errobjdir/$errkey";
 223         testcmd("chmod +w -R \"$errobjdir\"", "", "", 0,
 224                 "Make [errobjdir] writable");
 225         create_file($errobjfile, "File with errors.\n",
 226                     "Overwrite [errobjfile] with different data");
 227         testcmd("$CMD chk errfile",
 228                 "errfile fail\n",
 229                 "",
 230                 1,
 231                 "Check errfile");
 232
 233         SKIP: {
 234                 skip("Running tests as root", 14) if ($is_root);
 235
 236                 create_file('unrfile', "Unreadable file.\n");
 237                 ga_add('unrfile', 'Add unrfile in t_chk/');
 238                 git_commit('Add unrfile', 'Commit unrfile in t_chk/');
 239                 my $unrkey = 'SHA256-s17--93bd33a38896168b87271a6ee3ffacbed5b2b6c32b07dd784eb1e9be2e8c9c1a';
 240                 my $unrobjdir = ".git/annex/objects/64/5V/$unrkey";
 241                 my $unrobjfile = "$unrobjdir/$unrkey";
 242                 testcmd("chmod +w -R \"$unrobjdir\"", "", "", 0,
 243                         "Make [unrobjdir] writable");
 244                 ok(chmod(0000, $unrobjfile),
 245                    'Remove all permissions from [unrobjfile]');
 246                 testcmd("$CMD chk unrfile",
 247                         "",
 248                         "$CMDB: unrfile: File is not readable by you\n",
 249                         1,
 250                         "Check unrfile when it's not readable");
 251         }
 252
 253         testcmd("$CMD chk nonexistent",
 254                 "",
 255                 "$CMDB: nonexistent: File not found\n",
 256                 1,
 257                 "Check nonexistent");
 258
 259         testcmd("$CMD chk ''",
 260                 "",
 261                 "$CMDB: : File not found\n",
 262                 1,
 263                 "Check empty filename");
 264
 265         ok(mkdir('directory'), 'mkdir directory');
 266         testcmd("$CMD chk directory",
 267                 "",
 268                 "$CMDB: directory: Is a directory\n",
 269                 0,
 270                 "File is a directory");
 271
 272         ok(symlink('directory', 'dirlink'), 'Create symlink to directory');
 273         testcmd("$CMD chk dirlink",
 274                 "",
 275                 "$CMDB: dirlink: Is a symlink to a directory\n",
 276                 0,
 277                 "File is a symlink to a directory");
 278
 279         create_file('not-here', "This file is not here.\n");
 280         ga_add('not-here', 'Add not-here in t_chk/');
 281         git_commit('Add not-here', 'Commit not-here in t_chk/');
 282         ga_drop('not-here', 'Drop not-here');
 283         testcmd("$CMD chk not-here",
 284                 "",
 285                 "$CMDB: not-here: File not present here\n",
 286                 0,
 287                 "Check not-here");
 288
 289         create_file('regfile', "Regular file.\n");
 290         testcmd("$CMD chk regfile",
 291                 "",
 292                 "$CMDB: regfile: Not a symbolic link\n",
 293                 0,
 294                 "Check regfile");
 295
 296         ok(symlink('regfile', 'regfilelink'), 'Create regfilelink');
 297         testcmd("$CMD chk regfilelink",
 298                 "",
 299                 "$CMDB: regfilelink: SHA256 key not found in symlink\n",
 300                 0,
 301                 "Check regfilelink");
 302
 303         ok(symlink('brokendest', 'brokenlink'), 'Create brokenlink');
 304         testcmd("$CMD chk brokenlink",
 305                 "",
 306                 "$CMDB: brokenlink: Broken symlink\n",
 307                 0,
 308                 "Check brokenlink");
 309
 310         testcmd("$CMD chk *",
 311                 ""
 312                 . "errfile fail\n"
 313                 . "okfile ok\n"
 314                 . "with space.txt ok\n",
 315                 ""
 316                 . "$CMDB: brokenlink: Broken symlink\n"
 317                 . "$CMDB: directory: Is a directory\n"
 318                 . "$CMDB: dirlink: Is a symlink to a directory\n"
 319                 . "$CMDB: not-here: File not present here\n"
 320                 . "$CMDB: regfile: Not a symbolic link\n"
 321                 . "$CMDB: regfilelink: SHA256 key not found in symlink\n"
 322                 . ($is_root ? ""
 323                             : "$CMDB: unrfile: File is not readable by you\n"),
 324                 1,
 325                 'Test all files');
 326
 327         safe_chdir('..');
 328         delete_dir('t_chk');
 329
 330         return;
 331 }
 332
 333 sub test_copnum_command {
 334         diag("copnum");
 335         init_annex("t_copnum");
 336         safe_chdir("t_copnum");
 337         testcmd("$CMD copnum", "1\n", "", 0, "copnum is 1 by default");
 338         testcmd("$GIT_ANNEX numcopies 3",
 339                 "numcopies 3 ok\n"
 340                 . "(recording state in git...)\n",
 341                 "",
 342                 0,
 343                 "Set numcopies to 3");
 344         testcmd("$CMD copnum", "3\n", "", 0, "copnum is 3");
 345         safe_chdir("..");
 346         delete_dir("t_copnum");
 347
 348         return;
 349 }
 350
 351 sub delete_dir {
 352         my $dir = shift;
 353
 354         SKIP: {
 355                 skip("delete_dir(): $dir doesn't exist", 6) unless (-d $dir);
 356                 testcmd("chmod +w -R \"$dir\"", "", "", 0,
 357                         "Make everything in $dir/ writable");
 358                 testcmd("rm -rf \"$dir\"", "", "", 0,
 359                         "Delete $dir/");
 360         }
 361
 362         return;
 363 }
 364
 365 sub ga_add {
 366         my ($file, $desc) = @_;
 367
 368         if (!defined($desc) || !length($desc)) {
 369                 $desc = "ga add $file";
 370         }
 371
 372         likecmd("$CMD add $file",
 373                 '/^add .*ok\n/s',
 374                 '/^$/',
 375                 0,
 376                 $desc);
 377
 378         return;
 379 }
 380
 381 sub ga_drop {
 382         my ($file, $desc) = @_;
 383
 384         if (!defined($desc) || !length($desc)) {
 385                 $desc = "ga add $file";
 386         }
 387
 388         ok(-e $file, "$file exists");
 389         likecmd("$CMD drop --force $file",
 390                 '/^drop .* ok\n/',
 391                 '/^$/',
 392                 0,
 393                 $desc);
 394
 395         return;
 396 }
 397
 398 sub git_commit {
 399         my ($logmsg, $desc) = @_;
 400
 401         if (!defined($logmsg) || !length($logmsg)) {
 402                 BAIL_OUT('git_commit(): $logmsg not defined');
 403         }
 404
 405         likecmd("$GIT commit -m \"$logmsg\"",
 406                 '/'
 407                 . '.*'
 408                 . quotemeta($logmsg)
 409                 . '.*'
 410                 . '/',
 411                 '/^$/',
 412                 0,
 413                 $desc);
 414
 415         return;
 416 }
 417
 418 sub git_init {
 419         my $dir = shift;
 420
 421         ok(!-e $dir, "git_init(): $dir doesn't exist")
 422         || BAIL_OUT("git_init(): $dir already exists, aborting");
 423         likecmd("$GIT init \"$dir\"", '/.*/', '/^$/', 0, "$GIT init \"$dir\"");
 424
 425         return;
 426 }
 427
 428 sub init_annex {
 429         my $dir = shift;
 430
 431         git_init($dir);
 432         safe_chdir($dir);
 433         likecmd("$CMD init",
 434                 '/^'
 435                 . 'init \S+:.*\/'
 436                 . $dir
 437                 . " .*" # New versions print "(scanning for unlocked files...)"
 438                 . 'ok\n'
 439                 . '.*'
 440                 . '/s',
 441                 "/^$v1_templ\\n\$/",
 442                 0,
 443                 "ga init in $dir");
 444         likecmd("$CMD info",
 445                 "/$v1_templ -- "
 446                 . '\S+:.*\/' . $dir . ' \[here\]\n'
 447                 . '/',
 448                 '/Have disabled git annex pre-commit/',
 449                 0,
 450                 "ga info in $dir");
 451         safe_chdir("..");
 452
 453         return;
 454 }
 455
 456 sub safe_chdir {
 457         my ($dir, $desc) = @_;
 458         defined($desc) || ($desc = '');
 459
 460         ok(chdir($dir), length($desc) ? $desc : "chdir $dir")
 461         || BAIL_OUT("$progname: Can't chdir to $dir, aborting");
 462         if ($dir eq "..") {
 463                 $CMD =~ s!^\.\./!!
 464                 || BAIL_OUT('safe_chdir(): $dir is "..",'
 465                             . ' but $CMD doesn\'t start with "../"');
 466         } else {
 467                 $CMD = "../$CMD";
 468         }
 469
 470         return;
 471 }
 472
 473 sub testcmd {
 474         my ($Cmd, $Exp_stdout, $Exp_stderr, $Exp_retval, $Desc) = @_;
 475         defined($descriptions{$Desc})
 476         && BAIL_OUT("testcmd(): '$Desc' description is used twice");
 477         $descriptions{$Desc} = 1;
 478         my $stderr_cmd = '';
 479         my $cmd_outp_str = $Opt{'verbose'} >= 1 ? "\"$Cmd\" - " : '';
 480         my $Txt = join('', $cmd_outp_str, defined($Desc) ? $Desc : '');
 481         my $TMP_STDERR = "$CMDB-stderr.tmp";
 482         my $retval = 1;
 483
 484         if (defined($Exp_stderr)) {
 485                 $stderr_cmd = " 2>$TMP_STDERR";
 486         }
 487         $retval &= is(`$Cmd$stderr_cmd`, $Exp_stdout, "$Txt (stdout)");
 488         my $ret_val = $?;
 489         if (defined($Exp_stderr)) {
 490                 $retval &= is(file_data($TMP_STDERR),
 491                               $Exp_stderr, "$Txt (stderr)");
 492                 unlink($TMP_STDERR);
 493         } else {
 494                 diag("Warning: stderr not defined for '$Txt'");
 495         }
 496         $retval &= is($ret_val >> 8, $Exp_retval, "$Txt (retval)");
 497
 498         return $retval;
 499 }
 500
 501 sub likecmd {
 502         my ($Cmd, $Exp_stdout, $Exp_stderr, $Exp_retval, $Desc) = @_;
 503         defined($descriptions{$Desc})
 504         && BAIL_OUT("likecmd(): '$Desc' description is used twice");
 505         $descriptions{$Desc} = 1;
 506         my $stderr_cmd = '';
 507         my $cmd_outp_str = $Opt{'verbose'} >= 1 ? "\"$Cmd\" - " : '';
 508         my $Txt = join('', $cmd_outp_str, defined($Desc) ? $Desc : '');
 509         my $TMP_STDERR = "$CMDB-stderr.tmp";
 510         my $retval = 1;
 511
 512         if (defined($Exp_stderr)) {
 513                 $stderr_cmd = " 2>$TMP_STDERR";
 514         }
 515         $retval &= like(`$Cmd$stderr_cmd`, $Exp_stdout, "$Txt (stdout)");
 516         my $ret_val = $?;
 517         if (defined($Exp_stderr)) {
 518                 $retval &= like(file_data($TMP_STDERR),
 519                                 $Exp_stderr, "$Txt (stderr)");
 520                 unlink($TMP_STDERR);
 521         } else {
 522                 diag("Warning: stderr not defined for '$Txt'");
 523         }
 524         $retval &= is($ret_val >> 8, $Exp_retval, "$Txt (retval)");
 525
 526         return $retval;
 527 }
 528
 529 sub file_data {
 530         # Return file content as a string
 531         my $File = shift;
 532         my $Txt;
 533
 534         open(my $fp, '<', $File) or return undef;
 535         local $/ = undef;
 536         $Txt = <$fp>;
 537         close($fp);
 538
 539         return $Txt;
 540 }
 541
 542 sub create_file {
 543         # Create new file and fill it with data
 544         my ($file, $text, $desc) = @_;
 545         my $retval = 0;
 546
 547         if (!defined($desc) || !length($desc)) {
 548                 $desc = "$file was successfully created";
 549         }
 550
 551         open(my $fp, ">", $file) or return 0;
 552         print($fp $text);
 553         close($fp);
 554         $retval = is(file_data($file), $text, $desc);
 555
 556         return $retval; # 0 if error, 1 if ok
 557 }
 558
 559 sub print_version {
 560         # Print program version
 561         print("$progname $VERSION\n");
 562
 563         return;
 564 }
 565
 566 sub usage {
 567         # Send the help message to stdout
 568         my $Retval = shift;
 569
 570         if ($Opt{'verbose'}) {
 571                 print("\n");
 572                 print_version();
 573         }
 574         print(<<"END");
 575
 576 Usage: $progname [options]
 577
 578 Contains tests for the $CMDB(1) program.
 579
 580 Options:
 581
 582   -a, --all
 583     Run all tests, also TODOs.
 584   --git PATH
 585     Specify path to alternative git(1) executable.
 586   --git-annex PATH
 587     Specify path to alternative git-annex(1) executable.
 588   -h, --help
 589     Show this help.
 590   -q, --quiet
 591     Be more quiet. Can be repeated to increase silence.
 592   -t, --todo
 593     Run only the TODO tests.
 594   -v, --verbose
 595     Increase level of verbosity. Can be repeated.
 596   --version
 597     Print version information.
 598
 599 END
 600         exit($Retval);
 601 }
 602
 603 sub msg {
 604         # Print a status message to stderr based on verbosity level
 605         my ($verbose_level, $Txt) = @_;
 606
 607         $verbose_level > $Opt{'verbose'} && return;
 608         print(STDERR "$progname: $Txt\n");
 609
 610         return;
 611 }
 612
 613 __END__
 614
 615 # This program is free software; you can redistribute it and/or modify it under
 616 # the terms of the GNU General Public License as published by the Free Software
 617 # Foundation; either version 2 of the License, or (at your option) any later
 618 # version.
 619 #
 620 # This program is distributed in the hope that it will be useful, but WITHOUT
 621 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
 622 # FOR A PARTICULAR PURPOSE.
 623 # See the GNU General Public License for more details.
 624 #
 625 # You should have received a copy of the GNU General Public License along with
 626 # this program.
 627 # If not, see L<http://www.gnu.org/licenses/>.
 628
 629 # vim: set ts=8 sw=8 sts=8 noet fo+=w tw=79 fenc=UTF-8 :