HelpSource/Classes/Pgauss.schelp

   1 class:: Pgauss
   2 summary:: random values that follow a Gaussian Distribution
   3 related:: Classes/Ppoisson
   4 categories:: Streams-Patterns-Events>Patterns>Random
   5
   6 description::
   7
   8 This pattern uses the Box-Muller transform to generate a gaussian distribution from uniformly distributed values: code::sqrt(-2 * log(1.0.rand)) * sin(2pi.rand)::
   9
  10 ClassMethods::
  11
  12 method::new
  13
  14 argument::mean
  15 The mean of the distribution.
  16
  17 argument::standardDeviation
  18 The spread of values around the mean.
  19
  20 argument::length
  21 Number of values produced.
  22
  23 Examples::
  24
  25 code::
  26 (
  27 var a;
  28 a = Pgauss(0.0, 100, inf);
  29 c = a.asStream.nextN(500);
  30 w = Window.new("Pgauss", Rect(10, 10, 540, 800));
  31 // plot the values
  32 c.plot(bounds: Rect(10, 10, 520, 380), discrete: true, parent: w);
  33 // a histogram of the values
  34 c.histo(500).plot(bounds: Rect(10, 410, 520, 380), parent: w);
  35 )
  36
  37 (
  38 var a, c, w;
  39 a = Pgauss(0.0, 10.0, inf);
  40 c = a.asStream.nextN(500);
  41 w = Window.new("Pgauss", Rect(10, 10, 540, 800));
  42 // plot the values
  43 c.plot(bounds: Rect(10, 10, 520, 380), discrete: true, parent: w);
  44 // a histogram of the values
  45 c.histo(500).plot(bounds: Rect(10, 410, 520, 380), parent: w);
  46 )
  47
  48
  49 // sound example
  50 (
  51 SynthDef(\help_sinegrain,
  52         { arg out=0, freq=440, sustain=0.05;
  53                 var env;
  54                 env = EnvGen.kr(Env.perc(0.01, sustain, 0.2), doneAction:2);
  55                 Out.ar(out, SinOsc.ar(freq, 0, env))
  56         }).add;
  57 )
  58
  59 (
  60 var a;
  61 a = Pgauss(0.0, 1.0,inf).asStream;
  62 {
  63         loop {
  64                 Synth(\help_sinegrain, [\freq, a.next * 600 + 300]);
  65                 0.02.wait;
  66         }
  67 }.fork;
  68 )
  69 ::