HelpSource/Classes/VDiskIn.schelp

   1 class:: VDiskIn
   2 summary:: Stream in audio from a file, with variable rate
   3 categories:: UGens>InOut, UGens>Buffer
   4 related:: Classes/PlayBuf, Classes/BufRd, Classes/DiskIn
   5
   6 description::
   7 Continuously play a longer soundfile from disk. This requires a buffer to be preloaded with one buffer size of sound.
   8
   9 classmethods::
  10 method:: ar
  11
  12 argument:: numChannels
  13 number of channels
  14
  15 argument:: bufnum
  16 buffer number
  17 Note:: The Buffer's numFrames must be a power of two and is recommended to be at least 65536 -- preferably 131072 or 262144. Smaller buffer sizes mean more frequent disk access, which can cause glitches. ::
  18
  19 argument:: rate
  20 controls the rate of playback. Values below 4 are probably fine, but the higher the value, the more disk activity there is, and the more likelihood there will be a problem.
  21
  22 warning::
  23 the rate does have a practical limit. The following must be true: rate < Buffer's size / ( 2 * s.options.blockSize) e.g with typical default values, this wil be 32768 / (2 * 64) = 256.
  24 ::
  25
  26 If the rate is too high, the UGen will not execute, posting a warning.
  27
  28 argument:: loop
  29 If loop is set to 1, the soundfile will loop.
  30
  31 argument:: sendID
  32 If a sendID is given, the UGen sends an osc message with this id and the file position each time it reloads the buffer: code::['/diskin', nodeID, sendID, frame]::
  33
  34 discussion::
  35 This UGen will set the link::Classes/Done##'done' flag:: when finished playing.
  36
  37 examples::
  38 code::
  39 b = Buffer.cueSoundFile(s, Help.dir +/+ "sounds/a11wlk01-44_1.aiff", 0, 1);
  40
  41 x = { VDiskIn.ar(1, b, LFNoise2.kr(0.2).range(0.5, 2), 1, loop:1) }.play;
  42
  43 b.close;
  44
  45 // again
  46 // note the like named instance method, but different arguments
  47 b.cueSoundFile(Help.dir +/+ "sounds/a11wlk01-44_1.aiff", 0);
  48
  49 x.free; b.close; b.free;
  50
  51
  52 // cue and play right away
  53 (
  54 SynthDef("help-VDiskin", { arg bufnum = 0;
  55         Out.ar(0, VDiskIn.ar(1, bufnum, MouseX.kr(0.5, 2.0)));
  56 }).send(s);
  57 )
  58 (
  59 x = Synth.basicNew("help-VDiskin");
  60 m = { arg buf; x.addToHeadMsg(nil, [\bufnum, buf])};
  61
  62 b = Buffer.cueSoundFile(s,Help.dir +/+ "sounds/a11wlk01-44_1.aiff",0,1, completionMessage: m);
  63 )
  64
  65 x.free; b.close; b.free;        // clean up
  66
  67
  68
  69 // sending back the file position.
  70 // note:
  71 // the ugen knows nothing of the loop (apply a modulo).
  72 // if you load another file, you need to free the buffer and re-allocate it (see below)
  73
  74 b = Buffer.cueSoundFile(s, Help.dir +/+ "sounds/a11wlk01-44_1.aiff", 0, 1, bufferSize: 4096);
  75 c = SoundFile(Help.dir +/+ "sounds/a11wlk01-44_1.aiff").info;
  76 x = { VDiskIn.ar(1, b, LFNoise2.kr(0.2).range(0.2, 0.9), 1, sendID: 14) }.play;
  77
  78 // register to receive this message
  79
  80 (
  81 o = OSCFunc({ arg msg;
  82         var sendID = msg[2];
  83         var index = msg[3];
  84         msg.postln;
  85         "id: % pos: % frames (% sec)\n"
  86                 .postf(sendID, index % c.numFrames, (index % c.numFrames / c.sampleRate));
  87 },'/diskin', s.addr)
  88 );
  89
  90 b.close; b.free;
  91
  92 b.alloc; b.cueSoundFile(Help.dir +/+ "sounds/a11wlk01-44_1.aiff", 0); c = SoundFile(Help.dir +/+ "sounds/a11wlk01-44_1.aiff").info;
  93
  94 x.free; b.close; b.free; o.free; // clean up eventually
  95
  96
  97
  98 // the same example in OSC Messaging style, see link::Guides/NodeMessaging::
  99
 100 // allocate a disk i/o buffer
 101 s.sendMsg("/b_alloc", 0, 65536, 1);
 102
 103 // open an input file for this buffer, leave it open
 104 s.sendMsg("/b_read", 0, Help.dir +/+ "sounds/a11wlk01-44_1.aiff", 0, 65536, 0, 1);
 105
 106 // create a diskin node
 107 s.sendMsg("/s_new", "help-VDiskin", x = s.nextNodeID, 1, 1);
 108
 109 s.sendMsg("/b_close", 0); // close the file (very important!)
 110
 111
 112 // again
 113 // don't need to reallocate and Synth is still reading
 114 s.sendMsg("/b_read", 0, Help.dir +/+ "sounds/a11wlk01-44_1.aiff", 0, 0, 0, 1);
 115
 116 s.sendMsg("/n_free", x); // stop reading
 117
 118 s.sendMsg("/b_close", 0); // close the file.
 119
 120 s.sendMsg("/b_free", 0); // frees the buffer
 121 ::