SCClassLibrary/Common/Streams/PgeneralHid.sc

   1 //human device interface pattern. pulls values from devices like gamepads etc.
   2 // based on GeneralHID
   3
   4 PhidSlot : Pattern {
   5         var <>slot,<>type,<>device;
   6         var <>repeats;
   7         var <>pSlot;
   8
   9         // the Device list must have been built.
  10         *new { arg slot, type, device, repeats=inf;
  11                 ^super.new.init(slot, type, device, repeats)
  12         }
  13
  14         init{|sl,tp,dev,rep|
  15                 device = dev;
  16                 slot = sl;
  17                 type = tp;
  18                 repeats = rep;
  19                 if ( device.isKindOf( GeneralHIDDevice ).not,
  20                         {
  21                                 try { device = GeneralHID.open( device ); }{ "device argument is not a GeneralHIDDevice".error; ^nil }
  22                         });
  23         }
  24
  25         storeArgs { ^[slot, type, device, repeats] }
  26
  27         embedInStream { arg inval;
  28
  29                 // slot and type streams
  30                 var slotStr = slot.asStream;
  31                 var typeStr = type.asStream;
  32                 var slotVal, typeVal, slottypes;
  33
  34                 repeats.value.do({
  35
  36                         slotVal = slotStr.next(inval);
  37                         typeVal = typeStr.next(inval);
  38
  39                         slottypes = [slotVal, typeVal].flop;
  40
  41                         inval = slottypes.collect{ |it|
  42                                 var ret;
  43                                 if ( device.slots[ it[1] ].isNil,
  44                                         { "slot type not found".warn;
  45                                                 ret = inval;
  46                                         },{
  47                                         if ( device.slots[ it[1] ][ it[0] ].isNil,
  48                                                 { "slot not found".warn;
  49                                                         ret = inval;
  50                                                 },{
  51                                                         ret = device.slots[ it[1] ][ it[0] ].value;
  52                                                 });
  53                                         });
  54                                 ret;
  55                         }.unbubble.yield;
  56
  57                 });
  58
  59                 ^inval;
  60         }
  61 }
  62
  63
  64 PhidKey : Pattern {
  65         var <>key,<>device;
  66         var <>repeats;
  67         var <>pSlot;
  68
  69         // the Device list must have been built.
  70         *new { arg key, device, repeats=inf;
  71                 ^super.new.init(key, device, repeats)
  72         }
  73
  74         init{|ky,dev,rep|
  75                 key = ky;
  76                 device = dev;
  77                 repeats = rep;
  78                 if ( device.isKindOf( GeneralHIDDevice ).not,
  79                         {
  80                                 try { device = GeneralHID.open( device ); }{ "device argument is not a GeneralHIDDevice".error; ^nil }
  81                         });
  82         }
  83
  84         storeArgs { ^[key, device, repeats] }
  85
  86         embedInStream { arg inval;
  87                 // key stream
  88                 var keyStr = key.asStream;
  89                 var keyVal;
  90
  91                 repeats.value.do({
  92
  93                         keyVal = keyStr.next(inval);
  94                         keyVal = keyVal.asArray;
  95
  96                         inval = keyVal.collect{ |it|
  97                                 var ret;
  98                                 if ( device.at(it).isNil,
  99                                         { "slot not found".warn;
 100                                                 ret = inval;
 101                                         },{
 102                                                 ret = device.at( it ).value;
 103                                         });
 104                                 ret;
 105                         }.unbubble.yield;
 106
 107                 });
 108
 109                 ^inval;
 110         }
 111 }