HelpSource/Classes/BeatTrack.schelp

   1 class:: BeatTrack
   2 summary:: Autocorrelation beat tracker
   3 categories:: UGens>Analysis, UGens>FFT
   4 related:: Classes/BeatTrack2
   5
   6 description::
   7 Autocorrelation based beat tracker; footnote::
   8 Research note: This UGen is a derivation following:
   9 Davies, M. E. P.  and Plumbley, M. D. Beat Tracking With A Two State Model. Proceedings of the IEEE International Conference on Acoustics, Speech and Signal Processing (ICASSP 2005), Philadelphia, USA, March 19-23, 2005
  10
  11 The UGen was converted by Nick Collins for beat tracking research in the course of his PhD and uses an original C implementation of Matthew Davies' MATLAB model. It first appeared as part of BBCut2 as AutoTrack but has now been added to core to enhance SuperCollider's realtime machine listening options.
  12 :: the underlying model assumes 4/4, but it should work on any isochronous beat structure, though there are biases to 100-120 bpm; a fast 7/8 may not be tracked in that sense.
  13 There are four k-rate outputs, being ticks at quarter, eighth and sixteenth level from the determined beat, and the current detected tempo. Note that the sixteenth note output won't necessarily make much sense if the music being tracked has swing; it is provided just as a convenience.
  14
  15 This beat tracker determines the beat, biased to the midtempo range by weighting functions. It does not determine the measure level, only a tactus.
  16 It is also slow reacting, using a 6 second temporal window for its autocorrelation maneouvres. Don't expect human musician level predictive tracking.
  17
  18 On the other hand, it is tireless, relatively general (though obviously best at transient 4/4 heavy material without much expressive tempo variation), and can form the basis of computer processing that is decidedly faster than human.
  19
  20 classmethods::
  21 private:: categories
  22
  23 method:: kr
  24
  25 argument:: chain
  26 [fft] Audio input to track, already passed through an FFT UGen; the expected size of FFT is 1024 for 44100 and 48000 sampling rate, and 2048 for double those. No other sampling rates are supported.
  27 argument:: lock
  28 [sk] If this argument is greater than 0.5, the tracker will lock at its current periodicity and continue from the current phase. Whilst it updates the model's phase and period, this is not reflected in the output until lock goes back below 0.5.
  29 returns::
  30 Four k-rate outputs:
  31 code::
  32 #quarternotetick, eighthnotetick, sixteenthnotetick, tempo = BeatTrack.kr(chain, 0)
  33 ::
  34
  35 instancemethods::
  36 private:: init
  37
  38 examples::
  39
  40 code::
  41 b = Buffer.alloc(s,1024,1); //for sampling rates 44100 and 48000
  42 //b = Buffer.alloc(s,2048,1); //for sampling rates 88200 and 96000
  43
  44 //this is a one minute pop song; you should load something equivalent for testing
  45 d=Buffer.read(s,"/Volumes/data/stevebeattrack/samples/100.wav");
  46
  47
  48 //you can also test at 48000 and it should work
  49 (
  50 a= SynthDef(\help_beattrack,{arg vol=1.0, beepvol=1.0, lock=0;
  51 var in, fft, resample;
  52 var trackb,trackh,trackq,tempo;
  53 var bsound,hsound,qsound, beep;
  54
  55 in= PlayBuf.ar(1,d,BufRateScale.kr(d),1,0,1);
  56 //in = SoundIn.ar(0);
  57
  58 fft = FFT(b, in);
  59
  60 #trackb,trackh,trackq,tempo=BeatTrack.kr(fft, lock);
  61
  62 beep= SinOsc.ar(1000,0.0,Decay.kr(trackb,0.1));
  63
  64 Out.ar(0,Pan2.ar((vol*in)+(beepvol*beep),0.0));
  65 }).play
  66 )
  67
  68 a.set(\vol,0.0);
  69 a.set(\vol,1.0);
  70
  71 a.set(\beepvol,1.0);
  72 a.set(\beepvol,0.0);
  73
  74 a.set(\lock,1); //fix it rigidly from current phase/period solution
  75 a.set(\lock,0); //unfix, back to tracking
  76 ::
  77
  78 track audio in (try clapping a beat or beatboxing, but allow up to 6 seconds for tracking to begin) and spawning stuff at quarters, eighths and sixteenths:
  79 code::
  80 (
  81 SynthDef(\help_beattrack2,{
  82 var trackb,trackh,trackq,tempo;
  83 var source;
  84 var bsound,hsound,qsound;
  85
  86 source= SoundIn.ar(0);
  87
  88 #trackb,trackh,trackq,tempo=BeatTrack.kr(FFT(b, source));
  89
  90 bsound= Pan2.ar(LPF.ar(WhiteNoise.ar*(Decay.kr(trackb,0.05)),1000),0.0);
  91
  92 hsound= Pan2.ar(BPF.ar(WhiteNoise.ar*(Decay.kr(trackh,0.05)),3000,0.66),-0.5);
  93
  94 qsound= Pan2.ar(HPF.ar(WhiteNoise.ar*(Decay.kr(trackq,0.05)),5000),0.5);
  95
  96 Out.ar(0, bsound+hsound+qsound);
  97 }).play;
  98 )
  99 ::
 100