HelpSource/Classes/UnpackFFT.schelp

   1 class:: UnpackFFT
   2 summary:: Unpack an FFT chain into separate demand-rate FFT bin streams
   3 categories:: UGens>FFT
   4 related:: Classes/PackFFT, Classes/Unpack1FFT
   5
   6 description::
   7 Takes an FFT chain and separates the magnitude and phase data into separate demand-rate streams, for arithmetic manipulation etc.
   8
   9 This is technically a demand-rate UGen. The actual "demand" is usually created by PackFFT later on in the graph, which requests the values in order to re-pack the data. This allows for processing to occur imbetween...
  10
  11 See also pvcollect, pvcalc and pvcalc2 methods ( in link::Classes/PV_ChainUGen:: ) which provide convenient ways to process audio in the frequency domain. The help for pvcollect includes notes on efficiency considerations.
  12
  13 classmethods::
  14 private:: categories
  15
  16 method:: new
  17 argument:: chain
  18 FFT chain
  19 argument:: bufsize
  20 FFT buffer size
  21 returns::
  22 A list from DC up to Nyquist of code:: [mag[0], phase[0], mag[1], phase[1], ... mag[nyquist], phase[nyquist]]. ::
  23 discussion::
  24 Note that you do have to decide your FFT buffer size in advance, since this determines how many values the UGen will output.
  25 code::
  26 #magsphases = UnpackFFT(chain, bufsize)
  27 ::
  28
  29 examples::
  30 code::
  31 (
  32 s.boot.doWhenBooted {
  33         var fftsize = 1024;
  34         b = Buffer.alloc(s, fftsize, 1);
  35         c = Buffer.read(s, Help.dir +/+ "sounds/a11wlk01.wav");
  36 }
  37 )
  38
  39 // This one just drags out various the values and posts them - a little bit pointless!
  40 (
  41 x = {
  42         var sig, chain, unp;
  43         sig = SinOsc.ar;
  44         sig = PlayBuf.ar(1, c, BufRateScale.kr(c), loop: 1);
  45         chain = FFT(b, sig);
  46
  47         // Using the frombin & tobin args makes it much more efficient, limiting analysis to the bins of interest
  48         unp = UnpackFFT(chain, b.numFrames, frombin: 0, tobin: 4);
  49
  50         // Demand some data from the unpacker.
  51         // NOTE: At present, Demand.kr is unable to handle more than 32 inputs,
  52         // so using frombin & tobin to limit the number of bins is compulsory.
  53         Demand.kr(chain>=0, 0, unp).collect{|anunp, index|
  54                 anunp.poll(chain>=0, if(index % 2 == 0,  "Magnitude", "Phase")+(index/2).floor);
  55         };
  56
  57         (sig*0.1).dup;
  58 }.play(s);
  59 )
  60 x.free;
  61
  62 // Now a simple frequency-domain manipulation, square-rooting the magnitudes AND phases.
  63 (
  64 x = {
  65         var in, chain, magsphases;
  66         in = PlayBuf.ar(1, c, BufRateScale.kr(c), loop: 1);
  67         chain = FFT(b, in);
  68         magsphases = UnpackFFT(chain, b.numFrames);
  69         magsphases = magsphases.collect(_.sqrt);
  70         PackFFT(chain, b.numFrames, magsphases);
  71         Out.ar(0, 0.25 * IFFT(chain).dup);
  72 }.play(s);
  73 )
  74 x.free;
  75 ::
  76