HelpSource/Guides/SynthDefsVsSynths.schelp

   1 title::SynthDefs versus Synths
   2 summary:: The use of precompiled SynthDefs as opposed to always compiling on the fly
   3 categories:: SC3 vs SC2
   4
   5 In SC2 code::Synth.play:: was the standard way to compile a emphasis::ugenGraphFunc:: and play it. Each time you executed code::Synth.play::, or Spawned a new event, that function was compiled anew. SC3 on the other hand, makes use of what are called SynthDefs. A link::Classes/SynthDef:: takes a emphasis::ugenGraphFunc:: and compiles it to a kind of bytecode (sort of like Java bytecode) which can be understood by the server app. The server reads the link::Classes/SynthDef:: and creates a synth node based upon it.
   6
   7 SynthDefs can be precompiled and saved to disk. Any def saved in the synthdefs/ directory (or in any directory set in the environment variable SC_SYNTHDEF_PATH) will be loaded into memory by a local link::Classes/Server:: when it is booted. If the def being used in a new link::Classes/Synth:: is already compiled and loaded, there is much less of a CPU spike when creating a new link::Classes/Synth:: than there was in SC2.
   8
   9 SynthDefs can also be compiled and loaded into the link::Classes/Server:: without writing them to disk. This can be done while performing.
  10
  11 The downside of this is that precompiled SynthDefs lack some of the programmatic flexibility that was one of SC2's great strengths. Much of this flexibility is gained back however, through the ability to set and change arguments (which you build into your emphasis::ugenGraphFunc::), and through new UGens such as link::Classes/Rand:: and link::Classes/TRand::.
  12
  13 When maximum flexibility is required, it is still possible to compile and send SynthDefs 'on the fly', albeit with SC2-like CPU spikes and a small amount of messaging latency.
  14
  15 It is important to understand that creating and sending SynthDefs is emphasis::asynchronous::. This means that it is impossible to determine precisely how long it will take to compile and send a link::Classes/SynthDef::, and thus when it will be available for creating new Synths. A simple way around this is to execute code in blocks, selecting them one at a time. More complicated is to use completion messages. code::SynthDef.play:: takes care of this for you, and returns a link::Classes/Synth:: object which you can then manipulate. See the example below
  16
  17 Another important distinction is between Synth in SC2 and link::Classes/Synth:: in SC3. The latter is a client-side object which represents a synth node on the server. Although it has some of the same methods, it does not function in the same way. There is no top level Synth in SC3, within which all scheduling and creation of other Synths occurs. There are only link::Classes/Synth:: objects which represent synth nodes on the server. These can be created at any time, within any scope.
  18
  19 examples::
  20
  21 code::
  22 (
  23 s = Server.local;
  24 s.boot;
  25 )
  26
  27 // Compile a SynthDef and write it to disk
  28 (
  29 SynthDef("Help-SynthDef", { arg out = 0;
  30         Out.ar(out, PinkNoise.ar(0.1))
  31 }).writeDefFile;
  32 )
  33
  34 // Compile, write, and load it to the server
  35 (
  36 SynthDef("Help-SynthDef", { arg out = 0;
  37         Out.ar(out, PinkNoise.ar(0.1))
  38 }).load(s);
  39 )
  40
  41 // Load it to the server without writing to disk
  42 (
  43 SynthDef("Help-SynthDef", { arg out = 0;
  44         Out.ar(out, PinkNoise.ar(0.1))
  45 }).send(s);
  46 )
  47
  48 // Create a Synth with it
  49 x = Synth.new("Help-SynthDef", s);
  50 x.free;
  51
  52 // Shorthand method to compile and write a SynthDef, and then play it in a Synth when done.
  53 // Look familiar?
  54 (
  55 x = SynthDef("Help-SynthDef", { arg out = 0;
  56         Out.ar(out, PinkNoise.ar(0.1))
  57 }).play(s);
  58 )
  59 // The above only starts the new Synth after the def has been sent to the server.
  60 // Note that SynthDef.play returns a Synth object!
  61
  62 x.set(\out, 1); // change one of the arguments
  63 x.free;
  64
  65 // SynthDef with a parameter that will be randomly determined each time a new Synth is created
  66 // (try it several times to hear the differences)
  67 (
  68 SynthDef("help-RandFreq", { arg out = 0;
  69         Out.ar(
  70                 out,
  71                 FSinOsc.ar(
  72                         Rand(200.0, 400.0), // frequency between 200 and 400 Hz
  73                         0, Line.kr(0.2, 0, 1, doneAction:2)
  74                 )
  75         )
  76 }).play(s);
  77 )
  78 ::