HelpSource/Classes/Pitch.schelp

   1 class:: Pitch
   2 summary:: Autocorrelation pitch follower
   3 categories:: UGens>Analysis>Pitch
   4
   5 description::
   6 This is a better pitch follower than link::Classes/ZeroCrossing::, but more costly of CPU. For most purposes the default settings can be used and only code::in:: needs to be supplied. Pitch returns two values (via an link::Classes/Array:: of OutputProxys, see the link::Classes/OutputProxy:: help file), a code::freq:: which is the pitch estimate and code::hasFreq::, which tells whether a pitch was found. Some vowels are still problematic, for instance a wide open mouth sound somewhere between a low pitched short 'a' sound as in 'sat', and long 'i' sound as in 'fire', contains enough overtone energy to confuse the algorithm.
   7
   8 classmethods::
   9 private:: categories
  10 method:: kr
  11 argument::in
  12 argument::initFreq
  13 argument::minFreq
  14 argument::maxFreq
  15 argument::execFreq
  16 argument::maxBinsPerOctave
  17 argument::median
  18 argument::ampThreshold
  19 argument::peakThreshold
  20 argument::downSample
  21 argument::clar
  22
  23 discussion::
  24 The pitch follower executes periodically at the rate specified by code::execFreq:: in cps. code::execFreq:: is clipped to be between code::minFreq:: and code::maxFreq::. First it detects whether the input peak to peak amplitude is above the code::ampThreshold::.
  25 If it is not then no pitch estimation is performed, code::hasFreq:: is set to zero and code::freq:: is held at its previous value. It performs an autocorrelation on the input and looks for the first peak after the peak around the lag of zero that is above code::peakThreshold:: times the amplitude of the peak at lag zero.
  26
  27 If the code::clar:: argument is greater than zero (it is zero by default) then code::hasFreq:: is given additional detail. Rather than simply being 1 when a pitch is detected, it is a "clarity" measure in the range between zero and one. (Technically, it's the height of the autocorrelation peak normalised by the height of the zero-lag peak.)
  28 It therefore gives a kind of measure of "purity" of the pitched signal.
  29
  30 Using a code::peakThreshold:: of one half does a pretty good job of eliminating overtones, and finding the first peak above that threshold rather than the absolute maximum peak does a good job of eliminating estimates that are actually multiple periods of the wave.
  31
  32 The autocorrelation is done coarsely at first using a maximum of code::maxBinsPerOctave:: lags until the peak is located. Then a fine resolution search is performed until the peak is found. (Note that maxBinsPerOctave does NOT affect the final pitch resolution; a fine resolution search is always performed.
  33 Setting maxBinsPerOctave larger will cause the coarse search to take longer, and setting it smaller will cause the fine search to take longer.)
  34
  35 The three values around the peak are used to find a fractional lag value for the pitch. If the pitch frequency is higher than code::maxFreq::, or if no peak is found above code::minFreq::, then code::hasFreq:: is set to zero and code::freq:: is held at its previous value.
  36
  37 It is possible to put a median filter of length code::median:: on the output estimation so that outliers and jitter can be eliminated. This will however add latency to the pitch estimation for new pitches, because the median filter will have to become half filled with new values before the new one becomes the median value.
  38 If median is set to one then that is equivalent to no filter, which is the default.
  39
  40 When an in range peak is found, it is inserted into the median filter, a new pitch is read out of the median filter and output as code::freq::, and code::hasFreq:: is set to one.
  41
  42 It is possible to down sample the input signal by an integer factor code::downSample:: in order to reduce CPU overhead. This will also reduce the pitch resolution.
  43
  44 Until Pitch finds a pitch for the first time, it will output code::initFreq::.
  45
  46 None of these settings are time variable.
  47
  48 instancemethods::
  49 private:: init
  50
  51 examples::
  52 (use headphones!)
  53
  54 code::
  55 s = Server.local;
  56
  57 (
  58 SynthDef("pitchFollow1",{
  59     var in, amp, freq, hasFreq, out;
  60     in = Mix.new(SoundIn.ar([0,1]));
  61     amp = Amplitude.kr(in, 0.05, 0.05);
  62     # freq, hasFreq = Pitch.kr(in, ampThreshold: 0.02, median: 7);
  63     //freq = Lag.kr(freq.cpsmidi.round(1).midicps, 0.05);
  64     out = Mix.new(VarSaw.ar(freq * [0.5,1,2], 0, LFNoise1.kr(0.3,0.1,0.1), amp));
  65     6.do({
  66         out = AllpassN.ar(out, 0.040, [0.040.rand,0.040.rand], 2)
  67     });
  68     Out.ar(0,out)
  69 }).play(s);
  70 )
  71 ::
  72
  73 code::
  74 (
  75 SynthDef("pitchFollow2",{
  76     var in, amp, freq, hasFreq, out;
  77     in = Mix.new(SoundIn.ar([0,1]));
  78     amp = Amplitude.kr(in, 0.05, 0.05);
  79     # freq, hasFreq = Pitch.kr(in, ampThreshold: 0.02, median: 7);
  80     out = CombC.ar(LPF.ar(in, 1000), 0.1, (2 * freq).reciprocal, -6).distort * 0.05;
  81     6.do({
  82         out = AllpassN.ar(out, 0.040, [0.040.rand,0.040.rand], 2)
  83     });
  84     Out.ar(0,out);
  85 }).play(s);
  86 )
  87 ::
  88