HelpSource/Classes/SpecFlatness.schelp

   1 class:: SpecFlatness
   2 summary:: Spectral Flatness measure
   3 categories:: UGens>FFT
   4 related:: Classes/SpecCentroid, Classes/SpecPcile
   5
   6 description::
   7 Given an link::Classes/FFT:: strong::chain:: this calculates the emphasis::Spectral Flatness:: measure, defined as a power spectrum's geometric mean divided by its arithmetic mean. This gives a measure which ranges from approx 0 for a pure sinusoid, to approx 1 for white noise.
   8
   9 The measure is calculated linearly. For some applications you may wish to convert the value to a decibel scale - an example of such conversion is shown below.
  10
  11 classmethods::
  12 method:: kr
  13
  14 argument:: chain
  15 an link::Classes/FFT:: chain.
  16
  17 examples::
  18
  19 code::
  20 s = Server.internal.boot;
  21 b = Buffer.alloc(s,2048,1);
  22
  23 (
  24 { // Example - vary mixture of white noise and pure tone with the mouse
  25 var in, chain, flat, flatdb, flatdbsquish;
  26 in = XFade2.ar(WhiteNoise.ar, SinOsc.ar, MouseX.kr(-1,1));
  27 chain = FFT(b, in);
  28 Out.ar(0, in * 0.1);
  29
  30 flat = SpecFlatness.kr(chain);
  31
  32 flatdb = 10 * flat.log; // Convert to decibels
  33 flatdbsquish = LinLin.kr(flatdb, -45, -1.6, 0, 1).max(-10); // Rescale db roughly to 0...1.
  34
  35 flat.poll(10, "flatness: ");
  36 flatdb.poll(10, "flatness (db): ");
  37
  38 Out.kr(0, [flat, flatdbsquish]);
  39 }.scope;
  40 )
  41
  42 (
  43 { // Now try with your own voice
  44 var in, chain;
  45 in = SoundIn.ar([0,1]).mean;
  46 chain = FFT(b, in);
  47 Out.kr(0, [in, SpecFlatness.kr(chain).poll(1, "flatness: ")]);
  48 }.scope;
  49 )
  50 ::