SCClassLibrary/QtCollider/QLayout.sc

   1 QLayout : QObject {
   2   spacing_ { arg spacing;
   3     this.setProperty( \spacing, spacing );
   4   }
   5
   6   margins_ { arg margins;
   7     this.setProperty( \margins, margins + [0,0,0,0] );
   8   }
   9 }
  10
  11 // LINE LAYOUTS ///////////////////////////////////////////////////
  12
  13 QLineLayout : QLayout {
  14   *new { arg ...items;
  15     var serializedItems = items.collect( { |x| this.parse(x) } );
  16     ^super.new( [serializedItems] );
  17   }
  18
  19   *parse { arg in;
  20     var out = [nil,0,0];
  21     var key;
  22     var i;
  23     if( in.isKindOf(Array) ) {
  24       out[0] = in[0];
  25       i = 1;
  26       while { i + 1 < in.size } {
  27         key = in[i];
  28         case (
  29           { (key === \stretch) || (key === \s) }, { out[1] = in[i+1] },
  30           { (key === \align) || (key === \a) }, { out[2] = QAlignment(in[i+1]) }
  31         );
  32         i = i + 2;
  33       };
  34     }{
  35       out[0] = in;
  36     };
  37     ^out;
  38   }
  39
  40   add { arg item, stretch = 0, align;
  41     this.invokeMethod( \addItem, [[item, stretch, QAlignment(align)]], true );
  42   }
  43
  44   insert { arg item, index=0, stretch = 0, align;
  45     this.invokeMethod( \insertItem, [[item, index, stretch, QAlignment(align)]], true );
  46   }
  47
  48   setStretch { arg item, stretch;
  49     this.invokeMethod( \setStretch, [item, stretch], true );
  50   }
  51
  52   setAlignment { arg item, align;
  53     this.invokeMethod( \setAlignment, [item, QAlignment(align)], true );
  54   }
  55 }
  56
  57 QHLayout : QLineLayout {
  58   *qtClass { ^'QcHBoxLayout'; }
  59 }
  60
  61 QVLayout : QLineLayout {
  62   *qtClass { ^'QcVBoxLayout'; }
  63 }
  64
  65 // GRID LAYOUT ///////////////////////////////////////////////////
  66
  67 QGridLayout : QLayout {
  68   *new {
  69     // get rid of QObject's arguments
  70     ^super.new;
  71   }
  72
  73   *qtClass { ^'QcGridLayout' }
  74
  75   *parse { arg in, row, col;
  76     var out = [nil,row,col,1,1,nil];
  77     var key;
  78     var i;
  79     if( in.isKindOf(Array) ) {
  80       out[0] = in[0];
  81       i = 1;
  82       while { i + 1 < in.size } {
  83         key = in[i];
  84         case (
  85           { (key === \rows) || (key === \r) }, { out[3] = in[i+1] },
  86           { (key === \columns) || (key === \c) }, { out[4] = in[i+1] },
  87           { (key === \align) || (key === \a) }, { out[5] = QAlignment(in[i+1]) }
  88         );
  89         i = i + 2;
  90       };
  91     }{
  92       out[0] = in;
  93     };
  94     ^out;
  95   }
  96
  97
  98   *rows { arg ...rows ;
  99     var grid;
 100     var data;
 101     grid = this.new;
 102     rows.do { |row, r|
 103       if( row.size > 0 ) {
 104         row.do { |item, c|
 105           if( item.notNil ) {
 106             data = this.parse( item, r, c );
 107             grid.invokeMethod( \addItem, [data], true );
 108           };
 109         };
 110       };
 111     }
 112     ^grid;
 113   }
 114
 115   *columns { arg ...cols;
 116     var grid;
 117     var data;
 118     grid = this.new;
 119     cols.do { |col, c|
 120       if( col.size > 0 ) {
 121         col.do { |item, r|
 122           if( item.notNil ) {
 123             data = this.parse( item, r, c );
 124             grid.invokeMethod( \addItem, [data], true );
 125           };
 126         };
 127       };
 128     }
 129     ^grid;
 130   }
 131
 132   add { arg item, row, column, align;
 133     this.invokeMethod( \addItem, [[item, row, column, 1, 1, QAlignment(align)]], true );
 134   }
 135
 136   addSpanning { arg item, row, column, rowSpan=1, columnSpan=1, align;
 137     this.invokeMethod( \addItem, [[item, row, column,
 138                                    rowSpan, columnSpan,
 139                                    QAlignment(align)
 140                                  ]], true );
 141   }
 142
 143   hSpacing_ { arg spacing;
 144     this.setProperty( \horizontalSpacing, spacing );
 145   }
 146
 147   vSpacing_ { arg spacing;
 148     this.setProperty( \verticalSpacing, spacing );
 149   }
 150
 151   setRowStretch{ arg row, factor;
 152     this.invokeMethod( 'setRowStretch', [row, factor], true );
 153   }
 154
 155   setColumnStretch{ arg column, factor;
 156     this.invokeMethod( 'setColumnStretch', [column, factor], true );
 157   }
 158
 159   setAlignment { arg item, align;
 160     var args = if( item.class === Point )
 161       { [item.y, item.x, QAlignment(align)] }
 162       { [item, QAlignment(align)] };
 163
 164     this.invokeMethod( \setAlignment, args, true );
 165   }
 166
 167   minRowHeight { arg row; ^this.invokeMethod( \minRowHeight, row ); }
 168
 169   setMinRowHeight { arg row, height;
 170     this.invokeMethod( \setMinRowHeight, [row, height] );
 171   }
 172
 173   minColumnWidth { arg column; ^this.invokeMethod( \minColumnWidth, column ); }
 174
 175   setMinColumnWidth { arg column, width;
 176     this.invokeMethod( \setMinColumnWidth, [column, width] );
 177   }
 178 }
 179
 180 QStackLayout : QLayout
 181 {
 182   *qtClass { ^'QcStackLayout' }
 183
 184   *new { arg ...views; ^super.new([views]) }
 185
 186   add { arg view; this.insert(view, -1) }
 187
 188   insert { arg view, index = 0; this.invokeMethod( \insertWidget, [index, view] ) }
 189
 190   index { ^this.getProperty(\currentIndex) }
 191   index_ { arg value; this.setProperty(\currentIndex, value) }
 192
 193   count { ^this.getProperty(\count) }
 194
 195   mode { ^this.getProperty(\stackingMode) }
 196   mode_ { arg value;
 197     value = value.switch(
 198       \stackOne, 0,
 199       \stackAll, 1,
 200       value
 201     );
 202     value = value.clip(0, 1).asInteger;
 203     this.setProperty(\stackingMode, value)
 204   }
 205 }