HelpSource/Classes/FreeVerb.schelp

   1 class:: FreeVerb
   2 summary:: A reverb
   3 categories:: UGens>Reverbs
   4 related:: Classes/FreeVerb2, Classes/GVerb
   5
   6 description::
   7 Coded from experiments with faust.
   8
   9 classmethods::
  10
  11 method:: ar
  12 argument:: in
  13 input signal.
  14 argument:: mix
  15 dry/wet balance. range 0..1.
  16 argument:: room
  17 room size. rage 0..1.
  18 argument:: damp
  19 Reverb HF damp. range 0..1.
  20
  21 discussion::
  22 Valid parameter range from 0 to 1. Values outside this range are clipped by the UGen.
  23
  24 examples::
  25 code::
  26 Server.default = s = Server.internal;
  27 s.boot;
  28
  29 // FreeVerb - 1x1 ugen
  30 (
  31 z = SynthDef(\src, {|mix = 0.25, room = 0.15, damp = 0.5|
  32         Out.ar(0,
  33                 FreeVerb.ar(
  34                         Decay.ar(Impulse.ar(1), 0.25, LFCub.ar(1200, 0, 0.1)), // mono src
  35                         mix, // mix 0-1
  36                         room, // room 0-1
  37                         damp // damp 0-1 duh
  38                 ) ! 2 // fan out...
  39         );
  40 }).play
  41 )
  42 z.set(\room, 0.7)
  43 z.set(\mix, 0.4)
  44 z.set(\damp, 0.2)
  45
  46 z.free
  47
  48 // it expands as any ugen does
  49 (
  50 z = SynthDef(\src, {|mix = 0.25, room = 0.15, damp = 0.5|
  51         Out.ar(0,
  52                 FreeVerb.ar(
  53                         Pan2.ar(
  54                                 Decay.ar(Impulse.ar(1), 0.25, LFCub.ar(1200, 0, 0.1)),
  55                                 LFNoise1.ar(1).range(-1, 1)
  56                         ),
  57                         mix,
  58                         room,
  59                         damp
  60                 )
  61         );
  62 }).play
  63 )
  64 z.set(\room, 0.7)
  65 z.set(\mix, 0.4)
  66 z.set(\damp, 0.2)
  67
  68 z.free
  69 ::