HelpSource/Classes/MidEQ.schelp

   1 class:: MidEQ
   2 summary:: Parametric filter.
   3 categories::  UGens>Filters>Linear
   4
   5
   6 Description::
   7
   8 Attenuates or boosts a frequency band.
   9
  10
  11 classmethods::
  12
  13 method::ar, kr
  14
  15 argument::in
  16
  17 The input signal.
  18
  19
  20 argument::freq
  21
  22 Center frequency of the band in Hertz.
  23
  24
  25 argument::rq
  26
  27 The reciprocal of Q (bandwidth / cutoffFreq).
  28
  29
  30 argument::db
  31
  32 Amount of boost (db > 0) or attenuation (db < 0) of the
  33 frequency band.
  34
  35
  36 argument::mul
  37
  38 Output will be multiplied by this value.
  39
  40
  41 argument::add
  42
  43 This value will be added to the output.
  44
  45
  46 Examples::
  47
  48 code::
  49
  50 // mixer parametric eq as wahwah
  51 { MidEQ.ar(Saw.ar(200,0.2), FSinOsc.kr(1, 0, 24, 84).midicps, 0.3, 12) }.play
  52
  53
  54 // notch filter
  55 (
  56 { var in;
  57   in = PinkNoise.ar(0.2) + SinOsc.ar(600, 0, 0.1);
  58   MidEQ.ar(in, SinOsc.kr(0.2, 0.5pi) * 2 + 600, 0.01, -24)
  59 }.play
  60 )
  61
  62 /////
  63 // first start the synth
  64 (
  65 x = {| freq=400, db=0, rq=0.1 |
  66          var in;
  67          in =  SinOsc.ar([ 400, 420 ], 0, 0.4);
  68          MidEQ.ar(in, freq, Lag.kr(rq, 0.3), db)
  69         }.play
  70 )
  71
  72 // now play with its parameters to hear how the filter affects two frequencies
  73 // that are very close to each other
  74
  75 x.set(\db, -12)
  76 x.set(\rq, 0.1)
  77 x.set(\rq, 0.03)
  78 x.set(\freq, 410)
  79 x.set(\freq, 420)
  80 x.set(\freq, 400)
  81 x.set(\freq, 500)
  82
  83 ::