HelpSource/Classes/LinExp.schelp

   1 class:: LinExp
   2 summary:: Map a linear range to an exponential range
   3 related:: Classes/LinLin
   4 categories::  UGens>Maths
   5
   6
   7 Description::
   8
   9 Converts a linear range of values to an exponential range of values.
  10
  11 classmethods::
  12
  13 method::ar, kr
  14
  15 argument::in
  16
  17 The input signal to convert.
  18
  19
  20 argument::srclo
  21
  22 Lower limit of input range.
  23
  24
  25 argument::srchi
  26
  27 Upper limit of input range.
  28
  29
  30 argument::dstlo
  31
  32 Lower limit of output range.
  33
  34
  35 argument::dsthi
  36
  37 Upper limit of output range.
  38
  39 discussion::
  40 The code::dstlo::  and  code::dsthi::  arguments
  41 must be nonzero and have the same sign.
  42
  43
  44 Examples::
  45
  46 code::
  47 // compare:
  48 (
  49 {
  50         var mod = SinOsc.kr(Line.kr(1, 10, 10));
  51         SinOsc.ar(mod * 400 + 500) * 0.1
  52 }.play;
  53 )
  54
  55 (
  56 {
  57         var mod = SinOsc.kr(Line.kr(1, 10, 10));
  58         SinOsc.ar(LinExp.kr(mod, -1,1, 100, 900)) * 0.1
  59 }.play;
  60 )
  61
  62 // modulating destination values.
  63 (
  64 {
  65         var mod = LFNoise2.ar(80);
  66         SinOsc.ar(LinExp.ar(mod, -1,1, MouseX.kr(200, 8000, 1), MouseY.kr(200, 8000, 1))) * 0.1
  67 }.play;
  68 )
  69 ::
  70
  71 code::linexp:: and code::exprange:: can be used to create a LinExp implicitly from a ugen, mapping its output values from linear range to an exponential one. The rate is derived from the ugen.
  72
  73 code::
  74 // linexp
  75 (
  76 {
  77         var mod = LFNoise2.ar(80);
  78         SinOsc.ar(mod.linexp(-1,1, MouseX.kr(200, 8000, 1), MouseY.kr(200, 8000, 1))) * 0.1
  79 }.play;
  80 )
  81
  82 // exprange
  83 (
  84 {
  85         var mod = LFNoise2.ar(80).exprange(MouseX.kr(200, 8000, 1), MouseY.kr(200, 8000, 1));
  86         SinOsc.ar(mod) * 0.1
  87 }.play;
  88 )
  89 ::
  90