HelpSource/Classes/Pcauchy.schelp

   1 class:: Pcauchy
   2 summary:: random values that follow a Cauchy Distribution
   3 related:: Classes/BrownNoise, Classes/Pbrown
   4 categories:: Streams-Patterns-Events>Patterns>Random
   5
   6 ClassMethods::
   7
   8 method::new
   9
  10 argument::mean
  11 The mean of the distribution.
  12
  13 argument::spread
  14 The horizontal dispersion of the random values. The distribution is unbounded.
  15
  16 argument::length
  17 Number of values produced.
  18
  19 Examples::
  20
  21 code::
  22 (
  23 var a, c, w;
  24 a = Pcauchy(0.0, 1.0, inf);
  25 c = a.asStream.nextN(500);
  26 w = Window.new("Pcauchy", Rect(10, 10, 540, 800));
  27 // plot the values
  28 c.plot(bounds: Rect(10, 10, 520, 380), discrete: true, parent: w);
  29 // a histogram of the values
  30 c.histo(500).plot(bounds: Rect(10, 410, 520, 380), parent: w);
  31 )
  32
  33 (
  34 var a, c, w;
  35 a = Pcauchy(0.0, 10.0, inf);
  36 c = a.asStream.nextN(500);
  37 w = Window.new("Pbetarand", Rect(10, 10, 540, 800));
  38 // plot the values
  39 c.plot(bounds: Rect(10, 10, 520, 380), discrete: true, parent: w);
  40 // a histogram of the values
  41 c.histo(500).plot(bounds: Rect(10, 410, 520, 380), parent: w);
  42 )
  43
  44 // sound example
  45 (
  46 SynthDef(\help_sinegrain,
  47         { arg out=0, freq=440, sustain=0.05;
  48                 var env;
  49                 env = EnvGen.kr(Env.perc(0.01, sustain, 0.2), doneAction:2);
  50                 Out.ar(out, SinOsc.ar(freq, 0, env))
  51         }).add;
  52 )
  53
  54
  55 (
  56 var a;
  57 a = Pcauchy(0.0, 1.0,inf).asStream;
  58 {
  59         loop {
  60                 Synth(\help_sinegrain, [\freq, a.next * 600 + 300]);
  61                 0.02.wait;
  62         }
  63 }.fork;
  64 )
  65 ::