HelpSource/Classes/VLayoutView.schelp

   1 class:: VLayoutView
   2 redirect:: implClass
   3 summary:: A container view that arranges its children vertically
   4 categories:: GUI>Views
   5 related:: Classes/HLayoutView, Classes/CompositeView
   6
   7 DESCRIPTION::
   8
   9 note::
  10 In Qt GUI, this class has been rendered strong::obsolete:: by a special set of layout classes; they are easier to use and more flexible. See link::Classes/VLayout:: for an equivalent to this class, and link::Guides/GUI-Layout-Management:: for a general description of the Qt layout system.
  11 ::
  12
  13 VLayoutView can be a parent to other views, and it automatically arranges its child views in vertical order, expanding their width to its own bounds. Only the height of the children is relevant.
  14
  15 When arranging its children, VLayoutView takes the values of their 'minHeight' and 'maxHeight' properties into account. This is useful when a child's link::Classes/View#-resize#resize:: mode is set to 4, 5, or 6. See link::#examples:: below.
  16
  17 VLayoutView inherits some useful formatting methods from its superclasses.
  18
  19 note::
  20 VLayoutView is designed mainly for grouping and placing widgets. While you can set it to accept key presses, it does not accept mouse clicks or drags.
  21 ::
  22
  23 CLASSMETHODS::
  24 PRIVATE:: key
  25
  26 EXAMPLES::
  27
  28 code::
  29 (
  30 q = 10;
  31 w = Window.new;
  32
  33 v = VLayoutView(w,Rect(10,10,300,300));
  34
  35 Array.fill(q,{ arg i;
  36     Slider(v,Rect(0,0,75,20)).value_(i / q)
  37 });
  38
  39 w.front
  40 )
  41
  42 // show the area of the view.
  43 v.background_(Color.rand) // The sliders automatically expand to the optimal width
  44 ::
  45
  46
  47 Stretching the layout view; Slider height is fixed:
  48
  49 code::
  50 (
  51 q = 10;
  52 w = Window.new;
  53
  54 v = VLayoutView(w,Rect(10,10,300,300));
  55 v.background_(Color.rand);
  56 v.resize = 5; // elastic
  57 Array.fill(q,{ arg i;
  58     var s;
  59     s = Slider(v,Rect(0,0,55,20));// The bounds.width are irrelevant here. They expand to the optimal width
  60     s.value = i / q;
  61     s
  62 });
  63 StaticText(v, Rect(0,0,55,20)).background_(Color.rand).string_("Some Example Text").align_(\center);
  64 w.front
  65 )
  66 ::
  67
  68 Stretching the layout view and the contents; if all the contents are elastic, the heights of the contents are perfectly divided up. In this example, the StaticText is not elastic in order to preserve its height.
  69
  70 code::
  71 (
  72 q = 10;
  73 w = Window.new;
  74
  75 v = VLayoutView(w,Rect(10,10,300,300));
  76 v.background_(Color.rand);
  77 v.resize = 5; // elastic
  78 Array.fill(q,{ arg i;
  79     var s;
  80     s = Slider(v,Rect(0,0,75,20));
  81     s.resize = 5; // elastic
  82     s.value = i / q;
  83     s
  84 });
  85 StaticText(v, Rect(0,0,55,40))
  86     .background_(Color.rand).string_("Some Example Text")
  87     .align_(\center);
  88
  89 w.front
  90 )
  91 ::
  92
  93 Mixed stretching modes:
  94 code::
  95 (
  96 q = 5;
  97 w = Window.new;
  98
  99 v = VLayoutView(w,Rect(10,10,300,300));
 100 v.resize = 5; // elastic
 101 v.background_(Color.grey);
 102 Array.fill(q,{ arg i;
 103     var s;
 104     s = Slider(v,Rect(0,0,75,20)).background_(Color.rand);
 105     s.value = i / 5;
 106     if(i < 2,{
 107         s.resize = 5; // some elastic
 108         s.setProperty(\minHeight,20);
 109     },{
 110         s.resize = 1; // some not elastic
 111     });
 112     s
 113 });
 114 StaticText(v, Rect(0,0,55,20)).background_(Color.rand).string_("Some Example Text").align_(\center);
 115
 116 w.front
 117 )
 118 ::
 119
 120 Set minimum heights; beware that if the layout view height is smaller than the combined height of all the contents, things might disappear when you try to handle them with the mouse:
 121
 122 code::
 123 (
 124 q = 5;
 125 w = Window.new;
 126
 127 v = VLayoutView(w,Rect(10,10,300,300));
 128 v.resize = 5; // elastic
 129 v.background_(Color.grey);
 130 Array.fill(q,{ arg i;
 131     var s;
 132     s = Slider(v,Rect(0,0,75,20)).background_(Color.blue.alpha_(0.2));
 133     s.value = i / 5;
 134     s.resize = 5;
 135     s.setProperty(\minHeight,20);
 136     s.setProperty(\maxHeight,40);
 137     s
 138 });
 139 w.front
 140 )
 141 ::
 142
 143 Spacing:
 144
 145 code::
 146 (
 147 q = 10;
 148 w = Window.new;
 149
 150 v = VLayoutView(w,Rect(10,10,300,300));
 151 v.setProperty(\spacing,0);
 152
 153 Array.fill(q,{
 154     Slider(v,Rect(0,0,75,20))
 155 });
 156
 157 w.front
 158 )
 159 ::
 160
 161
 162 Nesting: use VLayoutView and HLayoutView in combination:
 163 code::
 164 (
 165 q = 10;
 166 w = Window.new("nesting",Rect(30,30,400,700));
 167
 168 v = VLayoutView(w,Rect(10,10,300,600));
 169
 170 v.background = Color.rand;
 171
 172 Array.fill(q,{ arg i;
 173     Slider(v,Rect(0,0,75,20)).value_(i / q)
 174 });
 175
 176 StaticText(v, Rect(0,0,55,20)).background_(Color.rand).string_("Some Example Text").align_(\center);
 177
 178 h = HLayoutView(v,Rect(10,10,300,300));
 179
 180 Array.fill(q,{ arg i;
 181     Slider(h,Rect(0,0,20,70)).value_(i / q)
 182 });
 183 h.background = Color.rand;
 184
 185 w.front
 186 )
 187 ::