HelpSource/Classes/DelTapWr.schelp

   1 class:: DelTapWr
   2 categories:: UGens>Buffer, UGens>Delays
   3 summary:: Write to a buffer for a DelTapRd UGen
   4 related:: Classes/DelTapRd
   5
   6 description::
   7 Write to a buffer for a link::Classes/DelTapRd:: UGen
   8
   9 classmethods::
  10 private:: categories
  11
  12 method:: ar, kr
  13 argument:: buffer
  14 the buffer to write signal into. Max delay time is based on buffer size.
  15 argument:: in
  16 the signal to write to the buffer.
  17 returns::
  18 phase - DelTapWr outputs its current sample value for use in the phase argument in DelTapRd
  19
  20 examples::
  21 code::
  22 // a Buffer for the UGens to use, one second at the current sample rate
  23 b = Buffer.alloc(s, s.sampleRate * 1, 1);
  24
  25 // write a signal into a delay, tap it at mutiple times
  26 SynthDef(\test, {arg buffer;
  27         var src, tapPhase, tap1, tap2, tap3;
  28         src = WhiteNoise.ar(0.2) * Decay.kr(Dust.kr(3), 0.2);
  29         tapPhase = DelTapWr.ar(buffer, src);
  30         #tap1, tap2, tap3 = DelTapRd.ar(buffer, tapPhase,
  31                 [0.2, 0.27, 0.303],     // tap times
  32                 1,                                      // no interp
  33                 [1.0, 0.4, 0.2]                 // muls for each tap
  34                 );
  35         Out.ar(0, [src + tap2, tap1 + tap3])
  36         }).send(s);
  37
  38 x = Synth(\test, [\buffer, b]);
  39 x.free;
  40 b.free;
  41 ::
  42
  43 code::
  44 // a Buffer for the UGens to use
  45 b = Buffer.alloc(s, 44100, 1);
  46
  47 // write a signal into a delay, tap it at mutiple times
  48 SynthDef(\write, {arg buffer, cout;
  49         var src, tapPhase, tap1, tap2, tap3;
  50         src = WhiteNoise.ar(0.2) * Decay.kr(Dust.kr(3), 0.7);
  51         tapPhase = DelTapWr.ar(buffer, src);
  52         Out.kr(cout, tapPhase);
  53         }).send(s);
  54
  55 SynthDef(\readFilt, {arg buffer, cin;
  56         var phase, src, filt;
  57         phase = In.kr(cin);
  58         src = DelTapRd.ar(buffer, phase, [0.01, 0.2]);
  59         filt = BPF.ar(src, 880, 0.01) * 10;
  60         Out.ar(0, filt);
  61         }).send(s);
  62
  63 c = Bus.control;
  64
  65 x = Synth(\write, [\buffer, b, \cout, c]);
  66 y = Synth(\readFilt, [\buffer, b, \cin, c]);
  67
  68 x.free;
  69 b.free;
  70 ::
  71