HelpSource/Classes/Plprand.schelp

   1 class:: Plprand
   2 summary:: random values that tend toward lo
   3 related:: Classes/Phprand
   4 categories:: Streams-Patterns-Events>Patterns>Random
   5
   6 ClassMethods::
   7
   8 method::new
   9
  10 argument::lo
  11 lower boundary of values.
  12
  13 argument::hi
  14 upper boundary of values.
  15
  16 argument::length
  17 number of values produced.
  18
  19 Examples::
  20
  21 code::
  22 (
  23 var a, c, w;
  24 a = Plprand(0.0, 1.0, inf);
  25 c = a.asStream.nextN(500);
  26 w = Window.new("Plprand", Rect(10, 10, 540, 800));
  27 // plot the values
  28 c.plot(bounds: Rect(10, 10, 520, 380), discrete: true, parent: w);
  29 // a histogram of the values
  30 c.histo(500).plot(bounds: Rect(10, 410, 520, 380), parent: w);
  31 )
  32
  33
  34 // sound example
  35 (
  36 SynthDef(\help_sinegrain,
  37         { arg out=0, freq=440, sustain=0.05;
  38                 var env;
  39                 env = EnvGen.kr(Env.perc(0.01, sustain, 0.2), doneAction:2);
  40                 Out.ar(out, SinOsc.ar(freq, 0, env))
  41         }).add;
  42 )
  43
  44
  45 (
  46 var a;
  47 a = Plprand(0.0, 1.0, inf).asStream;
  48 {
  49         loop {
  50                 Synth(\help_sinegrain, [\freq, a.next * 600 + 300]);
  51                 0.02.wait;
  52         }
  53 }.fork;
  54 )
  55
  56 // this is equivalent to:
  57 (
  58 {
  59         loop {
  60                 Synth(\help_sinegrain, [\freq, min(rrand(0.0, 1.0), rrand(0.0, 1.0)) * 600 + 300]);
  61                 0.02.wait;
  62         }
  63 }.fork;
  64 )
  65 ::