HelpSource/Classes/Phasor.schelp

   1 class:: Phasor
   2 summary:: A resettable linear ramp between two levels.
   3 categories::  UGens>Triggers, UGens>Buffer
   4
   5
   6 Description::
   7
   8 Phasor is a linear ramp between start and end values. When its trigger
   9 input crosses from non-positive to positive, Phasor's output will jump to
  10 its reset position. Upon reaching the end of its ramp Phasor will wrap
  11 back to its start.
  12
  13
  14 note::
  15 N.B. Since end is defined as the wrap point, its value is never
  16 actually output.
  17 ::
  18
  19 Phasor is commonly used as an index control with  link::Classes/BufRd::
  20 and  link::Classes/BufWr:: .
  21
  22
  23 classmethods::
  24
  25 method::ar, kr
  26
  27 argument::trig
  28
  29 When triggered, jump to resetPos (default: 0, equivalent to
  30 start).
  31
  32
  33 argument::rate
  34
  35 The amount of change per sample, i.e at a rate of 1 the value of
  36 each sample will be 1 greater than the preceding sample.
  37
  38
  39 argument::start
  40
  41 Start point of the ramp.
  42
  43
  44 argument::end
  45
  46 End point of the ramp.
  47
  48
  49 argument::resetPos
  50
  51 The value to jump to upon receiving a trigger.
  52
  53
  54 Examples::
  55
  56 code::
  57
  58 // phasor controls sine frequency: end frequency matches a second sine wave.
  59
  60 (
  61 { var trig, rate, x, sr;
  62         rate = MouseX.kr(0.2, 2, 1);
  63         trig = Impulse.ar(rate);
  64         sr = SampleRate.ir;
  65         x = Phasor.ar(trig, rate / sr);
  66         SinOsc.ar(
  67                 [
  68                         LinLin.kr(x, 0, 1, 600, 1000), // convert range from 0..1 to 600..1000
  69                         1000 // constant second frequency
  70                 ], 0, 0.2)
  71
  72 }.play;
  73 )
  74
  75
  76 // two phasors control two sine frequencies: mouse y controls resetPos of the second
  77 (
  78 { var trig, rate, x, sr;
  79         rate = MouseX.kr(1, 200, 1);
  80         trig = Impulse.ar(rate);
  81         sr = SampleRate.ir;
  82         x = Phasor.ar(trig, rate / sr, 0, 1, [0, MouseY.kr(0, 1)]);
  83         SinOsc.ar(x * 500 + 500, 0, 0.2)
  84 }.play;
  85 )
  86
  87
  88 // use phasor to index into a sound file
  89
  90 // allocate a buffer with a sound file
  91 b = Buffer.read(s, Platform.resourceDir +/+ "sounds/a11wlk01.wav");
  92
  93 // simple playback (more examples: see BufRd)
  94 // Start and end here are defined as 0 and the number of frames in the buffer.
  95 // This means that the Phasor will output values from 0 to numFrames - 1 before looping,
  96 // which is perfect for driving BufRd. (See note above)
  97 { BufRd.ar(1, b.bufnum, Phasor.ar(0, BufRateScale.kr(b.bufnum), 0, BufFrames.kr(b.bufnum))) }.play;
  98
  99
 100 // two phasors control two sound file positions: mouse y controls resetPos of the second
 101 (
 102 { var trig, rate, framesInBuffer;
 103         rate = MouseX.kr(0.1, 100, 1);
 104         trig = Impulse.ar(rate);
 105         framesInBuffer = BufFrames.kr(b.bufnum);
 106         x = Phasor.ar(trig, BufRateScale.kr(b.bufnum), 0, framesInBuffer,
 107                 [0, MouseY.kr(0, framesInBuffer)]);
 108         BufRd.ar(1, b.bufnum, x);
 109 }.play;
 110 )
 111
 112 ::