| blob | a7de4a730c762b591d832c976d38c1768e2ed12c |
1 title:: Multichannel Expansion
2 summary:: Explaining multichannel expansion and representation
3 categories:: Server>Nodes, UGens>Multichannel
5 section:: Multiple channels as Arrays
6 Multiple channels of audio are represented as link::Classes/Array::s.
7 code::
8 s.boot;
9 // one channel
10 { Blip.ar(800,4,0.1) }.play;
12 // two channels
13 { [ Blip.ar(800,4,0.1), WhiteNoise.ar(0.1) ] }.play;
14 ::
15 Each channel of output will go out a different speaker, so your limit here is two for a stereo output. If you have a supported multi channel audio interface or card then you can output as many channels as the card supports.
17 All link::Classes/UGen::s have only a single output. This uniformity facilitates the use of array operations to perform manipulation of multi channel structures.
19 In order to implement multichannel output, UGens create a separate UGen known as an link::Classes/OutputProxy:: for each output. An OutputProxy is just a place holder for the output of a multichannel UGen. OutputProxies are created internally, you never need to create them yourself, but it is good to be aware that they exist so you'll know what they are when you run across them.
20 code::
21 // look at the outputs of Pan2:
22 Pan2.ar(PinkNoise.ar(0.1), FSinOsc.kr(3)).dump;
24 play({ Pan2.ar(PinkNoise.ar(0.1), FSinOsc.kr(1)); });
25 ::
27 section:: Multichannel expansion
28 When an link::Classes/Array:: is given as an input to a unit generator it causes an array of multiple copies of that unit generator to be made, each with a different value from the input array. This is called multichannel expansion. All but a few special unit generators perform multichannel expansion. Only Arrays are expanded, no other type of Collection, not even subclasses of Array.
29 code::
30 { Blip.ar(500,8,0.1) }.play // one channel
32 // the array in the freq input causes an Array of 2 Blips to be created :
33 { Blip.ar([499,600],8,0.1) }.play // two channels
35 Blip.ar(500,8,0.1).postln // one unit generator created.
37 Blip.ar([500,601],8,0.1).postln // two unit generators created.
38 ::
39 Multichannel expansion will propagate through the expression graph. When a unit generator constructor is called with an array of inputs, it returns an array of instances. If that array is the input to another constructor, then another array is created, and so on.
40 code::
41 { RLPF.ar(Saw.ar([100,250],0.05), XLine.kr(8000,400,5), 0.05) }.play;
43 // the [100,250] array of frequency inputs to Saw causes Saw.ar to return
44 // an array of two Saws, that array causes RLPF.ar to create two RLPFs.
45 // Both RLPFs share a single instance of XLine.
46 ::
47 When a constructor is parameterized by two or more arrays, then the number of channels created is equal to the longest array, with parameters being pulled from each array in parallel. The shorter arrays will wrap.
49 for example, the following:
50 code::
51 Pulse.ar([400, 500, 600],[0.5, 0.1], 0.2)
52 ::
53 is equivalent to:
54 code::
55 [ Pulse.ar(400,0.5,0.2), Pulse.ar(500,0.1,0.2), Pulse.ar(600,0.5,0.2) ]
56 ::
57 A more complex example based on the Saw example above is given below. In this example, the link::Classes/XLine:: is expanded to two instances, one going from 8000 Hz to 400 Hz and the other going in the opposite direction from 500 Hz to 7000 Hz.
58 These two XLines are 'married' to the two Saw oscillators and used to parameterize two copies of link::Classes/RLPF::. So on the left channel a 100 Hz Saw is filtered from 8000 Hz to 400 Hz and on the right channel a 250 Hz Saw is filtered from 500 Hz to 7000 Hz.
59 code::
60 { RLPF.ar(Saw.ar([100,250],0.05), XLine.kr([8000,500],[400,7000],5), 0.05) }.play;
61 ::
63 subsection:: Expanding methods and operators
64 Many operators and methods also multichannel expand. For example all common math operators:
65 code::
66 { Saw.ar([100,250]) * [0.5,0.8] }.play;
67 { Saw.ar(LFNoise1.kr(1).range(0,100) + [100,250]) }.play;
68 ::
69 Also the various UGen convenience functions like code::.clip2::, code::.lag:: and code::.range:: :
70 code::
71 { Saw.ar(LFNoise1.kr(1).range(100,[200,300]) }.play;
72 { Saw.ar(LFPulse.kr(1).range(100,[200,300]).lag([0.1,0.2]) }.play;
73 ::
74 The expansion is handled by wrapper-methods defined in link::Classes/SequenceableCollection::.
76 You can use link::Classes/Object#-multiChannelPerform:: to do multichannel expansion with any method on any kind of object:
77 code::
78 ["foo","bar"].multiChannelPerform(\toUpper);
79 ::
80 The shorter arrays wrap:
81 code::
82 ["foo","bar","zoo"].multiChannelPerform('++', ["l","ba"])
83 ::
85 subsection:: Using flop for multichannel expansion
86 The method flop swaps columns and rows, allowing to derive series of argument sets:
87 code::
88 (
89 SynthDef("help_multichannel", { |out=0, freq=440, mod=0.1, modrange=20|
90 Out.ar(out,
91 SinOsc.ar(
92 LFPar.kr(mod, 0, modrange) + freq
93 ) * EnvGate(0.1)
94 )
95 }).send(s);
96 )
97 ::
98 code::
99 (
100 var freq, mod, modrange;
102 freq = Array.exprand(8, 400, 5000);
103 mod = Array.exprand(8, 0.1, 2);
104 modrange = Array.rand(8, 0.1, 40);
106 fork {
107 [\freq, freq, \mod, mod, \modrange, modrange].flop.do { |args|
108 args.postln;
109 Synth("help_multichannel", args);
110 0.3.wait;
111 }
112 };
113 )
114 ::
116 Similarly, link::Classes/Function#flop#Function:flop:: returns an unevaluated function that will expand to its arguments when evaluated:
117 code::
118 (
119 SynthDef("blip", { |freq| Out.ar(0, Line.ar(0.1, 0, 0.05, 1, 0, 2)
120 * Pulse.ar(freq * [1, 1.02])) }).send(s);
122 a = { |dur=1, x=1, n=10, freq=400|
123 fork { n.do {
124 if(x.coin) { Synth("blip", [\freq, freq]) };
125 (dur / n).wait;
126 } }
127 }.flop;
128 )
130 a.value(5, [0.3, 0.3, 0.2], [12, 32, 64], [1000, 710, 700]);
131 ::
133 section:: Pitfalls
134 Some UGens create stereo output from mono input, and might not behave as expected regarding multichannel expansion.
136 For example, link::Classes/Pan2:: :
137 code::
138 { Pan2.ar(SinOsc.ar([500,600]),[-0.5,0.5]) }.play;
139 ::
140 The expectation here might be that the two sines would get individual pan positions. And they do, but Pan2 expands into two stereo ugens nested in an outer array, resulting in a total of four output channels. code::play:: will add an link::Classes/Out:: UGen for each of them, resulting in both Pan2's writing to the same output bus:
141 code::
142 Pan2.ar(SinOsc.ar([500,600]),[-0.5,0.5])
144 // prints:
145 // [ [ an OutputProxy, an OutputProxy ], [ an OutputProxy, an OutputProxy ] ]
146 ::
148 In this case, the solution is simply to sum the nested four channels into a single stereo-channel:
149 code::
150 { Pan2.ar(SinOsc.ar([500,600]),[-0.5,0.5]).sum }.play;
151 ::
153 If we take a look at the resulting UGen graph of the code above, we can see that it is correct. The two Pan2 is mixed together to create a single stereo output:
154 code::
155 { Pan2.ar(SinOsc.ar([500,600]),[-0.5,0.5]).sum }.asSynthDef.dumpUGens
157 // prints:
158 // [ 0_Control, scalar, nil ]
159 // [ 1_SinOsc, audio, [ 500, 0 ] ]
160 // [ 2_Pan2, audio, [ 1_SinOsc, -0.5, 1 ] ]
161 // [ 3_SinOsc, audio, [ 600, 0 ] ]
162 // [ 4_Pan2, audio, [ 3_SinOsc, 0.5, 1 ] ]
163 // [ 5_+, audio, [ 2_Pan2[0], 4_Pan2[0] ] ]
164 // [ 6_+, audio, [ 2_Pan2[1], 4_Pan2[1] ] ]
165 // [ 7_Out, audio, [ 0_Control[0], 5_+, 6_+ ] ]
166 ::
168 section:: Protecting arrays against expansion
169 Some unit generators such as link::Classes/Klank:: require arrays of values as inputs. Since all arrays are expanded, you need to protect some arrays by a link::Classes/Ref:: object.
170 A Ref instance is an object with a single slot named 'value' that serves as a holder of an object.
171 code::Ref.new(object):: is one way to create a Ref, but there is a syntactic shortcut. The backquote code::`:: is a unary operator that is equivalent to calling code::Ref.new(something)::. So to protect arrays that are inputs to a Klank or similar UGens you write:
172 code::
173 Klank.ar(`[[400,500,600],[1,2,1]], z)
174 ::
175 You can still create multiple Klanks by giving it an array of Ref'ed arrays.
176 code::
177 Klank.ar([ `[[400,500,600],[1,2,1]], `[[700,800,900],[1,2,1]] ], z)
178 ::
179 is equivalent to:
180 code::
181 [ Klank.ar(`[[400,500,600],[1,2,1]], z), Klank.ar(`[[700,800,900],[1,2,1]], z)]
182 ::
183 Also the Refs multichannelExpand when passed to a Klank:
184 code::
185 Klank.ar(`[[[400,500,600], [700,800,900]],[1,2,1]], z)
186 ::
187 , which is is equivalent to:
188 code::
189 [ Klank.ar(`[[400,500,600],[1,2,1]], z), Klank.ar(`[[700,800,900],[1,2,1]], z)]
190 ::
192 section:: Reducing channel expansion with Mix
193 The link::Classes/Mix:: object provides the means for reducing multichannel arrays to a single channel.
194 code::
195 Mix.new([a, b, c]) // array of channels
196 ::
197 or
198 code::
199 [a, b, c].sum
200 ::
201 is equivalent to:
202 code::
203 a + b + c // mixed to one
204 ::
205 Mix is more efficient than using + since it can perform multiple additions at a time. But the main advantage is that it can deal with situations where the number of channels is arbitrary or determined at runtime.
206 code::
207 // three channels of Pulse are mixed to one channel
208 { Mix.new( Pulse.ar([400, 501, 600], [0.5, 0.1], 0.1) ) }.play
209 ::
210 Multi channel expansion works differently for Mix. Mix takes one input which is an array (one not protected by a Ref). That array does not cause copies of Mix to be made.
211 All elements of the array are mixed together in a single Mix object. On the other hand if the array contains one or more arrays then multi channel expansion is performed one level down. This allows you to mix an array of stereo (two element) arrays resulting in one two channel array. For example:
212 code::
213 Mix.new( [ [a, b], [c, d], [e, f] ] ) // input is an array of stereo pairs
214 ::
215 is equivalent to:
216 code::
217 // mixed to a single stereo pair
218 [ Mix.new( [a, c, e] ), Mix.new( [b, d, f] ) ]
219 ::
220 Currently it is not recursive. You cannot use Mix on arrays of arrays of arrays.
222 Here's a final example illustrating multi channel expansion and Mix. By changing the variable 'n' you can change the number of voices in the patch. How many voices can your machine handle?
223 code::
224 (
225 {
226 var n;
227 n = 8; // number of 'voices'
228 Mix.new( // mix all stereo pairs down.
229 Pan2.ar( // pan the voice to a stereo position
230 CombL.ar( // a comb filter used as a string resonator
231 Dust.ar( // random impulses as an excitation function
232 // an array to cause expansion of Dust to n channels
233 // 1 means one impulse per second on average
234 Array.fill(n, 1),
235 0.3 // amplitude
236 ),
237 0.01, // max delay time in seconds
238 // array of different random lengths for each 'string'
239 Array.fill(n, {0.004.rand+0.0003}),
240 4 // decay time in seconds
241 ),
242 Array.fill(n,{1.0.rand2}) // give each voice a different pan position
243 )
244 )
245 }.play;
246 )
247 ::